"RCCTD(2026)Report04"의 두 판 사이의 차이

2026년 10월 21일 (수) 13:59 판

중국 바둑의 황금기와 변화

- 1988년 이후 한·중 세계대회 우승 양상 비교를 중심으로-

사학과 송영준

연구배경

바둑은 고대 중국에서 기원한 것으로 알려진 전통 보드게임으로, 사마천의 「사기(史記)」 속에도 주나라 시기 바둑에 대한 언급이 있다는 점에서, 최소 3000년 이상의 역사를 지닌 중국 유구의 마인드 스포츠이다. 특히 중국에서 바둑은 선비의 필수 교양으로 여겨진 금기서화(琴棋書畵) 중 하나로, 단순한 오락을 넘어 예술과 주요 문화로 인식돼 왔다.

오늘날에도 바둑은 종주국인 중국에서 인기 있는 종목이다. 중국의 바둑 인구는 약 6000만명으로, 900만 명 전후인 한국의 7배에 달한다. 비공인 세계랭킹인 고레이팅(GoRating)에 따르면, 2026년 10월 12일 기준 세계랭킹 1위부터 20위까지 중국 기사가 15명에 이를 정도로 중국은 가장 두터운 선수층을 보유한 국가이기도 하다.

그러나 압도적인 양적 우세에도 불구하고, 중국은 오랫동안 세계 대회에서 한국에 밀린다는 평가를 받아왔다. 바둑의 인기가 절정이던 90년대~2000년대의 세계대회는 이창호, 조훈현, 유창혁, 이세돌로 대표되는 한국 선수들이 세계대회를 휩쓸었다. 이러한 상황 속에서 중국은 2010년대 한·일 바둑계를 압도하며 동아시아 3국의 바둑 패권을 장악했다. 이 시기를 이른바 '중국 바둑의 황금기'라고 부른다. 이후로도 중국 바둑계는 성장을 거듭하며, 현재까지 바둑 패권을 두고 한국과 팽팽히 맞서고 있다.

주목할 점은 소수의 강자가 오랜 기간 동안 집중적으로 우승을 차지해 온 한국 바둑계와 달리, 중국 바둑계는 수많은 기사가 세계대회를 번갈아 우승하는 선수층의 차이를 보인다는 점이다. 특히 황금기엔 90년대생 신예 기사들이 세계 정상에 오르며 세대 교체가 이루어졌는데, 이는 중국 바둑계의 여러 역사, 문화적 배경에서 기인한다고 추론할 수 있다.

이러한 중국 바둑계의 변화를 확인하기 위해선 1988년 이후 진행된 세계대회 기록과 기사들의 인적 데이터를 연결해야 한다. 기존의 바둑 기록은 세계대회 기록과 인적 데이터를 별개로 다뤘지, 입체적으로 연결하는 시도는 부족했다. 따라서 본 연구는 위키데이터의 다양한 데이터를 통해, 세계대회 우승자의 국적, 연령, 출생지(학습 도장) 등을 세계대회 우승과 연결하여 시각화 하고자 한다.
이는 바둑을 매개로 중국 문화를 이해하고, 나아가 동아시아 3국 간 문화적 공감대와 유대감을 넓히는 시도가 될 것이다.

연구목적

상단으로 이동

1.) 메이저 세계바둑대회 우승 기록 데이터화
1988년 세계대회 출범 이후 현재까지의 우승 기록을 위키데이터 쿼리를 통해 추출한다. 제한기전과 메이저 세계대회를 구분하고, 대회 정보를 기사의 국적, 스포츠 국적과 연결한다.

2.) 중국 바둑의 황금기 분석
2010년대 중국 바둑에 황금기가 도래한 이유를, 당시 세계대회 우승자를 그들의 출생 연도, 우승 당시 연령, 출생지, 출신 도장 등의 데이터와 연결하여 분석한다.

3.) 결과 분석 및 시각화
위키데이터가 2번까지의 과정을 수행해 줄 수는 있지만, 이 데이터를 기반으로 "왜 중국 바둑의 황금기가 그때 도래했는가?"라는 질문에 답할 순 없다. 따라서 데이터와 기타 자료를 바탕으로 인문학적 소양을 발휘해 위 질문을 해결한다.

