RCCTD WikiDataCuration04
CNUDH
목차
Contents
연구배경
중국의 근현대사를 논할 때 1839년 아편전쟁은 결코 빼놓을 수 없는 거대한 분기점이다. 이 전쟁은 단순한 무력 충돌을 넘어, 굳게 닫혀 있던 중국의 문호가 서구 열강에 의해 강제로 개방된 사건이었다. 역사 수업과 문헌을 통해 우리는 아편전쟁 이후 상하이, 홍콩 등 개항장을 중심으로 서구의 자본(은행, 무역회사)과 문화(교회, 병원, 학교)가 물밀듯이 유입되었음을 익히 알고 있다.
본 연구는 이러한 역사적 전환을 텍스트가 아닌 '디지털 데이터'를 통해 확인하고자 하는 호기심에서 출발했다. 거대한 역사적 사건 뒤에는 반드시 방대한 데이터의 흔적이 남아있을 것이라는 가정하에, 아편전쟁이 남긴 물리적, 경제적 유산들을 위키데이터를 통해 시각화해보고자 했다. 이를 위해 1840년부터 1900년 사이 청나라 및 중국 전역에 설립된 은행, 기업, 교회, 학교, 병원 등을 포괄적으로 검색하는 정밀 쿼리를 계획하였다.
그러나 실제 데이터 추출 과정에서 예상치 못한 현상을 발견했다. 분석의 명확성을 위해 모호한 하위 개념을 배제하고 핵심적인 시설 유형(은행, 학교, 병원 등)을 직접 지정하여 검색하였으나, 도출된 데이터의 총 개수는 단 80건에 불과했다. 이는 4억 인구와 광활한 영토를 가진 중국에서 60년이라는 긴 시간 동안 연평균 약 1.3개의 시설만이 기록되었다는 의미로, 실제 역사의 규모와는 명백한 괴리가 존재한다.
이에 본 연구는 이 '80건'이라는 숫자가 단순한 데이터 부족을 넘어, 위키데이터 내에 어떤 구조적 특징이나 편향이 내포되어 있음을 시사한다고 판단하였다. 따라서 본 과제에서는 쿼리 작성을 통해 데이터를 직접 추출해 보고, 그 안에 숨겨진 데이터의 속성을 상세히 분석하여 디지털 기록이 역사를 어떻게 재현(또는 왜곡)하고 있는지 검증해 보고자 한다.
연구목적
본 연구는 아편전쟁 이후 중국의 개항과 서구 문물 유입이라는 역사적 사건이 위키데이터상에서 어떻게 투영되고 있는지 분석하고, 그 과정에서 발견된 '데이터의 공백'이 갖는 의미를 고찰하는 데 목적이 있다. 구체적인 세부 연구 목표는 다음과 같다.
1. 역사적 사실과 데이터 간의 불일치를 정량적으로 규명한다. 역사 문헌에 기록된 19세기 후반 중국 개항장(상하이, 홍콩 등)의 번성함과 달리, 위키데이터에 등재된 당시 근대 기업 및 기관 데이터는 극소수에 불과함을 SPARQL 쿼리를 통한 전수 조사로 검증한다. 이를 통해 실제 역사와 디지털 기록 사이에 존재하는 정량적 격차를 수치로 제시한다.
2. 데이터의 유형별 분포를 통해 '기록의 편향'을 분석한다. 추출된 데이터를 경제(은행, 기업), 종교(교회), 사회 인프라(병원, 학교) 등 유형별로 분류하여 분석한다. 당시 존재했던 다양한 시설 중 어떤 종류의 데이터가 주로 살아남아 기록되었는지, 혹은 특정 분야에만 데이터가 쏠려 있지는 않은지를 파악하여 디지털 아카이브가 갖는 '생존자 편향'의 가능성을 진단한다.
3. 디지털 인문학 관점에서 기록되지 않은 역사의 의미를 재해석한다. 단순히 위키데이터의 정보 부족을 지적하는 것을 넘어, 제국주의 시기의 침탈과 토착적 변화들이 왜 데이터화 되지 않았는지 구조적인 원인을 탐구한다. 이를 통해 데이터의 부재 역시 역사를 읽어내는 중요한 단서임을 주장하고, 향후 역사 데이터 구축 시 고려해야 할 비판적 관점을 제시한다.
대상주제
1. 시간적 범위: 1839년 ~ 1900년
시작점(1839): 제1차 아편전쟁 발발로 서구 세력의 중국 진출이 본격화된 시점.
종료점(1900): 의화단 운동으로 반외세 감정이 폭발하고 서구 열강의 침탈이 정점에 달했던 시기.
선정 이유: 중국 근대사에서 서구 문물 유입이 가장 폭발적으로 이루어졌어야 할 60년간의 데이터를 전수 조사하여 데이터 결핍의 심각성을 강조함.
2.공간적 범위 : 중국 및 청나라
특정 도시(상하이 등)에 한정하지 않고 중국 전역을 범위로 설정함. 이는 데이터의 부재나 편중이 특정 지역만의 문제인지, 아니면 위키데이터 전체의 구조적 특성인지 규명하기 위함임.
3. 분석 대상: 아편전쟁(원인)과 그로 인한 사회적 변화(결과)를 다각도로 비교하기 위해 3가지 핵심 카테고리를 선정하여 쿼리함.
-군사/사건 : 아편전쟁(1차, 2차) 관련 전투및 조약.
목적: 서구 열강이 무력으로 개입한 주요 지점들을 파악하여, 전쟁의 물리적 경로가 데이터상에 어떻게 남아있는지 확인한다.
-사회 인프라 : 병원, 학교.
목적: 전쟁 이후 설립된 근대식 의료·교육 시설의 데이터를 수집하여, 이들의 지리적 입지가 전쟁의 경로와 어떤 상관관계를 갖는지 시각적으로 분석한다.
-경제/종교 : 은행, 기업, 교회, 선교회.
목적: 자본(기업)과 종교(교회) 등 다양한 분야의 데이터를 수집하고, 앞서 선정한 사회 인프라(병원/학교) 데이터와 비교하여 분야별 데이터의 생존율과 기록 편향을 검증한다.
쿼리작성
① 아편전쟁 기본 정보
1-1.아편전쟁의 기간은?
SELECT ?war ?warLabel ?startDate ?endDate
WHERE {
VALUES ?war { wd:Q191282 wd:Q418151 } . # Q191282: 1차 아편전쟁, Q476691: 2차 아편전쟁
?war wdt:P580 ?startDate ;
wdt:P582 ?endDate .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
1-2.아편전쟁 참전국은?
SELECT ?war ?warLabel ?participant ?participantLabel
WHERE {
VALUES ?war { wd:Q191282 wd:Q220984 } .
?war wdt:P710 ?participant . # P710: 참전 (participant)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
1-3.아편전쟁에 참여한 사람은?
SELECT DISTINCT ?person ?personLabel ?warLabel
WHERE {
VALUES ?war { wd:Q191282 wd:Q220984 } .
?person wdt:P607 ?war .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}
ORDER BY ?war
1-4.아편전쟁과 관련된 전투목록과 날짜는?
SELECT ?battle ?battleLabel ?date WHERE {
VALUES ?war { wd:Q191282 wd:Q418151 } # 제1아편전쟁, 제2아편전쟁
?battle wdt:P361 ?war ; # 전쟁의 일부
wdt:P585 ?date . # 날짜
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
} ORDER BY ?date
1-5.아편전쟁 전투 위치
#defaultView:Map
SELECT ?item ?itemLabel ?coord ?partOfWarLabel
WHERE {
VALUES ?partOfWar { wd:Q191282 wd:Q418151} .
?item wdt:P361 ?partOfWar ; # P361: ~의 일부 (part of)
wdt:P625 ?coord . # P625: 좌표 (coordinate location)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
1-6.아편전쟁 전투 타임라인
#defaultView:Timeline
SELECT ?item ?itemLabel ?date ?warLabel
WHERE {
VALUES ?war { wd:Q191282 wd:Q418151 } .
?item wdt:P361 ?war ; # 전쟁의 일부인 사건들
wdt:P585 ?date . # P585: 시점 (point in time)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
②아편전쟁의 물리적 흔적과 결과
2-1. 불평등 조약의 체결과 개항(결과값 안나옴)
-전쟁의 결과로 체결된 조약(난징조약, 베이징조약 등)을 찾아, 서구 문물 유입의 법적 근거가 된 사건들을 확인한다.
SELECT ?treaty ?treatyLabel ?date
WHERE {
VALUES ?war { wd:Q191282 wd:Q418151 }
?treaty wdt:P361 ?war; # 전쟁의 일부인 사건 중
wdt:P31/wdt:P279* wd:Q131569. # '조약(Treaty)'인 것만 필터링
OPTIONAL { ?treaty wdt:P585 ?date. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en". }
}
ORDER BY ?date
2-2. 관련 주요 불평등 조약 목록 (직접 지정)
SELECT ?treaty ?treatyLabel ?date
WHERE {
# 주요 조약을 지정
VALUES ?treaty {
wd:Q238262 # 난징 조약 (1차 결과)
wd:Q612577 # 톈진 조약 (2차 도중)
wd:Q604938 # 베이징 조약 (2차 결과)
}
OPTIONAL { ?treaty wdt:P585 ?date. } # 체결일
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en". }
}
ORDER BY ?date
③이식된 서구 문명: 유형별 상세 분석
3-1. 1840~1900년 청나라/중국 주요 시설
SELECT DISTINCT ?item ?itemLabel ?typeLabel ?inception WHERE {
VALUES ?country { wd:Q8733 wd:Q148 }
?item wdt:P17 ?country.
?item wdt:P571 ?inception. FILTER(YEAR(?inception) >= 1840 && YEAR(?inception) <= 1900)
VALUES ?type {
wd:Q22687 # Bank
wd:Q783794 # Business
wd:Q16970 # Church building
wd:Q16917 # Hospital
wd:Q3914 # School
}
?item wdt:P31 ?type.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en,zh". }
} ORDER BY ?inception
3-2 1840~1900년 청나라/중국 서구 시설의 위치
#defaultView:Map
SELECT ?item ?itemLabel ?typeLabel ?coord ?inception
WHERE {
# 1. 대상 시공간 조건
VALUES ?country { wd:Q8733 wd:Q148 }
?item wdt:P17 ?country.
?item wdt:P571 ?inception.
FILTER(YEAR(?inception) >= 1840 && YEAR(?inception) <= 1900)
# 2. 유형 조건
VALUES ?type {
wd:Q22687 # Bank
wd:Q783794 # Company
wd:Q16970 # Church building
wd:Q16917 # Hospital
wd:Q3914 # School
}
?item wdt:P31 ?type.
# 3. [추가] 좌표 정보 (P625)
?item wdt:P625 ?coord.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en,zh". }
}
ORDER BY ?inception
3-3.1840~1900년 설립된 시설 중, 설립자가 중국 국적이 아닌 시설 목록 (결과값 안나옴)
SELECT DISTINCT ?item ?itemLabel ?inception ?typeLabel ?founderLabel
WHERE {
# 1. 대상 시설 지정 (병원, 학교, 교회, 기업, 은행)
VALUES ?type {
wd:Q16917 wd:Q3914 wd:Q16970 wd:Q783794 wd:Q22687
}
?item wdt:P31/wdt:P279* ?type.
# 2. 시공간 조건 (중국/청나라, 1840~1900년)
VALUES ?country { wd:Q148 wd:Q1742 } # 중국 OR 청나라
?item wdt:P17 ?country.
?item wdt:P571 ?inception.
FILTER(YEAR(?inception) >= 1840 && YEAR(?inception) <= 1900)
# 3. 설립자가 중국 국적인 시설을 제외
FILTER NOT EXISTS {
?item wdt:P112 ?founder. # 시설의 설립자를 찾고
?founder wdt:P27 wd:Q148. # 그 설립자의 국적이 중국(Q148)인 경우를 제외
}
# 4. 설립자 라벨 추가 (확인용)
OPTIONAL { ?item wdt:P112 ?founder. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en". }
}
ORDER BY ?inception
3-4.교회,학교,병원/은행,기업 시각화
#defaultView:BubbleChart
SELECT ?group (COUNT(?item) AS ?count) WHERE {
# 1. 국가(중국) 및 기간(1840~1900) 필터
VALUES ?country { wd:Q8733 wd:Q148 }
?item wdt:P17 ?country.
?item wdt:P571 ?inception.
FILTER(YEAR(?inception) >= 1840 && YEAR(?inception) <= 1900)
# 2. 5가지 유형 지정
VALUES ?type {
wd:Q16917 wd:Q3914 wd:Q16970 # 병원, 학교, 교회 -> Group A
wd:Q22687 wd:Q783794 # 은행, 회사 -> Group B
}
?item wdt:P31 ?type.
# 3. 그룹 통합 로직
BIND(
IF(?type IN (wd:Q16917, wd:Q3914, wd:Q16970),
"Group A (병원+학교+교회)",
"Group B (회사+은행)")
AS ?group
)
}
GROUP BY ?group
결과해석
① 아편전쟁 기본 정보 해석
1-1. 전쟁의 기간과 데이터의 정밀도(1-1, 1-6 통합)
분석:아편전쟁의 전체 기간은 1839년부터 1860년까지로 확인된다.그러나 세부 데이터를 살펴보면, 제2차 아편전쟁의 시작일과 종료일은 구체적인 월/일 없이 모두 '1월 1일'로만 기록되어 있다. 이는 정확한 날짜 데이터가 입력되지 않았을 때 연도만 표기되는 전형적인 데이터 공백현상이다.
해석:제1차 전쟁에 비해 제2차 전쟁의 시점 정보가 불분명한 것은, 위키데이터 내에서 아편전쟁 관련 메타데이터가 균일한 품질로 관리되지 않고 있음을 보여준다.전쟁 자체의 기간 정보가 부정확하기 때문에, 개별 전투의 날짜를 추적한 타임라인 데이터(1-6)가 전쟁의 실제 흐름을 파악하는 데 더욱 필수적인 자료가 된다. 즉, '전쟁'이라는 상위 개념보다 '전투'라는 하위 사건들이 더 구체적인 시공간 정보를 담고 있다.
1-2. 전쟁의 주체와 '인물 공백' (1-2, 1-3 통합)
분석:참전국은 '영국'과 '프랑스'로 명확히 나타난다.(1-2)그러나 연결된 인물 데이터 53명을 상세 분석한 결과, 대다수가 영국·프랑스군 지휘관이나 서구 외교관 등 외국인 이름으로 구성되어 있다. 반면, 당시 청나라 측의 주요 지휘관이나 관료의 데이터는 상대적으로 매우 빈약하거나 누락되어 있다.
해석 (기록의 서구 중심성):이는 위키데이터가 구축한 아편전쟁의 역사가 서구의 시각에서 기록되었음을 시사한다.전쟁은 쌍방의 충돌임에도 불구하고, 데이터베이스 상에서는 침략한 자의 이름만 남고 방어한 자의 이름은 지워진 상태이다.따라서 53명이라는 숫자는 단순한 정보 부족을 넘어, 승자와 서구권 중심의 기록 권력이 반영된 결과로 해석해야 한다. 이로써 우리는 디지털 아카이브가 결코 중립적이지 않음을 확인할 수 있다.
1-3. 북상하는 전선 (1-4, 1-5 통합)
분석: 전투 목록과 좌표를 지도에 시각화했을 때, 초기 전투는 남부 광저우 인근에서 발생하다가 점차 양쯔강 유역을 거쳐 북부 톈진과 베이징 인근으로 이동하는 경향을 보인다. 또한 모든 좌표는 해안선과 주요 강에 위치한다.
해석:서구 열강은 내륙 점령이 아닌, 물류의 동맥(해안/강)을 장악하여 수도(북쪽)를 압박하는 전략을 취했다. 이 전투 좌표들은 훗날 '개항장'이 되어 서구 문물이 유입되는 물리적 통로가 된다.
②아편전쟁의 물리적 흔적과 결과 해석
2-1. 불평등 조약의 데이터 공백 (2-1, 2-2 통합)
분석: 난징조약(1차 결과)과 톈진조약은 확인되나, 제2차 아편전쟁을 종결짓고 기독교 포교의 자유를 허용한 핵심 조약인 '베이징 조약'의 날짜 정보가 누락되어 있다.
해석: 역사 교과서에서는 중요하게 다루어지는 사건이 디지털 아카이브에서는 기초적인 메타데이터조차 갖추지 못한 상태이다. 우리는 이 '데이터의 구멍'을 통해, 디지털 인문학 연구가 단순히 있는 정보를 찾는 것을 넘어, 없는 정보를 지적하고 채워넣어야 하는 과제를 안고 있음을 알 수 있다.
③이식된 서구 문명: 유형별 상세 분석 해석
3-1. 전쟁의 상처 위에 세워진 시설들 (3-1 위치 분석)
분석:전투 좌표(1-5)와 서구 시설 좌표(3-2)를 비교했을 때, 개수의 차이(전투 30개 vs 시설 69개)로 인해 1:1 대응은 어렵다.그러나 두 데이터 모두 내륙 깊숙한 곳이 아닌 동남부 해안선과 양쯔강 유역에 극도로 집중되어 있다는 명확한 지리적 공통점을 보인다.
해석:이는 아편전쟁이 중국의 '해안 장벽'을 무너뜨린 사건이었음을 의미하며, 그 무너진 틈(개항장)을 통해 서구 문물이 유입되었음을 시각적으로 증명한다.전투가 발생했던 주요 항구들이 곧 서구 문물의 유입 통로가 되었으며, 병원과 학교 등은 이 해안선을 따라 내륙으로 진출했다.
3-2. 유형별 분석: 자본보다 먼저 온 문화 (3-1, 3-4 통합)
분석: 시설 유형을 분석한 결과, 병원, 학교, 교회의 수가 은행이나 기업보다 월등히 많았다. 또한 많은 시설의 설립일이 '1월 1일'로 기록되어 있어 정확한 기록 부재를 시사한다.
해석: 이는 제국주의 침략이 단순히 경제적 수탈로 시작된 것이 아니라, 문화적·종교적 침투가 선행되었음을 보여준다. 서구 열강은 반발감을 줄이기 위해 선교사를 앞세워 치료와 교육을 제공하며 정신적 영향력을 먼저 확대했다.
3-3. 주체 없는 근대화 (3-3 설립자 분석)
분석: '중국 국적이 아닌 설립자'를 찾으려 했으나 유의미한 데이터가 도출되지 않았다. 이는 실제로 설립자가 없어서가 아니라, 위키데이터 내에 해당 시설들의 설립자 속성 자체가 입력되어 있지 않기 때문이다.
해석: 우리는 '어떤 건물'이 들어왔는지는 알지만, 그것을 '누가' 세웠는지는 디지털 데이터에서 찾을 수 없다. 건물의 유형 정보는 존재하지만, 그 이면의 인적 네트워크 정보는 끊겨 있어, 현재 위키데이터만으로는 서구 세력의 인적 침투 경로를 완벽히 파악하는 데 한계가 있음을 시사한다.
④종합 결론 및 느낀점
종합 결론
이번 연구는 위키데이터를 활용해 아편전쟁의 전개 과정과 그 이후 이식된 서구 문물의 흐름을 추적했다. 도출된 데이터는 [남부 해안의 공격(전쟁) → 불평등 조약 체결(개항) → 의료와 교육을 앞세운 서구 시스템의 정착(이식)]이라는 19세기 중국 근대화의 경로를 명확히 보여주었다.
하지만 이번 연구의 더 본질적인 성과는 오히려 데이터의 빈틈을 확인한 데 있다.
기록의 편향: 참전 인물의 대다수는 서구인이고, 청나라 측의 인물 정보는 거의 비어있다.
정밀도의 부족: 제2차 아편전쟁과 베이징 조약 같은 중대 사건의 날짜 정보가 누락되거나 정확하지 않다.
주체의 실종: 서구식 건물이 해안가에 들어섰음은 확인되나, 정작 그 설립자가 누구인지에 대한 정보는 찾아보기 힘들다.
결론적으로, 현재 위키데이터가 보여주는 아편전쟁은 서구의 시각에서 기록된 반쪽짜리 역사이다. 디지털 공간 속에 건물은 남았으나, 그 시대를 살았던 사람과 치열했던 시간은 희미하다. 따라서 디지털 인문학의 과제는 단순히 존재하는 데이터를 시각화하는 것을 넘어, 이 거대한 ‘데이터 공백’을 인지하고 메워나가는 것에서부터 다시 시작되어야 함을 알 수 있다.
느낀점
처음 이 프로젝트를 시작할 때의 목표는 위키데이터의 방대한 연결성을 활용해 아편전쟁의 인과관계를 화려한 네트워크 그래프와 다양한 통계로 시각화하는 것이었다. 하지만 실제 쿼리를 작성하고 실행하는 과정은 계속되는 ‘결과값 없음’과의 싸움이었다.
솔직하게, 연구를 진행하는 내내 아쉬움이 컸다. 설립자의 국적을 분석해 인적 네트워크를 그려보려던 시도는 데이터 누락으로 무산되었고, 정밀한 타임라인을 구현하려던 계획은 불분명한 날짜 데이터 때문에 한계에 부딪혔다. 더 다양하고 역동적인 시각화 자료를 통해 자료를 풍성하게 채우고 싶었던 욕심에 비추어 볼 때, 쿼리 결과의 다양성이 부족한 점은 아직도 너무 아쉬운 부분이다.
하지만 원하던 데이터가 나오지 않는다는 그 좌절감이 오히려 이번 과제의 핵심을 깨닫게 해 주는 전환점이 되었다. 쿼리 오류가 아님에도 결과가 나오지 않는 현상을 보며, 나는 이것이 나의 실패가 아니라 디지털 아카이브의 현주소임을 깨달았다. 우리가 교과서에서 배우는 당연한 역사적 사실들이 디지털 세계에서는 아직 ‘입력되지 않은 빈칸’으로 남아있다는 사실은 꽤 큰 충격이었다.
결국 이번 과제는 화려한 그래프를 그리는 기술적 연습이 아니라, 디지털 데이터가 가진 편향성과 빈틈을 읽어내는 인문학적 훈련이었다. 비록 아쉬움은 남지만, ‘보이지 않는 것을 보려 했던’ 이 시도가 훗날 동양의 데이터를 디지털 세상에 온전히 복원하는 연구의 밑거름이 될 것이라 생각한다.
참고자원
(내용 서술)
연구 후기 및 학우들의 감상
신서령 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 연구 소감을 남겨주세요)
박승정 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
김태현 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
강현지 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
황시아 (👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
최다혜 (🇬🇧🇨🇳🇬🇧🇨🇳🇬🇧🇨🇳🇬🇧🇨🇳👍🏻👍🏻👍🏻👍🏻)
(데이터 분석을 잘하시고 결과를 잘 보여주신듯 합니다. 결과 해석부분들의 내용이 흥미롭고 재밌었습니다.)
김성산 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
정윤환 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
김은지 (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
YEFENG (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
QUAN (😭🤪😭🤪😭🤪😭🤪👍🏻👍🏻👍🏻👍🏻)
(이곳에 학우의 연구에 대한 감상을 남겨주세요)
주석