행위

RCCTD(2025)WikiDataQueries

CNUDH

JSH CNUGrad (토론 | 기여)님의 2025년 11월 13일 (목) 00:58 판 (→‎③ 당나라 국적 인물들의 문학 작품 목록 찾기)

데이터로 읽는 중국문화(강의) 페이지로 가기



WikiData Query 샘플

: 중국 문화를 중심으로



목차

Contents

인물 관련 질의어 사건 관련 질의어 장소 관련 질의어 문화유산 관련 질의어 조합



Person


① 한글 명칭으로 특정 인물(예:마오쩌둥) 찾기


SELECT ?person ?personLabel
WHERE {
?person rdfs:label "마오쩌둥"@ko.
SERVICE wikibase:label { bd:serviceParam wikibase:language
"[AUTO_LANGUAGE],ko,en". }
}


② 기본 정보(생몰년, 출생지)를 포함한 당나라 시대 사람들 찾기


SELECT ?person ?personLabel ?birth ?death ?birthplaceLabel ?occupationLabel
WHERE {
?person wdt:P27 wd:Q9683.      # 국적: 당나라

OPTIONAL { ?person wdt:P569 ?birth. }
OPTIONAL { ?person wdt:P570 ?death. }
OPTIONAL { ?person wdt:P19 ?birthplace. }
OPTIONAL { ?person wdt:P106 ?occupation. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }
}
LIMIT 100

국적이 '당나라'(Q9683)인 인물 100명을 찾아, 그들의 이름, 생년월일, 사망일, 출생지, 직업 정보를 표로 만들어 달라


③ 당나라 국적 인물들의 문학 작품 목록 찾기


SELECT ?person ?personLabel ?bookLabel
WHERE {

?person wdt:P27 wd:Q9683 .
?book wdt:P31 wd:Q7725634 ;
wdt:P50 ?person .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}

국적이 ‘당나라’(Q9683)인 인물이 저자인(P50) 문학작품(Q7725634)을 찾아달라


④ 당나라 인물의 출생지 좌표 보기


SELECT ?place ?placeLabel (COUNT(?person) AS ?count) ?location
WHERE {

?person ?wdt:P31 wd:Q5 ;
wdt:P19 ?place ;
wdt:P27 wd:Q9683 .
OPTIONAL { ?place wdt:P625 ?lacation }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}
GROUP BY ?place ?placeLabel ?location
LIMIT 1000



⑤ 당나라 인물 중, 시인 아버지를 둔 정치인 아들 찾기


SELECT ?place ?placeLabel
WHERE {

?person wdt:P27 wd:Q9683 .
?person wdt:P22 ?father ;
wdt:P106 wd:Q82955 .
?father wdt:P27 wd:Q9683 .
?father wdt:P106 wd:Q49757 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}



⑥ 1950년 이후의 드라마와 영화에 가장 많이 출연한 인물 찾기


#defaultView:BubbleChart
SELECT ?person (COUNT(?work) AS ?count) ?personLabel
WHERE {

VALUES ?type { wd:Q11424 wd:Q5398426 }
?work wdt:P31 ?type.
?work wdt:P577 ?date.
FILTER (YEAR(?date) >= 1950)
?work wdt:P161 ?person.
?person wdt:P27 wd:Q148.
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, ko, en". }
}

GROUP BY ?person ?personLabel
ORDER BY DESC(?count)
LIMIT 50

1950년 이후에 제작된 중국(Q148) 국적의 배우가 출연한 영화(Q11424) 또는 TV 시리즈(Q5398426)의 수를 세어, 작품 수가 많은 순서대로 상위 50명의 배우 목록을 버블 차트로 보여달라


Event


① 중국에서 발생한 운동(Campaign) 찾기


SELECT  ?campaign ?campaignLabel ?start ?end
WHERE {

?campaign wdt:P31/wdt:P279* wd:Q6056746;
wdt:P17 wd:Q148.
OPTIONAL { ?campaign wdt:P580 ?start. }
OPTIONAL { ?campaign wdt:P582 ?end. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }
}


국가가 '중국'(Q148)으로 지정된 '캠패인'(Q6056746, 및 그 하위 분류 포함)을 모두 찾아, 그 이름과 시작일, 종료일 정보를 표로 만들어 달라

② 당나라의 주요 사건을 타임라인으로 보기