또한 데이터 결과를 공간축과 시간축 두 가지로 나눠 시각화한다. 공간축은 우승자의 출생지와 출신 도장을 지도 API에 연결해 어느 지역에서 우승자를 많이 배출했는지를 시간의 흐름과 함께 볼 수 있게 한다. 시간축은 우승자의 출생 연도와 우승 당시 연령을 시계열 그래프로 나타내어, 시간에 따른 국가 간 패권의 이동과 90년대생 젊은 기사의 등장과 활약을 확인할 수 있게 한다.

연구과정

상단으로 이동

1. 프로 바둑기사 데이터 추출

위키데이터에서 직업(P106)이 프로 바둑기사(wd:Q3186699)로 등록된 인물들을 추출한다.

SELECT DISTINCT ?person ?personLabel

WHERE {

  ?person wdt:P106 wd:Q3186699.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh,ja". }

}

2. 한·중·일 바둑기사의 국적 및 스포츠 국적 추출

바둑기사의 국적(P27)과 스포츠 국적(P1532)을 함께 추출한다. 바둑계에는 조치훈과 같이 출신 국적과 실제 소속되어 활동하는 기원(스포츠 국적)이 다른 기사들이 존재하므로 두 속성을 모두 확인할 필요가 있다. 단, 위키데이터에 스포츠 국적(P1532)이 입력되지 않은 기사도 있기에 OPTIONAL을 사용하여 누락을 방지하고, VALUES를 통해 한국(Q884), 중국(Q148), 일본(Q17), 대만(Q865) 국적의 기사로 범위를 한정하였다.

SELECT DISTINCT ?person ?personLabel ?nationalityLabel ?sportCountryLabel

WHERE {

  ?person wdt:P106 wd:Q3186699;

          wdt:P27 ?nationality.

  OPTIONAL { ?person wdt:P1532 ?sportCountry. }

  VALUES ?nationality {

    wd:Q884 # 한국 국적

    wd:Q148 # 중국 국적

    wd:Q17 # 일본 국적

    wd:Q865 # 대만 국적

  }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh,ja". }

}

3. ‘세계바둑대회’ 항목(QID) 탐색

세계대회 우승자를 찾기 위해 먼저 위키데이터 내에서 ‘세계바둑대회’를 뜻하는 항목이 무엇인지 탐색한다. 영어 라벨에 "world Go competition"이 포함된 항목을 검색하여 세계바둑대회(Q10869075)의 QID를 확인하였다.

SELECT DISTINCT ?item ?itemLabel

WHERE {

  ?item rdfs:label ?label.

  FILTER(LANG(?label) = "en")

  FILTER(CONTAINS(LCASE(?label), "world go competition"))

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh,ja". }

}

4. 세계바둑대회(Q10869075)의 하위 대회 분류

3번 쿼리를 통해 확인한 세계바둑대회(Q10869075) 항목의 하위 개념(P279)으로 분류된 대회들을 추출한다. 먼저 조건 없이 전체 하위 대회를 조회한 뒤, 본 연구의 분석 대상인 ‘메이저 세계대회' 만을 남긴다.

SELECT DISTINCT ?competition ?competitionLabel

WHERE {

  ?competition wdt:P279 wd:Q10869075.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh,ja". }

}

위 결과에는 여자·신예·단체전 등 제한기전이 포함되어 있으므로, 아래 쿼리와 같이 FILTER 조건을 추가하여 메이저 개인 세계대회만 필터링한다.

SELECT DISTINCT ?competition ?competitionLabel

WHERE {

  ?competition wdt:P279 wd:Q10869075.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh,ja". }

  # 영어 라벨을 가져와서 제외 키워드 필터링

  OPTIONAL { ?competition rdfs:label ?enLabel. FILTER(LANG(?enLabel) = "en") }

  FILTER(!BOUND(?enLabel) || !REGEX(?enLabel, "Women|Female|Pair|Team|Youth|Junior|Senior|Master|Amateur|Asian|Globis|Bohae Cup|Wu Qingyuan|Senko|Bingsheng|Nongshim|Mind Sports| Zhonghuan| Kuksu| Myungin|Kisei|Tengen|Oza|Honinbo|Judan|Gosei|Meijin|Ryusei|Agon|NEC|CCTV|Changqi|Mingren|Tianyuan|Liguang|Xinan|Longxing|Weifu|Quzhou|烂柯|倡棋|名人|天元|국수|명인|기성|천원|왕좌|본인방|십단|작성", "i"))

  # 한국어/중국어 라벨에서도 제한기전 키워드 제외

  OPTIONAL { ?competition rdfs:label ?koLabel. FILTER(LANG(?koLabel) = "ko") }

  FILTER(!BOUND(?koLabel) || !REGEX(?koLabel, "여자|여성|여류|페어|단체|신예|청소년|시니어|아마추어|아시아|글로비스|보해배|오청원|센코|병성|농심|마인드|중환", "i"))

}

