행위

RCCTD(2025)WikiDataQueries

CNUDH

JSH CNUGrad (토론 | 기여)님의 2025년 11월 17일 (월) 15:38 판 (→‎⑤ 당나라와 관련된 유적·공간 찾아 지도에 그리기)

데이터로 읽는 중국문화(강의) 페이지로 가기



WikiData Query 샘플

: 중국 문화를 중심으로



목차

Contents

인물 관련 질의어 사건 관련 질의어 장소 관련 질의어 문화유산 관련 질의어 조합



Person


① 한글 명칭으로 특정 인물(예:마오쩌둥) 찾기


SELECT ?person ?personLabel
WHERE {
?person rdfs:label "마오쩌둥"@ko.
SERVICE wikibase:label { bd:serviceParam wikibase:language
"[AUTO_LANGUAGE],ko,en". }
}


② 기본 정보(생몰년, 출생지)를 포함한 당나라 시대 사람들 찾기


SELECT ?person ?personLabel ?birth ?death ?birthplaceLabel ?occupationLabel
WHERE {
?person wdt:P27 wd:Q9683.      # 국적: 당나라

OPTIONAL { ?person wdt:P569 ?birth. }
OPTIONAL { ?person wdt:P570 ?death. }
OPTIONAL { ?person wdt:P19 ?birthplace. }
OPTIONAL { ?person wdt:P106 ?occupation. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }
}
LIMIT 100

국적이 '당나라'(Q9683)인 인물 100명을 찾아, 그들의 이름, 생년월일, 사망일, 출생지, 직업 정보를 표로 만들어 달라


③ 당나라 국적 인물들의 문학 작품 목록 찾기


SELECT ?person ?personLabel ?bookLabel
WHERE {

?person wdt:P27 wd:Q9683 .
?book wdt:P31 wd:Q7725634 ;
wdt:P50 ?person .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}

국적이 ‘당나라’(Q9683)인 인물이 저자인(P50) 문학작품(Q7725634)을 찾아달라


④ 당나라 인물의 출생지 좌표 보기


SELECT ?place ?placeLabel (COUNT(?person) AS ?count) ?location
WHERE {

?person wdt:P31 wd:Q5 ;
wdt:P19 ?place ;
wdt:P27 wd:Q9683 .
OPTIONAL { ?place wdt:P625 ?location }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}
GROUP BY ?place ?placeLabel ?location
LIMIT 1000

국적(P27)이 당나라(Q9683) 사람인 사람들의 출생지(P19)와 그 좌표(P625)를 보여달라


⑤ 당나라 인물 중, 시인 아버지를 둔 정치인 아들 찾기


SELECT ?person ?personLabel
WHERE {

?person wdt:P27 wd:Q9683 .
?person wdt:P22 ?father ;
wdt:P106 wd:Q82955 .
?father wdt:P27 wd:Q9683 .
?father wdt:P106 wd:Q49757 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}

당나라(Q9683) 인물 중, 아버지의 직업이 시인(Q49757)이고, 아들의 직업이 정치인(Q82955)인 사람을 보여달라


⑥ 1950년 이후의 드라마와 영화에 가장 많이 출연한 인물 찾기


#defaultView:BubbleChart
SELECT ?person (COUNT(?work) AS ?count) ?personLabel
WHERE {

VALUES ?type { wd:Q11424 wd:Q5398426 }     # ?type 변수는 {   } 안에 있는 값이다
?work wdt:P31 ?type.
?work wdt:P577 ?date.
FILTER (YEAR(?date) >= 1950)     # ?date 변수의 값이 1950 이상인 것만 필터링한다
?work wdt:P161 ?person.
?person wdt:P27 wd:Q148.
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, ko, en". }
}

GROUP BY ?person ?personLabel    # ?person ?personLabel의 값이 동일한 걸로 묶는(그룹화 한)다
ORDER BY DESC(?count)
LIMIT 50

1950년 이후에 제작된 중국(Q148) 국적의 배우가 출연한 영화(Q11424) 또는 TV 시리즈(Q5398426)의 수를 세어, 작품 수가 많은 순서대로 상위 50명의 배우 목록을 버블 차트로 보여달라



Event


① 예제 '최근 일어난 사건들'을 활용한 기본적인 쿼리


SELECT ?event ?eventLabel ?date
WHERE {

?event wdt:P31/wdt:P279* wd:Q1190554 .
OPTIONAL { ?event wdt:P585 ?date. }
OPTIONAL { ?event wdt:P582 ?date. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ko, zh, en" . }
}

LIMIT 10



② 중국에서 발생한 역사적 사건 찾기


SELECT ?event ?eventLabel ?place ?placeLabel
WHERE {

?event wdt:P31/wdt:P279* wd:Q1190554 .    #역사적 사건 또는 그 하위 개념
?event wdt:P276 ?place .    #장소(위치)
?place wdt:P17 wd:Q148 .    #중국에 있는 장소
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ko, zh, en" . }
}

LIMIT 20





③ 당나라 수도와 시기 찾기


SELECT ?itemLabel ?capitalLabel ?startTime ?endTime
WHERE {

VALUES ?item { wd:Q9683 }
OPTIONAL { ?item wd:P36 ?capital . }     #수도
OPTIONAL { ?item wd:P580 ?startTime . }     #시작일
OPTIONAL { ?item wd:P36 ?endTime . }     #종료일
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}


④(당나라 시기(618-907) 찾은 후) 당나라 때의 사건만 골라내기


SELECT ?event ?eventLabel ?date
WHERE {

?event wdt:P31/wdt:P279* wd:Q1190554 .
OPTIONAL { ?event wdt:P585 ?date. }     #특정 시점이 있는 사건
FILTER( ?date >= "0618-01-01T00:00:00Z"^^xsd:dateTime &&
?date < "0910-01-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ko, zh, en" . }

}

ORDER BY ASC(?date)
LIMIT 50

⑤ 당나라와 관련된 유적·공간 찾아 지도에 그리기


i) 중국과 관련된 유적·공간 찾기


