RCCTD WikiDataCuration06

데이터로 읽는 중국문화(강의) 페이지로 가기

중국 영화와 영화산업의 발전양상

: 영광과 딜레마

정윤환

목차

Contents

---

연구배경 연구목적 대상주제 쿼리작성 결과해석 참고자원

---

연구배경

상단으로 이동

(내용 서술)

연구목적

상단으로 이동

(내용 서술)

대상주제

상단으로 이동

(내용 서술)

쿼리작성

상단으로 이동

1. 국제 영화제 수상 중국 감독

국제 영화제에서 상을 타본 적이 있는 중국 영화 감독들을 찾아보자

SELECT ?person ?personLabel ?award ?awardLabel

WHERE {

?person wdt:P27 wd:Q148;          # 중국 국적

        wdt:P106 wd:Q2526255;     # 영화 감독

        wdt:P166 ?award.          # 수상 경력

?award wdt:P31 wd:Q19020.         # 영화제 상

SERVICE wikibase:label {bd:serviceParam wikibase:language "ko, zh, en". }

}

1-1. 국제 영화제 후보 및 사망 여부

국제 영화제에서 후보로 올라간 영화 감독들을 찾아보자. 단, 사망한 인물이면 표시해보자

SELECT ?person ?personLabel ?nominated ?nominatedLabel ?death

WHERE {

?person wdt:P27 wd:Q148;          # 중국 국적

        wdt:P106 wd:Q2526255;     # 영화 감독

        wdt:P1411 ?nominated.     # 후보 경력

?nominated wdt:P31 wd:Q19020.     # 영화제

OPTIONAL {?person wdt:P570 ?death.} # 사망일

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en". }

}

2. 중국 내 영화 촬영지 분석

최근 중국 내에서 영화 촬영지로 사용된 장소들을 분석하여, 촬영된 영화 개수 순으로 정렬(상위 20곳)

SELECT ?place ?placeLabel (COUNT(?film) AS ?count)