5. 세계대회 회차별 우승자와 우승 연도 추출

위키데이터에서는 대회와 우승자를 연결하는 방식이 단일하지 않고 크게 세 가지 구조로 나뉜다.

방식 A: 개별 회차 항목(예: 제25회 LG배)이 대회 본체의 하위 항목(P31/P361/P179)으로 존재하고, 그 회차 항목에 우승자(P1346)와 시점(P585/P580)이 입력된 경우
방식 B: 대회 본체 항목(예: 응씨배)에 우승자(P1346)가 직접 연결되고, 그 하위 한정자(Qualifier)로 시점(pq:P585)이 입력된 경우
방식 C: 바둑기사 항목에 우승 대회(P2522, victory) 속성으로 대회나 회차가 역방향 입력된 경우

따라서 UNION을 사용하여 세 가지 경로의 데이터를 모두 합집합으로 추출하였다.

SELECT DISTINCT ?year ?competitionLabel ?editionLabel ?personLabel

WHERE {

  # 1. 메이저 세계대회 분류 및 제한기전 제외 (4번 쿼리 조건)

  ?competition wdt:P279* wd:Q10869075.

  OPTIONAL { ?competition rdfs:label ?enLabel. FILTER(LANG(?enLabel) = "en") }

  FILTER(!BOUND(?enLabel) || !REGEX(?enLabel, "Women|Female|Pair|Team|Youth|Junior|Senior|Master|Amateur|Asian|Globis|Bohae Cup|Wu Qingyuan|Senko|Bingsheng|Nongshim|Mind Sports| Zhonghuan| Kuksu| Myungin|Kisei|Tengen|Oza|Honinbo|Judan|Gosei|Meijin|Ryusei|Agon|NEC|CCTV|Changqi|Mingren|Tianyuan|Liguang|Xinan|Longxing|Weifu|Quzhou|烂柯|倡棋|名人|天元|국수|명인|기성|천원|왕좌|본인방|십단|작성", "i"))

  OPTIONAL { ?competition rdfs:label ?koLabel. FILTER(LANG(?koLabel) = "ko") }

  FILTER(!BOUND(?koLabel) || !REGEX(?koLabel, "여자|여성|여류|페어|단체|신예|청소년|시니어|아마추어|아시아|글로비스|보해배|오청원|센코|병성|농심|마인드|중환", "i"))

  # 2. 대회별 우승자 및 시점 추출 (방식 A, B, C 통합)

  {

    # [방식 A] 대회 본체 -> 개별 회차(edition) -> 우승자(P1346)

    ?edition (wdt:P31|wdt:P361|wdt:P179) ?competition.

    ?edition wdt:P1346 ?person.

    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }

  }

  UNION

  {

    # [방식 B] 대회 본체에 직접 우승자(P1346)와 시점 한정자(pq:P585)가 붙은 경우

    ?competition p:P1346 ?winnerStmt.

    ?winnerStmt ps:P1346 ?person.

    OPTIONAL { ?winnerStmt (pq:P585|pq:P580) ?date. }

    BIND(?competition AS ?edition)

  }

  UNION

  {

    # [방식 C] 기사 항목의 우승(P2522) 속성에 대회/회차가 연결된 경우

    ?person wdt:P106 wd:Q3186699;

            wdt:P2522 ?edition.

    ?edition (wdt:P31*|wdt:P361*|wdt:P179*) ?competition.

    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }

  }

  # 우승자가 프로 바둑기사인 경우로 한정 및 연도 추출

  ?person wdt:P106 wd:Q3186699.

  BIND(YEAR(?date) AS ?year)

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh,ja". }

}

ORDER BY ?year ?competitionLabel ?editionLabel