#defaultView:Timeline
SELECT ?event ?eventLabel ?date ?image
WHERE {

?event wdt:P585 ?date.   #특정 시점
?event wdt:P17|wdt:P276/wdt:P17 wd:Q148.    #중국 관련
FILTER(YEAR(?date) >= 618 && YEAR(?date) <= 907)    # 당나라 시기
OPTIONAL { ?event wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }
}

ORDER BY ?date

당나라 시대(618년~907년) 동안 중국(Q148)에서 발생했거나 중국과 관련된 사건들을 찾아, 시간순으로 정렬된 타임라인으로 보여달라


Place



① 중국의 2000m 이상의 산과 봉우리 찾기


#defaultView:Map
SELECT ?mountaintap ?mountaintapLabel ?tapPoint ?altitude
WHERE {

VALUES ?type { wdt:Q8502 wd:Q207326 }
?mountaintap wdt:P31 ?type;
p:P2044/psn:P2044/wikibase:quantityAmount ?altitude;
wdt:P17 wd:Q148;
wdt:P625 ?tapPoint.
FILTER (?altitude >= 2000)
SERVICE wikibase:label {bd:serviceParam wikibase:language "ko, zh, en".}
}


중국(Q148)에 있는 '산'(Q8502) 또는 '산맥'(Q207326) 중에서, 해발 고도가 2,000미터 이상인 모든 장소를 찾아 지도에 표시해 달라

② 당나라 인물들의 출생지별 좌표맵 찾기


#defaultView:Map
SELECT  ?birthplace ?birthplaceLabel (COUNT(DISTINCT?person)AS ?count ) (SAMPLE (?coordinates) AS ?location)
WHERE {

?person wdt:P27 wd:Q9683;    #당나라 사람
wdt:P19 ?birthplace.    #출생지
?birthplace wdt:P625 ?coordinates.
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }

}
GROUP BY ?birthplace ?birthplaceLabel
ORDER BY DESC(?count)
LIMIT 100

당나라(Q9683) 사람들의 출생지를 집계하여, 출생지별 인원수가 많은 순서대로 상위 100곳을 지도에 표시해 달라

③ 당나라 인물들의 개별 출생지 좌표맵


#defaultView:Map
SELECT  ?person ?personLabel ?birthplace ?birthplaceLabel ?coordinates
WHERE {

?person wdt:P27 wd:Q9683;    # 당나라 사람
wdt:P19 ?birthplace.    # 출생지
?birthplace wdt:P625 ?coordinates.
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }

}
LIMIT 100    # 너무 많으면 느려질 수 있으니 100명으로 제한

당나라(Q9683) 사람 100명을 찾아, 각 인물의 출생지를 지도에 표시해 달라

CulturalHeritage


① 유네스코 세계유산에 등재된 중국의 문화재 찾기


#defaultView:ImageGrid
SELECT ?heritage ?heritageLabel (SAMPLE (?location) AS ?Location) (SAMPLE (?image) AS ?Image)
WHERE {

?heritage wdt:P1435 wd:Q9259.
VALUES ?china { wd:Q148 wd:Q29520 }
?heritage wdt:P17 ?china;
wdt:P625 ?location.
OPTIONAL { ?heritage wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, en". }

}
GROUP BY ?heritage ?heritageLabel

중화인민공화국(Q148)과 중화민국(Q29520, 대만)에 있는 모든 유네스코 세계유산(Q9259)을 찾아, 그 이미지들을 이미지 그리드(격자) 뷰로 보여달라

② 당나라 황제의 무덤과 능묘의 이미지, 좌표 찾기


SELECT ?tomb ?tombLabel ?coordinates ?emperorLabel
WHERE {

?emperor p:P39 ?position.     #?emperor가 ?position을 가진다
?position ps:P39 wd:Q268218.     #?position은 중국의 황제다
?position pq:P1001 wd:Q9683.     #?position의 관할권은 당나라다
?emperor wdt:P119 ?tomb.
?tomb wdt:P625 ?coordinates.

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}

당나라(Q9683) 황제들의 묘지(무덤)를 찾아, 그 묘지의 이름, 좌표, 그리고 해당 황제의 이름을 표로 만들어 달라

Combination



① 당나라 시인과 그의 대표작 찾기


SELECT ?poet ?poetLabel ?work ?workLabel
WHERE {

?poet wdt:P27 wd:Q9683;
wdt:P106 wd:Q49757.
OPTIONAL { ?poet wdt:P800 ?work. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "zh,en". }

}
LIMIT 50


원본 주소 "https://dh.aks.ac.kr/~cnudh/wiki/index.php?title=RCCTD(2025)WikiDataQueries&oldid=22994"