RCCTD WikiDataCuration03
CNUDH
목차
Contents
연구배경
중국 축구는 1990년대 중반 프로리그 제도가 정착되면서 리그 운영, 경기장 인프라, 선수·감독 인력 구조가 빠르게 확장되었다. 그 과정에서 대규모 경기장 건설, 프로 클럽 수의 증가, 유소년 대표팀(U-17·U-20·U-23)의 정비 등 다양한 제도적 투자가 병행되었다.
그러나 이러한 변화가 실제로
(1) 어떤 인력 구조를 형성했는지
(2) 리그별 클럽과 경기장의 물리적 특성이 어떠한지
(3) 유소년 대표팀과 A대표팀 간의 연계가 작동하고 있는지
(4) 대표팀 및 프로리그 경험을 가진 선수들이 어떤 커리어 경로를 밟는지
에 대해서는 일관된 데이터 기반 분석이 부족하다.
이에 본 연구는 위키데이터 SPARQL 쿼리를 활용하여 중국 축구의 인력·리그·대표팀 구조를 체계적으로 파악하고, 중국 축구 시스템이 어떤 구조적 특성을 갖추고 있는지를 분석하고자 한다.
연구목적
본 연구는 SPARQL 기반 데이터 분석을 통해 중국 축구의 구조적 특성을 네 가지 측면에서 규명하는 것을 목표로 한다.
(1) 인력 구조의 특성 파악
1980~2009년 사이 출생한 중국 국적 선수·감독의 출생연도, 경력 시작 연도 등을 비교하여 중국 축구 인력의 세대 구성, 인력 유입 시기, 선수-감독 간 세대 구조를 파악한다.
(2) 리그 및 경기장 인프라의 구조적 특징 분석
중국 프로리그(1부·2부)에 속한 클럽의 홈 경기장 위치·좌표·수용 인원을 분석하여 리그 간 인프라 규모의 차이를 파악한다.
우승 클럽의 경기장 규모·창단 시기 등의 정보를 활용하여 프로리그 수준과 경기장 인프라 사이의 구조적 관계를 검토한다.
(3) 대표팀(U17/U20/U23/A) 구조 및 육성 흐름 분석
각 대표팀 단계별 선수 소속 여부와 소속 시점을 비교하여 유소년 대표팀이 실제로 A대표팀으로의 승격 구조를 형성하고 있는지 파악한다.
대표팀 경험이 선수의 성장 경로에서 어떤 역할을 하는지 확인한다.
(4) 대표팀 경험자의 커리어 경로 분석
대표팀(U17/U20/U23/A) 경험을 보유한 선수가 중국 1부·2부·해외 리그 중 어느 경로로 이동하는지를 정량적으로 비교하여 중국 축구 생태계의 개방성·폐쇄성을 평가한다.
대상주제
본 연구는 중국 축구계를 구성하는 핵심 요소들을 다음 네 가지 분석 단위로 구분한다.
(1) 중국 축구 인물(선수·감독) 구조 분석
- 중국 국적
- 축구선수·축구감독
- 소속 팀, 소속 리그
- 출생연도, 사망연도, 경력 시작연도
등의 정보를 추출하여 전체 인력 풀의 구조를 분석한다.
(2) 중국 프로리그(CSL·갑급리그) 및 경기장 인프라 분석
다음과 같은 리그·경기장 속성을 수집하고 비교한다.
- 홈 경기장의 위치 및 좌표
- 경기장 수용 인원의 평균·최소·최대값
- 리그별 클럽 수 및 경기장 수
- 우승 클럽의 창단연도, 첫 우승 연도, 총 우승 횟수
- 경기장 규모와 우승 클럽 간의 구조적 관계
(3) 대표팀(U17·U20·U23·A) 단계 분석
대표팀 관련 속성을 통해
- 각 대표팀에서 활동한 연도
- 단계별 대표팀 이동 여부(예: U17→U20→U23→A대표)
- A대표팀 승격자 데이터
를 분석하여 유소년 시스템의 구조적 특성을 파악한다.
(4) 대표팀 경험 선수들의 커리어 이동 분석
- 1부(슈퍼리그)
- 2부(갑급리그)
- 해외(클럽)
세 가지 구간을 기준으로 선수 경력을 분류하여 대표팀 경험이 실제 커리어 선택에 미치는 영향을 분석한다.
쿼리작성
- 본 연구에서 활용된 쿼리는 총 24개로, 핵심 분석을 담당하는 주요 쿼리 8개와 보조적 탐색을 위한 보조 쿼리 16개로 구성.
- 주요 퀴리는 시각적 구분을 위해 주황색 글씨로 표시.
- 분석 과정에서 참고용으로 활용된 보조 쿼리는 검정색 글씨로 구분하여 제시.
- 주요 쿼리 아래에는 → 표시를 활용하여 해당 쿼리의 결과값을 간단하게 설명.
중국 축구 인물 전체적인 풀
중국 국적을 가진 사람 중에서 축구선수 또는 축구감독은 누구이며 이들의 소속 팀은 무엇인가?
SELECT ?person ?personLabel ?team ?teamLabel ?occupation ?occupationLabel
WHERE {
?person wdt:P27 wd:Q148. # 중국 국적
?person wdt:P106 ?occupation. # 직업
FILTER (?occupation IN (wd:Q937857,wd:Q628099)) # 선수/감독
OPTIONAL { ?person wdt:P54 ?team } # 소속 팀 (있을 경우만)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh".}}
LIMIT 200
중국 국적의 축구선수 또는 축구감독 중에서, 1994년 이후에 출범한 축구 리그에 속한 팀에서 활동한 적이 있는 사람은 누구인가?
SELECT ?person ?personLabel ?team ?teamLabel ?league ?leagueLabel ?occupation ?occupationLabel
WHERE {
?person wdt:P27 wd:Q148 . # 중국 국적 ?person wdt:P106 ?occupation . # 직업 FILTER (?occupation IN (wd:Q937857, wd:Q628099)) # 선수/감독
?person wdt:P54 ?team . # 소속 팀 ?team wdt:P118 ?league . # 클럽이 속한 리그 ?league wdt:P571 ?leagueStart . # 리그 성립 시점(개시 시기)
FILTER (YEAR(?leagueStart) >= 1994) # 1994년 이후 시작된 리그만 선택
SERVICE wikibase:label {bd:serviceParam wikibase:language "ko, zh, en" .}}
LIMIT 200
1980~2009년에 태어난 중국 국적 축구선수와 축구감독을 대상으로, 출생연도·나이·경력 시작 연도를 추출해 세대별로 중국 축구의 현대적 인력 구조를 시각화.
#defaultView:Dimensions
SELECT ?personLabel ?occupationLabel ?birthYear ?deathYear ?age ?careerStart
WHERE {
?person wdt:P31 wd:Q5; # 인간이어야 한다
wdt:P27 wd:Q148; # 국적이 중국이다
wdt:P569 ?birth; # 출생일
wdt:P106 ?occupation. # 직업
FILTER(?occupation IN (wd:Q937857, # 축구선수
wd:Q628099)) # 축구감독
OPTIONAL { ?person wdt:P570 ?death. } # 사망일 (있을 경우)
OPTIONAL { ?person wdt:P2031 ?careerStartDate. } # 경력 시작일 (있을 경우)
BIND(YEAR(?birth) AS ?birthYear) # 출생연도 BIND(IF(BOUND(?death), YEAR(?death), 2025) AS ?deathYear) # 사망연도 또는 2025 BIND(?deathYear - ?birthYear AS ?age) # (사망연도/2025) - 출생연도 = 나이 BIND(YEAR(?careerStartDate) AS ?careerStart) # 경력 출발 시점(연도)
FILTER(?birthYear >= 1980 && ?birthYear <= 2009) # 현대 중국 축구 핵심 세대 FILTER(?age > 0)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
LIMIT 200
-> 지도자층(감독)은 주로 1980년대생, 선수층은 1990년대생 중심으로 세대 분리가 나타난다.
-> 경력 시작 연도는 제한적이지만, 기록이 있는 경우 대부분 18~21세 시기에 프로 커리어를 시작한다.[1]
-> 출생연도–나이–경력 시작 간 연결을 보면, 중국 축구는 유소년→프로→지도자로 이어지는 비교적 안정된 인력 재생산 구조를 갖추고 있다.
출생 연도·출생지
중국 축구선수들의 출생연도와 출생지는 무엇인가?
SELECT ?person ?personLabel ?birth ?birthplace ?birthplaceLabel WHERE {
?person wdt:P27 wd:Q148. # 중국 국적
?person wdt:P106 wd:Q937857. # 축구선수
OPTIONAL { ?person wdt:P569 ?birth. } # 출생
OPTIONAL { ?person wdt:P19 ?birthplace. } # 출생지
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
LIMIT 200
1980~2009년 출생 중국 축구선수는 누구인가?
SELECT ?person ?personLabel ?birth WHERE {
?person wdt:P27 wd:Q148. # 중국 국적
?person wdt:P106 wd:Q937857. # 축구선수
?person wdt:P569 ?birth. # 출생
FILTER (YEAR(?birth) >= 1980 && YEAR(?birth) < 2010) # 1980~2009
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
LIMIT 200
중국 프로 축구(1부, 2부리그) 분석
중국 1부리그에 속한 클럽의 구장은 어디에 위치에 있는가?
SELECT ?stadium ?stadiumLabel ?place ?placeLabel ?location WHERE {
?team wdt:P118 wd:Q209318. # 1부
?team wdt:P115 ?stadium. # 홈경기장
?stadium wdt:P31 wd:Q483110. # 경기장
?stadium wdt:P17 wd:Q148. # 중국
OPTIONAL { ?stadium wdt:P131 ?place. } # 지역
OPTIONAL { ?stadium wdt:P625 ?location. } # 좌표
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
1부(슈퍼리그) 경기장의 위치를 디지털 지도에 매핑.
#defaultView:Map
SELECT ?stadium ?stadiumLabel ?coord ?clubLabel
WHERE {
?club wdt:P118 wd:Q209318; # 리그: 중국 슈퍼리그)
wdt:P115 ?stadium. # 홈 구장(경기장)
?stadium wdt:P625 ?coord. # 경기장 좌표
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
2부(갑급리그) 경기장의 위치와 좌표.
SELECT ?stadium ?stadiumLabel ?place ?placeLabel ?location WHERE {
?team wdt:P118 wd:Q1207912. # 2부
?team wdt:P115 ?stadium. # 홈경기장
?stadium wdt:P31 wd:Q483110. # 경기장
?stadium wdt:P17 wd:Q148. # 중국
OPTIONAL { ?stadium wdt:P131 ?place. } # 지역
OPTIONAL { ?stadium wdt:P625 ?location. } # 좌표
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
1부(슈퍼리그) 경기장 이미지.
#defaultView:ImageGrid
SELECT ?stadium ?stadiumLabel ?image WHERE {
?club wdt:P118 wd:Q209318. # 중국 슈퍼리그
?club wdt:P115 ?stadium. # 홈 구장
?stadium wdt:P18 ?image. # 이미지가 있는 경기장만
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
중국 1부(슈퍼리그)와 2부(갑급리그)에 속한 클럽들의 홈 경기장을 대상으로, 리그별 평균 수용 인원, 최소·최대 수용 인원, 경기장 개수를 한 번에 비교한 후 인프라 규모 격차가 어느 정도인지 시각화
#defaultView:Dimensions
SELECT ?leagueLabel
(AVG(?capacity) AS ?avgCapacity) # 리그별 평균 수용 인원
(MIN(?capacity) AS ?minCapacity) # 리그별 최소 수용 인원
(MAX(?capacity) AS ?maxCapacity) # 리그별 최대 수용 인원
(COUNT(DISTINCT ?stadium) AS ?stadiumCount) # 리그별 경기장(클럽) 수
WHERE {
# 1단계: 팀 - 리그 - 홈 경기장 연결
?team wdt:P118 ?league; # 팀이 속한 리그
wdt:P115 ?stadium. # 팀의 홈 경기장
# 1부(중국 슈퍼리그) / 2부(중국 갑급리그)만 선택
FILTER (?league IN (wd:Q209318, # 중국 슈퍼리그(1부)
wd:Q1207912))# 중국 갑급리그(2부)
# 2단계: 경기장 수용 인원 값 가져오기 ?stadium wdt:P1083 ?capacity. # 경기장 수용 인원
# 라벨 불러오기
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
GROUP BY ?leagueLabel
-> 1부(슈퍼리그)와 2부(갑급리그) 모두 경기장 평균 수용 인원이 4만 석대 초반으로 비슷하다.
-> 최대 수용 인원은 두 리그 모두 8만 석대로 거의 같다.
-> 클럽 수는 1부가 2부보다 많다.
-> 중국 프로리그는 스타디움 규모로 리그를 계층화했다기보다는, 비슷한 규모의 경기장을 바탕으로 팀 수와 경쟁 수준으로 1부·2부를 나눈 구조.
중국 슈퍼리그(CSL) 시즌별 우승 팀은 어디인가?
SELECT ?season ?seasonLabel ?winner ?winnerLabel ?date WHERE {
?season wdt:P3450 wd:Q209318. # 중국 슈퍼리그
?season wdt:P1346 ?winner. # 우승 팀
OPTIONAL { ?season wdt:P585 ?date. } # 시점
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
ORDER BY ?date
2000년 이후 중국 슈퍼리그(CSL)에서 가장 많이 우승한 팀은 어디인가?
#defaultView:BarChart
SELECT ?winnerLabel (COUNT(?season) AS ?titles)
WHERE {
?season wdt:P3450 wd:Q209318; # 중국 슈퍼리그의 각 시즌
wdt:P1346 ?winner; # 시즌 우승 팀
wdt:P585 ?date. # 시즌 시점 (대부분 연도 단위)
FILTER (YEAR(?date) >= 2000) # 2000년 이후 시즌만 포함
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
GROUP BY ?winnerLabel
ORDER BY DESC(?titles)
수용 인원이 큰 홈 경기장을 사용하는 클럽일수록 중국 슈퍼리그(CSL) 우승을 더 많이 차지했는가?
#defaultView:ScatterChart
SELECT ?capacity ?titles ?clubLabel
WHERE {
# 1단계: 클럽별 중국 슈퍼리그 우승 횟수 집계
{
SELECT ?club (COUNT(?season) AS ?titles)
WHERE {
?season wdt:P3450 wd:Q209318; # 중국 슈퍼리그
wdt:P1346 ?club. # 시즌 우승 팀
}
GROUP BY ?club
}
# 2단계: 각 클럽의 홈구장 수용 인원 가져오기 ?club wdt:P115 ?stadium. # 홈 경기장 ?stadium wdt:P1083 ?capacity. # 경기장 수용 인원
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
-> 절대적인 대형 경기장이라고 해서 우승을 보장하는 것은 아니다.
-> 중위권~상위권 우승 팀들은 대부분 6만석 전후의 안정적 규모를 보유.
-> 우승 1회 그룹은 경기장 규모와 우승 사이의 상관성이 거의 없음.
-> 크고 잘 지은 경기장이 ‘상위권 가능성’을 높이긴 하지만, 절대적인 조건은 아니다.
중국 슈퍼리그(CSL)에서 우승한 클럽들을 대상으로 각 클럽의 창단 연도, 첫 우승 연도, 총 우승 횟수, 홈 경기장 수용 인원을 한 번에 비교한 후, 중국 프로 축구의 강팀들이 어떤 시기에 등장했고 어떤 인프라를 갖추고 있는지 시각화.
#defaultView:Dimensions
SELECT ?clubLabel ?foundedYear ?firstTitleYear ?titles ?capacity
WHERE {
# 1단계: CSL 우승 클럽별 우승 횟수와 첫 우승 연도 집계
{
SELECT ?club (COUNT(?season) AS ?titles) (MIN(YEAR(?date)) AS ?firstTitleYear)
WHERE {
?season wdt:P3450 wd:Q209318; # 중국 슈퍼리그 시즌
wdt:P1346 ?club; # 시즌 우승 팀
wdt:P585 ?date. # 시즌 시점
}
GROUP BY ?club
}
# 2단계: 각 클럽의 기본 정보(창단 연도, 홈구장 수용 인원)
OPTIONAL {
?club wdt:P571 ?founded. # 클럽 창단일
BIND(YEAR(?founded) AS ?foundedYear)
}
OPTIONAL {
?club wdt:P115 ?stadium. # 홈경기장
?stadium wdt:P1083 ?capacity. # 경기장 수용 인원
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
LIMIT 50
-> 과거에 창단한 전통 구단일수록 우승 첫 시점이 빠르다.
-> 신생 구단 중에서도 폭발적으로 성장한 팀이 있다.
-> 경기장 규모(=투자 규모)와 우승 경험은 약간의 상관 관계가 있다.
연령별 대표팀 구조(U17/U20/U23/A대표)
중국 U-17 대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE {
?person wdt:P27 wd:Q148. # 중국 국적
?person wdt:P106 wd:Q937857. # 축구선수
?person wdt:P54 wd:Q3589928. # U-17
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
중국 U-20 대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE {
?person wdt:P27 wd:Q148. # 중국 국적
?person wdt:P106 wd:Q937857. # 축구선수
?person wdt:P54 wd:Q5100058. # U-20
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
중국 U-23 대표팀(올림픽대표) 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE {
?person wdt:P27 wd:Q148. # 중국 국적
?person wdt:P106 wd:Q937857. # 축구선수
?person wdt:P54 wd:Q987926. # U-23
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
중국 A대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE {
?person wdt:P27 wd:Q148. # 중국 국적
?person wdt:P106 wd:Q937857. # 축구선수
?person wdt:P54 wd:Q130582. # A대표
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
2025년 기준으로 중국 U-23(올림픽대표) 대표팀에서 현재 활동 중인 선수들을 TreeMap으로 시각화.
#defaultView:TreeMap
SELECT ?teamLabel ?athleteLabel WHERE {
?athlete wdt:P31 wd:Q5; # 인간
wdt:P27 wd:Q148; # 중국 국적
wdt:P106 wd:Q937857. # 축구선수
# 대표팀(U-23) 소속 기간
?athlete p:P54 ?ntStatement.
?ntStatement ps:P54 wd:Q987926. # 중국 U-23 대표팀
OPTIONAL { ?ntStatement pq:P580 ?ntStart. }# 대표팀 시작일
OPTIONAL { ?ntStatement pq:P582 ?ntEnd. } # 대표팀 종료일
# 2025년 현재 U-23에 해당 FILTER ( !BOUND(?ntStart) || YEAR(?ntStart) <= 2025 ) FILTER ( !BOUND(?ntEnd) || YEAR(?ntEnd) >= 2025 )
# 클럽 소속 기간(현재 클럽만) ?athlete p:P54 ?clubStatement. ?clubStatement ps:P54 ?team. # 소속 팀 ?team wdt:P31 wd:Q476028. # 축구 클럽(국가대표팀 등 제외)
OPTIONAL { ?clubStatement pq:P580 ?clubStart. } # 클럽 합류일
OPTIONAL { ?clubStatement pq:P582 ?clubEnd. } # 클럽 퇴단일
# 2025년 현재 클럽에 해당 FILTER ( !BOUND(?clubStart) || YEAR(?clubStart) <= 2025 ) FILTER ( !BOUND(?clubEnd) || YEAR(?clubEnd) >= 2025 )
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
2025년 기준으로 중국 A대표팀에서 활동 중인 선수들을 TreeMap으로 시각화.
#defaultView:TreeMap
SELECT ?teamLabel ?athleteLabel WHERE {
?athlete wdt:P31 wd:Q5; # 인간
wdt:P27 wd:Q148; # 중국 국적
wdt:P106 wd:Q937857. # 축구선수
# A대표팀 소속 기간 조건
?athlete p:P54 ?ntStatement.
?ntStatement ps:P54 wd:Q130582. # 중국 A대표팀
OPTIONAL { ?ntStatement pq:P580 ?ntStart. }# 대표팀 시작일
OPTIONAL { ?ntStatement pq:P582 ?ntEnd. } # 대표팀 종료일
# 2025년 현재도 대표팀 소속 FILTER ( !BOUND(?ntStart) || YEAR(?ntStart) <= 2025 ) FILTER ( !BOUND(?ntEnd) || YEAR(?ntEnd) >= 2025 )
# 2025년 기준 '현 소속 클럽' ?athlete p:P54 ?clubStatement. ?clubStatement ps:P54 ?team. # 소속 클럽 ?team wdt:P31 wd:Q476028. # 클럽(국가대표팀 제외)
OPTIONAL { ?clubStatement pq:P580 ?clubStart. } # 클럽 합류일
OPTIONAL { ?clubStatement pq:P582 ?clubEnd. } # 클럽 퇴단일
# 2025년 현재 클럽에 해당 FILTER ( !BOUND(?clubStart) || YEAR(?clubStart) <= 2025 ) FILTER ( !BOUND(?clubEnd) || YEAR(?clubEnd) >= 2025 )
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
중국 U-17, U-20, U-23 대표팀을 거쳐 최종적으로 중국 A대표팀에 승격한 선수들을 찾아서, 이들의 대표팀 단계별 소속 시점(시작·종료 연도)을 함께 비교한 후, 중국 유소년 대표팀 시스템에서 실제로 A대표로 성장한 선수 라인을 시각화.
#defaultView:Dimensions
SELECT
?playerLabel
?u17StartYear ?u17EndYear
?u20StartYear ?u20EndYear
?u23StartYear ?u23EndYear
?aStartYear ?aEndYear
WHERE {
# 기본 조건: 중국 국적 + 축구선수
?player wdt:P31 wd:Q5; # 인간
wdt:P27 wd:Q148; # 중국 국적
wdt:P106 wd:Q937857. # 축구선수
# ① U-17 대표팀 경력
OPTIONAL {
?player p:P54 ?u17Statement.
?u17Statement ps:P54 wd:Q3589928; # 중국 U-17 대표팀
pq:P580 ?u17Start; # 시작 시점
pq:P582 ?u17End. # 종료 시점
BIND(YEAR(?u17Start) AS ?u17StartYear)
BIND(YEAR(?u17End) AS ?u17EndYear)
}
# ② U-20 대표팀 경력
OPTIONAL {
?player p:P54 ?u20Statement.
?u20Statement ps:P54 wd:Q5100058; # 중국 U-20 대표팀
pq:P580 ?u20Start;
pq:P582 ?u20End.
BIND(YEAR(?u20Start) AS ?u20StartYear)
BIND(YEAR(?u20End) AS ?u20EndYear)
}
# ③ U-23 대표팀 경력
OPTIONAL {
?player p:P54 ?u23Statement.
?u23Statement ps:P54 wd:Q987926; # 중국 U-23 대표팀
pq:P580 ?u23Start;
pq:P582 ?u23End.
BIND(YEAR(?u23Start) AS ?u23StartYear)
BIND(YEAR(?u23End) AS ?u23EndYear)
}
# ④ A대표팀 경력 (최종 목표)
OPTIONAL {
?player p:P54 ?aStatement.
?aStatement ps:P54 wd:Q130582; # 중국 A대표팀
pq:P580 ?aStart;
pq:P582 ?aEnd.
BIND(YEAR(?aStart) AS ?aStartYear)
BIND(YEAR(?aEnd) AS ?aEndYear)
}
# '승격자'만 보기 → A대표팀 경력이 있는 선수만 필터링 FILTER(BOUND(?aStart))
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
LIMIT 50
-> U-17 → U-20 → U-23 → A 대표로 이어지는 ‘육성 사다리’가 없다.
-> 대부분 선수는 유소년 단계를 건너뛰고 바로 A대표로 선발.
-> 유소년 대표 출신이 A대표로 승격되는 비율은 매우 낮음.
-> 강한 투자에도 불구하고, 체계적인 육성 구조가 부재함.
1990년 이후 출생한 중국 국적 축구선수 중에서 U-17, U-20, U-23 대표팀 가운데 하나라도 거친 선수들이 현재 중국 1부(슈퍼리그) 또는 2부(갑급리그) 클럽에서 활동하고 있는 비율(인원 수)을 바 차트 형태로 비교.
#defaultView:BarChart
SELECT ?category ?count
WHERE {
#1) 대표팀(U17/U20/U23)을 거쳐 + 1부/2부 리그에서도 뛴 선수 수
{
SELECT ("대표+프로" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
WHERE {
?player wdt:P31 wd:Q5; # 인간
wdt:P27 wd:Q148; # 중국 국적
wdt:P106 wd:Q937857; # 축구선수
wdt:P569 ?birth.
BIND(YEAR(?birth) AS ?birthYear)
FILTER(?birthYear >= 1990) # 1990년 이후 출생
# U17 / U20 / U23 중 하나라도 소속
VALUES ?youthNT { wd:Q3589928 wd:Q5100058 wd:Q987926 }
?player wdt:P54 ?youthNT.
# 중국 1부(슈퍼리그) 또는 2부(갑급리그) 클럽 경험
?player wdt:P54 ?club.
?club wdt:P118 ?league.
FILTER(?league IN (wd:Q209318, wd:Q1207912)) # 1부·2부 리그
}
}
UNION
#2) U17/U20/U23 대표팀을 하나라도 거친 전체 선수 수
{
SELECT ("대표 전체" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
WHERE {
?player wdt:P31 wd:Q5; # 인간
wdt:P27 wd:Q148; # 중국 국적
wdt:P106 wd:Q937857; # 축구선수
wdt:P569 ?birth.
BIND(YEAR(?birth) AS ?birthYear)
FILTER(?birthYear >= 1990)
VALUES ?youthNT { wd:Q3589928 wd:Q5100058 wd:Q987926 }
?player wdt:P54 ?youthNT.
}
}
}
-> 유소년 대표팀 출신 선수 중 프로 상위리그(1·2부)에 도달한 비율
-> 1990년대 이후 중국 유소년 대표팀을 경험한 선수들은 사실상 100% 중국 프로 상위리그(1부·2부)에 진출한다.
1990년 이후에 태어난 중국 국적 축구선수 가운데 U-17, U-20, U-23, A대표 중 하나 이상을 경험한 선수들을 대상으로, 그중에서 해외 클럽(중국이 아닌 나라 클럽)에서 뛴 적이 있는 선수 비율을 바 차트로 비교.
#defaultView:BarChart
SELECT ?category ?count
WHERE {
{
# ① 대표팀(U17/U20/U23/A) + 해외 클럽(중국 외 국가) 경험이 있는 선수 수
SELECT ("해외 진출" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
WHERE {
?player wdt:P31 wd:Q5; # 인간
wdt:P27 wd:Q148; # 중국 국적
wdt:P106 wd:Q937857; # 축구선수
wdt:P569 ?birth. # 출생일
BIND(YEAR(?birth) AS ?birthYear)
FILTER(?birthYear >= 1990) # 1990년 이후 출생
# U-17 / U-20 / U-23 / A대표 중 하나라도 경험
VALUES ?natTeam { wd:Q3589928 wd:Q5100058 wd:Q987926 wd:Q130582 }
?player wdt:P54 ?natTeam.
# 해외 클럽 경험: 클럽의 국가가 중국이 아닌 경우
?player wdt:P54 ?club.
?club wdt:P17 ?clubCountry.
FILTER(?clubCountry != wd:Q148) # 중국이 아닌 나라
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }
}
}
UNION
{
# ② 대표팀(U17/U20/U23/A) 경험이 있는 전체 선수 수
SELECT ("대표 전체" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
WHERE {
?player wdt:P31 wd:Q5; # 인간
wdt:P27 wd:Q148; # 중국 국적
wdt:P106 wd:Q937857; # 축구선수
wdt:P569 ?birth.
BIND(YEAR(?birth) AS ?birthYear)
FILTER(?birthYear >= 1990) # 1990년 이후 출생
VALUES ?natTeam { wd:Q3589928 wd:Q5100058 wd:Q987926 wd:Q130582 }
?player wdt:P54 ?natTeam.
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}}}
-> 대표팀(U17/U20/U23/A 중 하나라도 거친 선수 4명 중 1명만 해외에 나갔다.
-> 중국 유소년·성인 대표 시스템은 해외 진출로 거의 연결되지 않는다.
-> 중국 대표팀 라인의 '폐쇄성'이 수치로 드러난다.
1990년 이후 출생한 중국 국적 축구선수 중 U-17, U-20, U-23, A대표 가운데 하나라도 경험한 선수들이 어떤 커리어 경로(1부·2부·해외)로 가장 많이 흘러갔는지를 바 차트를 통해서 비교.
#defaultView:BarChart
SELECT ?category ?count WHERE {
# ① 대표팀(U17/U20/U23/A) + 중국 1부(슈퍼리그) 경험자
{
SELECT ("1부 리그" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
WHERE {
?player wdt:P31 wd:Q5;
wdt:P27 wd:Q148;
wdt:P106 wd:Q937857;
wdt:P569 ?birth.
BIND(YEAR(?birth) AS ?birthYear)
FILTER(?birthYear >= 1990)
VALUES ?natTeam { wd:Q3589928 wd:Q5100058 wd:Q987926 wd:Q130582 }
?player wdt:P54 ?natTeam.
?player wdt:P54 ?club.
?club wdt:P118 wd:Q209318. # 슈퍼리그(1부)
}
}
UNION
# ② 대표팀(U17/U20/U23/A) + 중국 2부(갑급리그) 경험자
{
SELECT ("2부 리그" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
WHERE {
?player wdt:P31 wd:Q5;
wdt:P27 wd:Q148;
wdt:P106 wd:Q937857;
wdt:P569 ?birth.
BIND(YEAR(?birth) AS ?birthYear)
FILTER(?birthYear >= 1990)
VALUES ?natTeam { wd:Q3589928 wd:Q5100058 wd:Q987926 wd:Q130582 }
?player wdt:P54 ?natTeam.
?player wdt:P54 ?club.
?club wdt:P118 wd:Q1207912. # 갑급리그(2부)
}
}
UNION
# ③ 대표팀(U17/U20/U23/A) + 해외 클럽 경험자
{
SELECT ("해외 리그" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
WHERE {
?player wdt:P31 wd:Q5;
wdt:P27 wd:Q148;
wdt:P106 wd:Q937857;
wdt:P569 ?birth.
BIND(YEAR(?birth) AS ?birthYear)
FILTER(?birthYear >= 1990)
VALUES ?natTeam { wd:Q3589928 wd:Q5100058 wd:Q987926 wd:Q130582 }
?player wdt:P54 ?natTeam.
?player wdt:P54 ?club.
?club wdt:P17 ?country.
FILTER(?country != wd:Q148) # 중국 제외
}
}
}
-> 중국 대표팀 시스템은 해외나 2부가 아니라 국내 1부 중심으로 흘러가는 폐쇄형 구조.
-> 대표팀을 경험했더라도 모두 1부에서 활약하는 것은 아니며, 많은 선수가 결국 2부로 유입·하향되고 있음.
-> 중국 대표 출신이라고 해서 해외 경쟁력을 갖추는 것은 아니며, 해외 리그 접근성·스카우팅 네트워크가 매우 제한적.
결과해석
본 연구는 위키데이터 기반 SPARQL 쿼리를 활용하여 (Map·ImageGrid·Treemap)등 여러 보조쿼리 통해 주요쿼리를 시각적·맥락적으로 보완하고
- 인력 구조(1980–2009년 출생 선수·감독의 출생연도·경력 시작 연도를 비교한 Dimensions 쿼리)
- 리그·인프라 특성(1·2부 리그 홈 경기장의 수용 인원·분포를 분석한 Dimensions·ScatterChart 쿼리)
- 유소년 대표 시스템(U-17·U-20·U-23·A대표 단계별 소속 시점을 추적한 Dimensions 쿼리)
- 대표팀 경험자의 커리어 경로(국내 1부·2부·해외 리그 이동을 비교한 BarChart 쿼리)
를 통해 중국 축구 구조의 핵심 특징을 도출하고, 다각도로 분석하였다.
연구 결과
1. 인력 구조 분석: 지도자층과 선수층의 세대 분리
1980–2009년 출생 인물을 기준:
- 세대 구도
지도자층(감독)은 주로 1980년대생 중심이다.
선수층은 1990년대생이 대부분을 구성한다.
→ 감독과 선수 간 분명한 세대 분리가 존재한다.
- 경력 시작 연도
경력 시작 연도는 데이터가 부족하지만, 클럽 최초 소속 연도 기준으로 보면 18~21세 사이에 프로로 진입하는 경향이 뚜렷하다.
- 인력 재생산 구조
출생연도 → 나이 → 경력 시작 연도가 유소년 → 프로 → 지도자 로 자연스럽게 이어지는 '형식적 구조'는 존재하나, 이를 안정적으로 뒷받침할 제도적 체계는 약하다.
2. 리그·인프라 구조 분석: 1부와 2부의 ‘비슷한 인프라 기반’
1부(슈퍼리그)와 2부(갑급리그)의 홈 경기장 수용 인원을 비교:
- 평균 수용 인원
-> 두 리그 모두 4만 석대 초반으로 큰 차이가 없다.
- 최대 수용 인원
-> 1부와 2부 모두 상위 구장은 8만 석 수준으로 비슷하다.
- 구조적 해석
-> 중국은 경기장 규모로 리그를 계층화한 시스템이 아니다.
->'비슷한 인프라를 공통 기반으로 두고, 팀 수·경쟁력·예산 등으로 리그를 구분'하는 모델에 가깝다.
-> 즉, 인프라는 상향 평준화되어 있고 팀 간 차별 요소가 아니다.
3. 우승 클럽 구조: 창단 시기·인프라·우승의 상관성
- 창단 연도와 첫 우승
-> 오래된 전통 구단일수록 첫 우승 시점이 빠르다.
그러나 신생 구단 중에서도 짧은 기간 내 폭발적 성장을 보여 다회 우승한 사례가 존재한다.
-> 중국 축구는 역사적 기반 + 투자 중심의 신흥 세력이 공존하는 구조다.
- 경기장 규모와 우승 상관성
경기장 수용 인원과 우승 횟수는 약한 양의 상관관계를 보인다.
-> 큰 경기장은 '우승 가능성을 높이는 배경 요소' 정도이다.
->'대형 경기장이 곧 우승'이라는 인과 관계는 성립하지 않는다.
4. 유소년 대표 시스템의 현실: 사다리의 부재
중국 U-17 → U-20 → U-23 → A대표 라는 이론적 육성 모델을 실제 데이터:
- 네 단계를 모두 거친 ‘정석 라인’은 거의 없다.
-> U17→U20→U23→A 대표로 이어지는 완전한 코스는 거의 존재하지 않음.
- 실제 경로는 분절적이다.
-> 다수의 A대표는 일부 단계만 거친다.
-> 유소년 대표팀을 아예 거치지 않고 바로 A대표에 선발된다.
-> 연령별 대표팀이 하나의 '육성 사다리'가 아니라, 서로 분리 운영되는 독립 집단에 가깝다.
- 유소년 대표 경험의 효과
1990년 이후 출생 기준:
-> U17/U20/U23 중 하나라도 경험한 선수들은 거의 예외 없이 중국 프로 상위리그(1·2부)에 진출한다.
-> 연령별 대표팀은 'A대표로 승격하는 통로'는 아니다.
->'국내 프로 상위리그로 진입하는 티켓' 역할은 강하게 한다.
5. 해외 진출 구조: 폐쇄성이 매우 강하다.
- 1990년 이후 출생 & U17/U20/U23/A 중 하나 이상 경험한 선수들
-> 해외 리그 경험자는 전체의 약 25%에 불과하다.
-> 대표팀을 경험해도 해외 진출로 자연스럽게 연결되지 않는다.
- 대표팀 경험자의 커리어 흐름
중국 1부 → 가장 많은 비중을 차지한다.
중국 2부 → 유의미한 수가 하향 이동한다.
해외 리그 → 극히 제한적이다.
-> 중국 대표팀 시스템은 '국내 1부 중심으로 회귀하는 폐쇄형 생태계'임이 명확히 드러난다.
종합 결론: 중국 축구 발전의 구조적 특징
분석 결과를 종합하면 중국 축구는 다음과 같은 특징을 가진다.
- 인력 구조는 안정적이나, 상향 이동이 제한적이다.
유소년→프로→지도자의 흐름은 존재하나 대표팀 단계 간 상향 이동은 매우 제한된다.
- 리그 인프라는 1·2부 모두 상향 평준화되었다.
경기장 인프라가 발전했지만, 이는 경쟁력의 핵심 요인이 되지는 못한다.
- 우승·성장 구조는 '전통+신흥'의 이중 구조를 이룬다.
역사 깊은 팀과 폭발적 성장 팀이 공존하는 독특한 시장 구조이다.
- 해외 진출은 제한적이며 폐쇄적이다.
대표팀 출신이라도 해외 진출 가능성이 낮고, 내부 리그 생태계를 벗어나기 어려운 구조적 폐쇄성이 존재한다.
- 유소년–A대표 간 구조적 단절이 있다.
이론적 사다리는 존재하지만, 실제 승격 메커니즘은 거의 작동하지 않는다.
-> 중국 축구 발전이 정체된 근본 원인 중 하나로 해석 가능하다.
느낀 점 & 보완하고 싶은 점
느낀 점
- 본 프로젝트를 통해 위키데이터 기반 SPARQL 분석이 중국 축구와 같은 복합적 스포츠 시스템을 구조적으로 이해하는 데 유효한 도구가 될 수 있음을 확인했다.
- 주요 쿼리와 보조 쿼리를 병행함으로써, 단일 결과에 의존하지 않고 여러 시각화 방식(BarChart, Dimensions, TreeMap, Map 등)을 통해 결과를 교차 검증하는 연구 접근의 중요성을 체감했다. 이를 통해 스포츠 연구에서도 데이터 기반 분석이 충분히 설득력을 가질 수 있음을 인식하게 됐다.
보완하고 싶은 점
- 귀화 선수, 유소년 아카데미 출신 여부, 해외 유소년 시스템 경험 등 다양한 변수를 추가한다면, 중국 축구 발전 정체의 원인을 더 입체적으로 분석할 수 있을 것으로 기대된다.
참고자원
- 발표에 포함되지는 않았으나 연구 과정에서 도출된 여러 보조 쿼리들 중 일부 결과.
- 향후 추가적인 궁금증이나, 탐구가 필요할 때 참고 자료로 활용.
1부(슈퍼리그) 경기장의 위치를 디지털 지도에 매핑.
1부(슈퍼리그) 경기장 이미지.
- 결과를 해석·보완하기 위한 관련 언론 인터뷰 자료.
본 연구의 분석 결과, 중국 축구는 유소년 대표팀에서 A대표팀으로 이어지는 구조가 충분히 작동하지 않는 것으로 나타났다.
이러한 결과를 해석·보완하기 위해 연구 과정에서 관련 언론 인터뷰 자료를 참고하였으며, 해당 기사 역시 중국 축구의 유소년 육성 시스템 부재를 핵심 문제로 지적하고 있다.[2]
연구 후기 및 학우들의 감상
김태현 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
본 프로젝트를 통해 위키데이터 기반 SPARQL 분석이 중국 축구와 같은 복합적 스포츠 시스템을 구조적으로 이해하는 데 유효한 도구가 될 수 있음을 확인했다. 주요 쿼리와 보조 쿼리를 병행함으로써, 단일 결과에 의존하지 않고 여러 시각화 방식(BarChart, Dimensions, TreeMap, Map 등)을 통해 결과를 교차 검증하는 연구 접근의 중요성을 체감했다. 이를 통해 스포츠 연구에서도 데이터 기반 분석이 충분히 설득력을 가질 수 있음을 인식하게 됐다.
강현지 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
황시아 (👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
최다혜 (⚽⚽⚽⚽👧🏻👧🏻🧑🏻🧑🏻🏃🏃➡️👍👍)
(쿼리뿐만아니라 전체적 맥락 정리를 잘 해주신듯 하다. 축구에 대해 하나도 모르는데도 불구하고 여러가지 정보들을얻어갑니다. 가장 어렵게만 느꼈던 디멘션 차트를 정말 잘 이용하시는듯하다. 본인의 연구에서 볼수 있었던 것과 마찬가지로 중국은 자국의 인재들을 해외로 유출시키지 않는다는 추가 분석결과를 얻어낼 수 있었다.)
김성산 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
신서령 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
박승정 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
축구는 좋아하지만 중국 축구는 관심이 없었는데 알게되어서 신기하다.
정윤환 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
김은지 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
YEFENG (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
QUAN (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
주석
- ↑ 중국 축구는 초기 커리어 기록(경력 시작 시점)이 부족해 데이터가 비어 있는 경우가 대부분이다.
- ↑ https://www.footballist.co.kr/news/articleView.html?idxno=184973