[문제점]
1.) 데이터 누락: 1988년부터 세계대회가 시작되었으나 1991년 이전 초기 대회 기록과 2021년 이후 최근 대회 기록이 다수 누락되어 있으며, 대표적 국가대항전인 ‘농심신라면배’나 2021년 신설된 세계대회인 대회인 ‘취저우 란커배’ 등이 세계바둑대회(Q10869075)의 하위 분류 체계와 다르게 입력되어 출력되지 않는다.
2.) 데이터 중복: 하나의 대회가 해를 넘겨 진행되는 경우, 시점(P585)과 시작 시점(P580)이 모두 입력되어 있으면 동일 회차 우승자가 연도별로 2줄씩 중복 출력되는 현상이 나타난다.
3.) 대회명 표기: 개별 회차 항목이 생성되지 않고 대회 본체에 우승자가 직접 연결된 경우(방식 B·C 일부), ‘삼성화재배 월드 바둑마스터스 – 박정환’이나 ‘잉창치배 – 이치리키 료’와 같이 특정 회차가 아닌 대회명 자체가 표기되는 문제가 발생한다.

6. 세계대회 우승자 데이터와 기사 인적 데이터(출생연도·우승연령·출생지·국적) 결합

5번 쿼리의 세계대회 우승 기록에 2번 쿼리의 국적 정보 및 기사의 출생일(P569), 출생지(P19) 데이터를 결합한다. 나아가 우승 연도(?year)에서 출생 연도(?birthYear)를 빼서 우승 당시 연령(?winAge)을 산출하였다.

?competitionLabel: 세계대회 본체 명칭 (예: LG배, 삼성화재배, 응씨배 등)
?editionLabel: 개별 대회 회차 명칭
?year: 대회 개최(또는 우승) 연도
?personLabel: 우승 기사 성명
?birthYear: 우승 기사의 출생 연도 (P569에서 연도 추출)
?winAge: 우승 당시 연령 (?year - ?birthYear)
?birthPlaceLabel: 우승 기사의 출생지 (P19)
?nationalityLabel: 우승 기사의 국적 (P27)
?sportCountryLabel: 우승 기사의 스포츠 국적 (P1532)

SELECT DISTINCT ?competitionLabel ?editionLabel ?year ?personLabel ?birthYear ?winAge ?birthPlaceLabel ?nationalityLabel ?sportCountryLabel

WHERE {

  # 1. 메이저 세계대회 분류 및 제한기전 제외 (4번 쿼리 조건)

  ?competition wdt:P279* wd:Q10869075.

  OPTIONAL { ?competition rdfs:label ?enLabel. FILTER(LANG(?enLabel) = "en") }

  FILTER(!BOUND(?enLabel) || !REGEX(?enLabel, "Women|Female|Pair|Team|Youth|Junior|Senior|Master|Amateur|Asian|Globis|Bohae Cup|Wu Qingyuan|Senko|Bingsheng|Nongshim|Mind Sports| Zhonghuan| Kuksu| Myungin|Kisei|Tengen|Oza|Honinbo|Judan|Gosei|Meijin|Ryusei|Agon|NEC|CCTV|Changqi|Mingren|Tianyuan|Liguang|Xinan|Longxing|Weifu|Quzhou|烂柯|倡棋|名人|天元|국수|명인|기성|천원|왕좌|본인방|십단|작성", "i"))

  OPTIONAL { ?competition rdfs:label ?koLabel. FILTER(LANG(?koLabel) = "ko") }

  FILTER(!BOUND(?koLabel) || !REGEX(?koLabel, "여자|여성|여류|페어|단체|신예|청소년|시니어|아마추어|아시아|글로비스|보해배|오청원|센코|병성|농심|마인드|중환", "i"))

  # 2. 대회별 우승자 및 시점 추출 (방식 A, B, C 통합)

  {

    ?edition (wdt:P31|wdt:P361|wdt:P179) ?competition.

    ?edition wdt:P1346 ?person.

    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }

  }

  UNION

  {

    ?competition p:P1346 ?winnerStmt.

    ?winnerStmt ps:P1346 ?person.

    OPTIONAL { ?winnerStmt (pq:P585|pq:P580) ?date. }

    BIND(?competition AS ?edition)

  }

  UNION

  {

    ?person wdt:P106 wd:Q3186699;

            wdt:P2522 ?edition.

    ?edition (wdt:P31*|wdt:P361*|wdt:P179*) ?competition.

    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }

  }

  # 3. 우승자 인적 사항 결합 (국적, 스포츠 국적, 출생일, 출생지)

  ?person wdt:P106 wd:Q3186699;

          wdt:P27 ?nationality.

  OPTIONAL { ?person wdt:P1532 ?sportCountry. }

  OPTIONAL { ?person wdt:P569 ?birthDate. }

  OPTIONAL { ?person wdt:P19 ?birthPlace. }

  VALUES ?nationality { wd:Q884 wd:Q148 wd:Q17 wd:Q865 }

  # 4. 연도 및 우승 당시 연령 계산

  BIND(YEAR(?date) AS ?year)

  BIND(YEAR(?birthDate) AS ?birthYear)

  BIND((?year - ?birthYear) AS ?winAge)

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh,ja". }

}

