행위

RCCTD WikiDataCuration03

CNUDH

KTH22CNU (토론 | 기여)님의 2025년 12월 2일 (화) 14:09 판 (→‎1부, 2부리그 분석)

데이터로 읽는 중국문화(강의) 페이지로 가기



중국 축구의 현대적 발전 과정

:중국 축구 리그·대표팀·유소년 시스템 및 발전 과정

김태현





목차

Contents

연구배경 연구목적 대상주제 쿼리작성 결과해석 참고자원



연구배경


(내용 서술)


연구목적


(내용 서술)


대상주제


(내용 서술)


쿼리작성



중국 축구 인물 전체적인 풀

중국 국적을 가진 사람 중에서 축구선수 또는 축구감독은 누구이며 이들의 소속 팀은 무엇인가?
SELECT ?person ?personLabel ?team ?teamLabel ?occupation ?occupationLabel WHERE { 

?person wdt:P27 wd:Q148.            # 중국 국적
?person wdt:P106 ?occupation.        # 직업
FILTER (?occupation IN (wd:Q937857,wd:Q628099))   # 선수/감독
OPTIONAL { ?person wdt:P54 ?team }    # 소속 팀 (있을 경우만)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh".}}
LIMIT 200

->중국 축구 분석의 출발점이 되는 전체 인물 풀을 확보.

중국 국적의 축구선수 또는 축구감독 중에서, 1994년 이후에 출범한 축구 리그에 속한 팀에서 활동한 적이 있는 사람은 누구인가?
SELECT ?person ?personLabel ?team ?teamLabel ?league ?leagueLabel ?occupation ?occupationLabel WHERE { 

 ?person wdt:P27 wd:Q148 .          # 중국 국적
 ?person wdt:P106 ?occupation .     # 직업
 FILTER (?occupation IN (wd:Q937857, wd:Q628099))    # 선수/감독

 ?person wdt:P54 ?team .            # 소속 팀
 ?team wdt:P118 ?league .           # 클럽이 속한 리그
 ?league wdt:P571 ?leagueStart .    # 리그 성립 시점(개시 시기)

 FILTER (YEAR(?leagueStart) >= 1994)  # 1994년 이후 시작된 리그만 선택

 SERVICE wikibase:label {bd:serviceParam wikibase:language "ko, zh, en" .}}
 LIMIT 200

->현대 중국 프로축구 체제(1994~)의 인물들만 추림.

출생 연도·출생지

중국 축구선수들의 출생연도와 출생지는 무엇인가?
SELECT ?person ?personLabel ?birth ?birthplace ?birthplaceLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 OPTIONAL { ?person wdt:P569 ?birth. }        # 출생
 OPTIONAL { ?person wdt:P19 ?birthplace. }    # 출생지
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
 LIMIT 200

->세대·지역 분포 분석을 위한 기본 정보를 확보.

1980~2009년 출생 중국 축구선수는 누구인가?
SELECT ?person ?personLabel ?birth WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P569 ?birth.                     # 출생
 FILTER (YEAR(?birth) >= 1980 && YEAR(?birth) < 2010)   # 1980~2009
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
 LIMIT 200

->현대 중국 축구의 핵심 세대(80~00년대생)를 구분하기 위해.

연령별 대표팀 구조(U17/U20/U23/A대표)

중국 U-17 대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q3589928.                 # U-17
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}

->U-17 대표팀이 형성하는 가장 어린 국가대표 세대를 파악하기 위해.

중국 U-20 대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q5100058.                 # U-20
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}

->유망주 핵심 집단인 U-20 세대의 주요 선수를 확인하기 위해.

중국 U-23 대표팀(올림픽대표) 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q987926.                  # U-23
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}

->성인 대표팀으로 이어지는 U-23(올림픽대표) 핵심 세대를 보기 위해.

중국 A대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q130582.                  # A대표
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}

->중국 축구 최상위 실력자(A대표) 그룹을 파악하기 위해.