WHERE {

?film wdt:P31 wd:Q11424.          # 영화

?film wdt:P915 ?place.            # 촬영지

?place wdt:P17 wd:Q148.           # 촬영지가 중국

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

GROUP BY ?place ?placeLabel

ORDER BY DESC(?count)

LIMIT 20

3. 중국 전국 영화관 지도

중국 전국 영화관을 지도로 보여줘

#defaultView:Map

SELECT ?place ?placeLabel ?location 

WHERE {

?place wdt:P31 wd:Q41253.       # 인스턴스 : 영화관 

?place wdt:P17 wd:Q148.         # 국가 : 중국 

?place wdt:P625 ?location.      # 좌표 

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

4. 영화 감독들의 출생 장소

영화 감독들의 출생 장소를 지도로 보여줘

#defaultView:Map

SELECT ?director ?directorLabel ?birthPlace ?birthPlaceLabel ?location 

WHERE {

?director wdt:P106 wd:Q2526255.   # 직업: 영화 감독 

?director wdt:P19 ?birthPlace.    # 출생지 

?birthPlace wdt:P17 wd:Q148.      # 국가: 중국 

?birthPlace wdt:P625 ?location.   # 좌표 (

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

5. 수상/후보작 영화 이미지 그리드

중국 영화 중 자국 영화제를 제외한 국제 시상식 수상작 혹은 후보작들의 이미지 생성해 줘 

#defaultView:ImageGrid

SELECT DISTINCT ?film ?filmLabel ?image

WHERE {

?film wdt:P31 wd:Q11424;       # 영화

      wdt:P495 wd:Q148;        # 제작 국가: 중국

      wdt:P18 ?image.          # 이미지 



#  상|후보|참여 데이터 찾기

?film wdt:P166|wdt:P1411|wdt:P1344 ?thing.



{

  # [경로 A] 직통 / 소속

  ?thing wdt:P1027|wdt:P361 ?festival. 

}

UNION

{

  # [경로 B] 회차 경유

  ?thing wdt:P1027|wdt:P361 ?edition.

  ?edition wdt:P361 ?festival. 

}

UNION

{

  # [경로 C] 상의 종류(Class)를 통한 간접 연결 (P31 경유)

  ?thing wdt:P31/wdt:P1027 ?festival. 

}



# 중국(Q148) 영화제 제외 

?festival wdt:P17 ?country.

FILTER(?country != wd:Q148)



SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

LIMIT 50

6. 제작비와 흥행 수익 상관관계

중국제작영화들의 제작비와 흥행 수익을 scatter chart에 표시해보자

#defaultView:ScatterChart 

SELECT ?budget ?boxOffice ?film ?filmLabel 

WHERE { 

?film wdt:P31 wd:Q11424;      # 영화 

      wdt:P495 wd:Q148.       # 중국 

OPTIONAL { ?film wdt:P2130 ?budget. }      # 제작비 

OPTIONAL { ?film wdt:P2142 ?boxOffice. }  # 흥행 수익 

FILTER(BOUND(?budget) && BOUND(?boxOffice)) 

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }

6-1. 중국 영화 수익 분석: 내수(Domestic) vs 전세계(Worldwide)

중국 영화 중 내수 수익과 월드와이드 수익 데이터가 모두 있는 상위 30개 작품의 수익 비교

#defaultView:LineChart

SELECT ?filmLabel ?revenue ?placeLabel

WHERE {

  # [1단계] '두 조건'을 모두 만족하는 영화 중 흥행 TOP 30 선정

  {

    SELECT ?film (MAX(?amount) AS ?maxRevenue)

    WHERE {

      ?film wdt:P31 wd:Q11424;        # 영화

            wdt:P495 wd:Q148;         # 국가: 중국

            wdt:P2142 ?amount.        # 수익 금액 (정렬용)

      

      # [조건 1] 중국(Domestic) 수익 데이터 존재

      FILTER EXISTS {

        ?film p:P2142 ?s1.

        ?s1 pq:P3005 wd:Q148;

      }



      # [조건 2] 월드와이드(Worldwide) 수익 데이터 존재

      FILTER EXISTS {

        ?film p:P2142 ?s2.

        ?s2 pq:P3005 wd:Q13780930;

      }

    }

    GROUP BY ?film

    ORDER BY DESC(?maxRevenue)

  }



  # [2단계] 선정된 영화들의 데이터 추출

  ?film p:P2142 ?statement.

  ?statement ps:P2142 ?revenue;

             pq:P3005 ?place;



  # [3단계] 필요한 두 분류만 남기기

  VALUES (?place ?placeLabel) {

    (wd:Q148 "중국(Domestic)")

    (wd:Q13780930 "전세계(Worldwide)")

  }



  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

7. 주요 국제 영화제 수상 및 후보작 현황

 주요 국제 영화제에서 수상했거나 후보에 오른 중국 영화들을 확인해보자

SELECT ?film ?filmLabel ?status ?festival ?festivalLabel ?award ?awardLabel

WHERE {

?film wdt:P31 wd:Q11424;           # 영화

      wdt:P495 wd:Q148.            # 중국

VALUES ?festival { 

  wd:Q42369    # 칸

  wd:Q49024    # 베니스

  wd:Q130871   # 베를린

  wd:Q482633   # 부산

  wd:Q477369   # 상하이

 }

{

   ?film wdt:P166 ?award.           # 수상 경력

   ?award wdt:P1027 ?festival.      # 상의 수여 주체가 위 영화제인 경우

   BIND("수상" AS ?status)

 }

 UNION

 {

   ?film wdt:P1411 ?award.          # 후보 경력

   ?award wdt:P1027 ?festival.      # 상의 수여 주체가 위 영화제인 경우

   BIND("후보" AS ?status)

 }

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

ORDER BY ?filmLabel ?status

7-1. 한·중·일 순수 해외 영화제 실적 추이 (자국 개최 제외)

한·중·일 3국의 자국 영화제를 제외한 해외 영화제 수상 및 후보 성과를 비교해보자

#defaultView:LineChart

SELECT ?yearLabel ?count ?countryLabel

WHERE {

  {

    SELECT ?yearLabel ?country (COUNT(DISTINCT ?thing) AS ?count)

    WHERE {

      VALUES ?country { wd:Q148 wd:Q884 wd:Q17 } 

      

      ?film wdt:P31 wd:Q11424;          # 영화

            wdt:P495 ?country;          # 국가

            wdt:P577 ?pubDate.          # 개봉일

      

      # 기간 설정: 1990년 ~ 2024년

      FILTER(?pubDate >= "1990-01-01"^^xsd:dateTime && 

             ?pubDate <= "2024-12-31"^^xsd:dateTime)

      BIND(STR(YEAR(?pubDate)) AS ?yearLabel)



      ?film wdt:P166|wdt:P1411|wdt:P1344 ?thing. 

      {

      # 여러 경로 탐색: 직통 / 회차 경유 / 소속

      ?thing wdt:P1027|wdt:P361|

             (wdt:P1027/wdt:P361)|

             (wdt:P361/wdt:P361) ?festival. 

      }

       UNION

      {

        # 상의 종류(Class)를 통한 간접 연결 (P31 경유)

        ?thing wdt:P31 ?awardClass. 

        ?awardClass wdt:P1027 ?festival.

      }



      # festival의 국적 확인 및 자국 영화제 제외

      ?festival wdt:P17 ?festCountry.

      

      # 개최국이 한/중/일이 아닌 경우만 

      FILTER(?festCountry != wd:Q148 && 

             ?festCountry != wd:Q884 && 

             ?festCountry != wd:Q17)

    }

    GROUP BY ?yearLabel ?country

  }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }

}

ORDER BY ?yearLabel

8. 국가별 주요 영화제 진출작 트리맵

9개국의 주요 영화제 후보작과 수상작을 출력해줘

#defaultView:TreeMap

SELECT DISTINCT ?countryLabel ?filmLabel

WHERE {

 VALUES ?country {

   wd:Q148    # 중국

   wd:Q142    # 프랑스

   wd:Q145    # 영국

   wd:Q30     # 미국

   wd:Q884    # 대한민국

   wd:Q17     # 일본

   wd:Q38     # 이탈리아

   wd:Q183    # 독일

   wd:Q29     # 스페인

 }

 VALUES ?festival {

   wd:Q42369   # 칸 영화제

   wd:Q49024   # 베니스 영화제

   wd:Q130871  # 베를린 영화제

 }

 ?film wdt:P31 wd:Q11424;        # 인스턴스: 영화

       wdt:P495 ?country.        # 제작 국가

 ?film wdt:P166|wdt:P1411 ?award.

 ?award wdt:P1027 ?festival.

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

LIMIT 1000

9. 최근 30년 중국 영화 제작 편수 추이

중국 영화의 최근 30년(1995~2024) 간 제작 편수 변화를 연도별로 확인해보자

#defaultView:BarChart

SELECT ?yearLabel (COUNT(?film) AS ?count)

WHERE {

 ?film wdt:P31 wd:Q11424;          # 영화

       wdt:P495 wd:Q148;           # 중국

       wdt:P577 ?pubDate.          # 개봉일

 BIND(YEAR(?pubDate) AS ?year)

 FILTER(?year >= 1995 && ?year <= 2024)

 BIND(STR(?year) AS ?yearLabel)

}

GROUP BY ?yearLabel ?year

ORDER BY ?year

10. 중국 영화 장르 분포 (버블 차트)

중국 영화의 장르별 분포를 버블 차트로 확인해보자

#defaultView:BubbleChart

SELECT ?genreLabel (COUNT(?film) AS ?count)

WHERE {

 ?film wdt:P31 wd:Q11424;       # 영화

       wdt:P495 wd:Q148;        # 제작 국가: 중국

       wdt:P136 ?genre.         # 장르

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

GROUP BY ?genreLabel

ORDER BY DESC(?count)

LIMIT 30

11. 주요 영화 제작사 분석

중국 영화 제작사별 제작 편수 순위를 확인해보자

SELECT ?company ?companyLabel (COUNT(?film) AS ?count)

WHERE {

 ?film wdt:P31 wd:Q11424;       # 영화

       wdt:P495 wd:Q148;        # 제작 국가: 중국

       wdt:P272 ?company.       # 제작사

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

GROUP BY ?company ?companyLabel

ORDER BY DESC(?count)

LIMIT 20

11-1. 중국 영화 권력 이동: 국영 vs 민간 vs 인터넷 기업

주요 국영, 민간, 인터넷 영화 기업의 연도별 제작 편수 추이를 비교하여 산업 주도권의 변화를 확인해보자

#defaultView:LineChart

SELECT ?year ?count ?categoryLabel

WHERE {

  {

    SELECT ?year ?categoryLabel (COUNT(DISTINCT ?film) AS ?count)

    WHERE {

      VALUES (?company ?categoryLabel) {

        (wd:Q1073380 "국영(State-owned)")   # 차이나 필름 그룹

        (wd:Q10873941 "국영(State-owned)")  # 차이나 필름 (주)

        (wd:Q7488442 "국영(State-owned)")   # 상하이 필름 그룹

        (wd:Q7488444 "국영(State-owned)")   # 상하이 영화 제작소

        (wd:Q10872932 "국영(State-owned)")  # 8.1 영화 제작소

        (wd:Q5071736 "국영(State-owned)")   # 장춘 영화 제작소

        (wd:Q17067015 "국영(State-owned)")  # 서부 영화 그룹



        (wd:Q8007810 "민간(Private)")       # 화이 브라더스

        (wd:Q10909544 "민간(Private)")      # 보나 필름

        (wd:Q25054226 "민간(Private)")      # 완다 미디어

        (wd:Q28472070 "민간(Private)")      # 광선 미디어



        (wd:Q11079561 "인터넷(Tech)")       # 알리바바 픽처스

        (wd:Q22080095 "인터넷(Tech)")       # 텐센트 픽처스

        (wd:Q15913890 "인터넷(Tech)")       # 아이치이

        (wd:Q110852757 "인터넷(Tech)")      # 아이치이 픽처스

      }



      ?film wdt:P31 wd:Q11424;          # 영화

            wdt:P495 wd:Q148;           # 국가: 중국

            wdt:P272 ?company;          # 제작사

            wdt:P577 ?pubDate.          # 개봉일

      

      BIND(str(YEAR(?pubDate)) AS ?year)

      FILTER(YEAR(?pubDate) >= 1995 && YEAR(?pubDate) <= 2024)

    }

    GROUP BY ?year ?categoryLabel

  }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }

}

ORDER BY ?year

12. 감독 세대 및 데뷔 시기 분석 (Dimensions)

중국 감독들의 출생년도, 사망년도, 그리고 첫 영화 개봉(데뷔) 시기를 입체적으로 분석해보자

#defaultView:Dimensions

SELECT ?personLabel ?birthYear ?deathYear ?age ?careerStart

WHERE {

 ?person wdt:P31 wd:Q5 ;          # 인간

         wdt:P27 wd:Q148 ;        # 중국 국적

         wdt:P106 wd:Q2526255 ;   # 영화 감독

         wdt:P569 ?birth .        # 출생일

 {

   SELECT ?person (MIN(?pubDate) AS ?firstMovieDate)

   WHERE {

     ?person wdt:P27 wd:Q148 ; wdt:P106 wd:Q2526255 . 

     ?film wdt:P31 wd:Q11424 ;      # 영화

           wdt:P57 ?person ;        # 감독 = ?person

           wdt:P577 ?pubDate .      # 개봉일

   }

   GROUP BY ?person

 }

 OPTIONAL { ?person wdt:P570 ?death. }

 BIND(YEAR(?birth) AS ?birthYear)

 BIND(YEAR(?death) AS ?deathYear)

 BIND(COALESCE(?deathYear, 2024) - ?birthYear AS ?age)

 BIND(YEAR(?firstMovieDate) AS ?careerStart) # 실제 첫 영화 개봉년도

 FILTER(?birthYear >= 1900 && ?birthYear <= 2000)

 FILTER(?age > 0)

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }

}

결과해석

상단으로 이동

(내용 서술)

참고자원

상단으로 이동

(내용 서술)

주석

상단으로 이동