#defaultView:Map
SELECT ?site ?siteLabel ?coord ?heritageLabel
WHERE {

?site wdt:P31/wdt:P279* wd:Q839954 ;     #고고학 유적지 / 역사적 장소 계열 (예: archaeological site)
wdt:P17 wd:Q148 ;     #중국에 있는
wdt:P625 ?coord .     #좌표가 있는
OPTIONAL { ?site wdt:P1435 ?heritage. }     #(있다면) 문화재 지정
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ko, zh, en" . }

}
LIMIT 200

i) 중국과 관련된 유적·공간 찾기


SELECT ?site ?siteLabel ?coord
WHERE {

?site wdt:P234 wd:Q9683 .     # ?site의 시간대가 '당나라'
OPTIONAL { ?site wdt:P625 ?coord .}     #좌표가 있는 것만
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ko, zh, en" . }

}
LIMIT 200


Place



① 중국의 2000m 이상의 산과 봉우리 찾기


#defaultView:Map
SELECT ?mountaintap ?mountaintapLabel ?tapPoint ?altitude
WHERE {

VALUES ?type { wdt:Q8502 wd:Q207326 }
?mountaintap wdt:P31 ?type;
p:P2044/psn:P2044/wikibase:quantityAmount ?altitude;
wdt:P17 wd:Q148;
wdt:P625 ?tapPoint.
FILTER (?altitude >= 2000)
SERVICE wikibase:label {bd:serviceParam wikibase:language "ko, zh, en".}
}


중국(Q148)에 있는 '산'(Q8502) 또는 '산맥'(Q207326) 중에서, 해발 고도가 2,000미터 이상인 모든 장소를 찾아 지도에 표시해 달라

② 당나라 인물들의 출생지별 좌표맵 찾기


#defaultView:Map
SELECT  ?birthplace ?birthplaceLabel (COUNT(DISTINCT?person)AS ?count ) (SAMPLE (?coordinates) AS ?location)
WHERE {

?person wdt:P27 wd:Q9683;    #당나라 사람
wdt:P19 ?birthplace.    #출생지
?birthplace wdt:P625 ?coordinates.
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }

}
GROUP BY ?birthplace ?birthplaceLabel
ORDER BY DESC(?count)
LIMIT 100

당나라(Q9683) 사람들의 출생지를 집계하여, 출생지별 인원수가 많은 순서대로 상위 100곳을 지도에 표시해 달라

③ 당나라 인물들의 개별 출생지 좌표맵


#defaultView:Map
SELECT  ?person ?personLabel ?birthplace ?birthplaceLabel ?coordinates
WHERE {

?person wdt:P27 wd:Q9683;    # 당나라 사람
wdt:P19 ?birthplace.    # 출생지
?birthplace wdt:P625 ?coordinates.
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }

}
LIMIT 100    # 너무 많으면 느려질 수 있으니 100명으로 제한

당나라(Q9683) 사람 100명을 찾아, 각 인물의 출생지를 지도에 표시해 달라

CulturalHeritage


① 유네스코 세계유산에 등재된 중국의 문화재 찾기


#defaultView:ImageGrid
SELECT ?heritage ?heritageLabel (SAMPLE (?location) AS ?Location) (SAMPLE (?image) AS ?Image)
WHERE {

?heritage wdt:P1435 wd:Q9259.
VALUES ?china { wd:Q148 wd:Q29520 }
?heritage wdt:P17 ?china;
wdt:P625 ?location.
OPTIONAL { ?heritage wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, en". }

}
GROUP BY ?heritage ?heritageLabel

중화인민공화국(Q148)과 중화민국(Q29520, 대만)에 있는 모든 유네스코 세계유산(Q9259)을 찾아, 그 이미지들을 이미지 그리드(격자) 뷰로 보여달라

② 당나라 황제의 무덤과 능묘의 이미지, 좌표 찾기


SELECT ?tomb ?tombLabel ?coordinates ?emperorLabel
WHERE {

?emperor p:P39 ?position.     #?emperor가 ?position을 가진다
?position ps:P39 wd:Q268218.     #?position은 중국의 황제다
?position pq:P1001 wd:Q9683.     #?position의 관할권은 당나라다
?emperor wdt:P119 ?tomb.
?tomb wdt:P625 ?coordinates.

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}

당나라(Q9683) 황제들의 묘지(무덤)를 찾아, 그 묘지의 이름, 좌표, 그리고 해당 황제의 이름을 표로 만들어 달라

Combination



① 당나라 시인과 그의 대표작 찾기


SELECT ?poet ?poetLabel ?work ?workLabel
WHERE {

?poet wdt:P27 wd:Q9683;
wdt:P106 wd:Q49757.
OPTIONAL { ?poet wdt:P800 ?work. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh,en". }

}
LIMIT 50


원본 주소 "https://dh.aks.ac.kr/~cnudh/wiki/index.php?title=RCCTD(2025)WikiDataQueries&oldid=23486"