2025년 기준으로 중국 U-23(올림픽대표) 대표팀에서 현재 활동 중인 선수들을 TreeMap으로 시각화.
#defaultView:TreeMap
SELECT ?teamLabel ?athleteLabel WHERE { 

 ?athlete wdt:P31 wd:Q5;                    # 인간
          wdt:P27 wd:Q148;                  # 중국 국적
          wdt:P106 wd:Q937857.              # 축구선수

 # 대표팀(U-23) 소속 기간 
 ?athlete p:P54 ?ntStatement.
 ?ntStatement ps:P54 wd:Q987926.            # 중국 U-23 대표팀
 OPTIONAL { ?ntStatement pq:P580 ?ntStart. }# 대표팀 시작일
 OPTIONAL { ?ntStatement pq:P582 ?ntEnd. }  # 대표팀 종료일

 # 2025년 현재 U-23에 해당
 FILTER ( !BOUND(?ntStart) || YEAR(?ntStart) <= 2025 )
 FILTER ( !BOUND(?ntEnd)   || YEAR(?ntEnd)   >= 2025 )

 # 클럽 소속 기간(현재 클럽만) 
 ?athlete p:P54 ?clubStatement.
 ?clubStatement ps:P54 ?team.               # 소속 팀
 ?team wdt:P31 wd:Q476028.                  # 축구 클럽(국가대표팀 등 제외)

 OPTIONAL { ?clubStatement pq:P580 ?clubStart. } # 클럽 합류일
 OPTIONAL { ?clubStatement pq:P582 ?clubEnd. }   # 클럽 퇴단일

 # 2025년 현재 클럽에 해당
 FILTER ( !BOUND(?clubStart) || YEAR(?clubStart) <= 2025 )
 FILTER ( !BOUND(?clubEnd)   || YEAR(?clubEnd)   >= 2025 )

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}



2025년 기준으로 중국 A대표팀에서 활동 중인 선수들을 TreeMap으로 시각화.
#defaultView:TreeMap
SELECT ?teamLabel ?athleteLabel WHERE { 

 ?athlete wdt:P31 wd:Q5;                    # 인간
          wdt:P27 wd:Q148;                  # 중국 국적
          wdt:P106 wd:Q937857.              # 축구선수

 # A대표팀 소속 기간 조건
 ?athlete p:P54 ?ntStatement.
 ?ntStatement ps:P54 wd:Q130582.            # 중국 A대표팀
 OPTIONAL { ?ntStatement pq:P580 ?ntStart. }# 대표팀 시작일
 OPTIONAL { ?ntStatement pq:P582 ?ntEnd. }  # 대표팀 종료일

 # 2025년 현재도 대표팀 소속
 FILTER ( !BOUND(?ntStart) || YEAR(?ntStart) <= 2025 )
 FILTER ( !BOUND(?ntEnd)   || YEAR(?ntEnd)   >= 2025 )

 # 2025년 기준 '현 소속 클럽'
 ?athlete p:P54 ?clubStatement.
 ?clubStatement ps:P54 ?team.               # 소속 클럽
 ?team wdt:P31 wd:Q476028.                  # 클럽(국가대표팀 제외)

 OPTIONAL { ?clubStatement pq:P580 ?clubStart. } # 클럽 합류일
 OPTIONAL { ?clubStatement pq:P582 ?clubEnd. }   # 클럽 퇴단일

 # 2025년 현재 클럽에 해당
 FILTER ( !BOUND(?clubStart) || YEAR(?clubStart) <= 2025 )
 FILTER ( !BOUND(?clubEnd)   || YEAR(?clubEnd)   >= 2025 )

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}



1부, 2부리그 분석

중국 1~2부 클럽의 구장은 어디에 위치에 있는가?
SELECT ?stadium ?stadiumLabel ?place ?placeLabel ?location WHERE { 

 ?team wdt:P118 wd:Q209318.          # 1부
 ?team wdt:P115 ?stadium.            # 홈경기장
 ?stadium wdt:P31 wd:Q483110.        # 경기장
 ?stadium wdt:P17 wd:Q148.           # 중국
 OPTIONAL { ?stadium wdt:P131 ?place. }    # 지역
 OPTIONAL { ?stadium wdt:P625 ?location. } # 좌표
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}