ORDER BY ?year ?competitionLabel ?editionLabel

[향후 2차 연구(기말) 데이터 보완 및 정제 계획]
1차 추출 결과에서 확인된 데이터 누락·중복·표기 불일치 문제를 해결하기 위해, 기말 연구에서는 다음과 같은 정제 작업을 진행할 예정이다.

첫째, 대회 분류 속성에 하위 개념(P279)뿐만 아니라 인스턴스(P31)와 스포츠 시즌(P3450) 경로를 추가하고, 위키데이터 내에서 누락된 초기·최근 대회 및 신설 메이저 대회(취저우 란커배 등), 국가대항전(농심신라면배) 데이터를 한국기원·중국위기협회 공식 기록과 대조하여 보완한다.
둘째, 해를 넘겨 진행되는 대회의 연도 중복 출력 문제를 해결하기 위해 종료 시점(P582)을 우선 반영하거나 GROUP BY와 MAX(?year) 집계를 적용하여 단일 회차당 하나의 최종 우승 연도만 남도록 쿼리를 고도화한다.
셋째, 정제된 최종 데이터셋을 바탕으로 연도별 한·중·일 우승 횟수 추이, 우승 연령 변화, 그리고 중국 우승 기사들의 출생지(P19) 좌표(P625)를 활용한 지역별 분포를 시각화하여 ‘중국 바둑의 황금기’가 지닌 구조적 특징을 입증할 것이다.

참고자원

상단으로 이동

참고자원

상단으로 이동

[현재 연구에 참고한 자료]

1. Wikidata Query Service
- https://query.wikidata.org/

2. 관련 속성

3. 원 출처

  - GoRatings: https://www.goratings.org/
    → 바둑기사의 직업, 종목 특성
  - 한국기원: https://www.baduk.or.kr/
    → 한국기사의 국적, 출생 정보 등 인적 사항
  - 일본기원·관서기원: https://www.nihonkiin.or.jp / https://kansaikiin.jp/
    → 일본기사의 국적, 출생 정보 등 인적 사항
  - 시나바둑: http://sports.sina.com.cn/go/
    → 중국기사의 국적, 출생 정보 등 인적 사항
  - 위키백과: https://zh.wikipedia.org/wiki/%E4%B8%96%E7%95%8C%E5%9B%B4%E6%A3%8B%E5%A4%A7%E8%B5%9B%E5%88%97%E8%A1%A8
    → 세계대회 목록

- 사진 출처: https://sports.sina.com.cn/go/2026-10-16/doc-inivkwti7031200.shtml

[앞으로 조사할 참고자료]

1. 중국 지도 GIS

주석

상단으로 이동

"RCCTD(2026)Report04"의 두 판 사이의 차이

CNUDH

2026년 10월 21일 (수) 13:59 판

목차

Contents

연구배경

연구목적

연구과정

참고자원

참고자원

주석

@@ 32번째 줄: / 32번째 줄: @@
 <br/>
 그러나 압도적인 양적 우세에도 불구하고, 중국은 오랫동안 세계 대회에서 한국에 밀린다는 평가를 받아왔다.
-바둑의 인기가 절정이던 90년대~2000년대는 이창호, 조훈현, 유창혁, 이세돌로 대표되는 한국 선수들이 세계대회를 휩쓸었다.
+바둑의 인기가 절정이던 90년대~2000년대의 세계대회는 이창호, 조훈현, 유창혁, 이세돌로 대표되는 한국 선수들이 세계대회를 휩쓸었다.
 이러한 상황 속에서 중국은 2010년대 한·일 바둑계를 압도하며 동아시아 3국의 바둑 패권을 장악했다. 이 시기를 이른바 '중국 바둑의 황금기'라고 부른다.
 이후로도 중국 바둑계는 성장을 거듭하며, 현재까지 바둑 패권을 두고 한국과 팽팽히 맞서고 있다.