->1부(슈퍼리그) 경기장 + 위치.

#defaultView:Map
SELECT ?stadium ?stadiumLabel ?coord ?clubLabel WHERE { 

 ?club wdt:P118 wd:Q209318;   # 리그: 중국 슈퍼리그)
       wdt:P115 ?stadium.    # 홈 구장(경기장)
 ?stadium wdt:P625 ?coord.   # 경기장 좌표

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}

->1부(슈퍼리그) 경기장의 위치를 디지털 지도에 매핑.

SELECT ?stadium ?stadiumLabel ?place ?placeLabel ?location WHERE { 

 ?team wdt:P118 wd:Q1207912.         # 2부
 ?team wdt:P115 ?stadium.            # 홈경기장
 ?stadium wdt:P31 wd:Q483110.        # 경기장
 ?stadium wdt:P17 wd:Q148.           # 중국
 OPTIONAL { ?stadium wdt:P131 ?place. }    # 지역
 OPTIONAL { ?stadium wdt:P625 ?location. } # 좌표
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}

->2부(갑급리그) 경기장 + 위치.

#defaultView:ImageGrid
SELECT ?stadium ?stadiumLabel ?image WHERE { 

 ?club wdt:P118 wd:Q209318.     # 중국 슈퍼리그
 ?club wdt:P115 ?stadium.       # 홈 구장
 ?stadium wdt:P18 ?image.       # 이미지가 있는 경기장만
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}

->1부(슈퍼리그) 경기장 이미지.

중국 슈퍼리그(CSL) 시즌별 우승 팀은 어디인가?
SELECT ?season ?seasonLabel ?winner ?winnerLabel ?date WHERE { 

 ?season wdt:P3450 wd:Q209318.                # 중국 슈퍼리그
 ?season wdt:P1346 ?winner.                   # 우승 팀
 OPTIONAL { ?season wdt:P585 ?date. }         # 시점
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
 ORDER BY ?date

->중국 프로축구의 시즌별 우승 팀을 구분.

2000년 이후 중국 슈퍼리그(CSL)에서 가장 많이 우승한 팀은 어디인가?
#defaultView:BarChart
SELECT ?winnerLabel (COUNT(?season) AS ?titles) WHERE { 

 ?season wdt:P3450 wd:Q209318;   # 중국 슈퍼리그의 각 시즌
         wdt:P1346 ?winner;      # 시즌 우승 팀
         wdt:P585 ?date.         # 시즌 시점 (대부분 연도 단위)
 
 FILTER (YEAR(?date) >= 2000)    # 2000년 이후 시즌만 포함

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
 GROUP BY ?winnerLabel
 ORDER BY DESC(?titles)

->2000년대 이후 CSL 우승 횟수가 가장 많은 팀을 바 차트로 출력.

수용 인원이 큰 홈 경기장을 사용하는 클럽일수록 중국 슈퍼리그(CSL) 우승을 더 많이 차지했는가?
#defaultView:ScatterChart
SELECT ?capacity ?titles ?clubLabel WHERE { 

 # 1단계: 클럽별 중국 슈퍼리그 우승 횟수 집계
 {
   SELECT ?club (COUNT(?season) AS ?titles)
   WHERE {
     ?season wdt:P3450 wd:Q209318;  # 중국 슈퍼리그
             wdt:P1346 ?club.       # 시즌 우승 팀
   }
   GROUP BY ?club
 }

 # 2단계: 각 클럽의 홈구장 수용 인원 가져오기
 ?club wdt:P115 ?stadium.          # 홈 경기장
 ?stadium wdt:P1083 ?capacity.     # 경기장 수용 인원

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}

->수용 인원이 큰 홈 경기장을 사용하는 클럽일수록 중국 슈퍼리그(CSL) 우승을 더 많이 차지했는지 스캐터 차트로 출력.

그래프로 출력.
#defaultView:Graph



결과해석


(내용 서술)


참고자원


(내용 서술)


주석






원본 주소 "https://dh.aks.ac.kr/~cnudh/wiki/index.php?title=RCCTD_WikiDataCuration03&oldid=24472"