행위

"RCCTD WikiDataCuration03"의 두 판 사이의 차이

CNUDH

(→‎중국 축구 인물 전체적인 풀)
(→‎중국 축구 인물 전체적인 풀)
91번째 줄: 91번째 줄:
 
</font>
 
</font>
 
<br/>
 
<br/>
−
<font color=#D2691E><font size="3">'''1980~2009년에 태어난 중국 국적 축구선수와 축구감독을 대상으로, 출생연도·나이·경력 시작 연도를 추출해 세대별로 중국 축구의 현대적 인력 구조를 시각화.'''</font></font>
+
<font color=#4682B4><font size="3">'''1980~2009년에 태어난 중국 국적 축구선수와 축구감독을 대상으로, 출생연도·나이·경력 시작 연도를 추출해 세대별로 중국 축구의 현대적 인력 구조를 시각화.'''</font></font>
 
<br/>
 
<br/>
 
<font size="1">
 
<font size="1">

2025년 12월 5일 (금) 16:22 판

데이터로 읽는 중국문화(강의) 페이지로 가기



중국 축구의 현대적 발전 과정

:중국 축구 리그·대표팀·유소년 시스템 및 발전 과정

김태현





목차

Contents

연구배경 연구목적 대상주제 쿼리작성 결과해석 참고자원



연구배경


(내용 서술)


연구목적


(내용 서술)


대상주제


(내용 서술)


쿼리작성



중국 축구 인물 전체적인 풀

중국 국적을 가진 사람 중에서 축구선수 또는 축구감독은 누구이며 이들의 소속 팀은 무엇인가?
SELECT ?person ?personLabel ?team ?teamLabel ?occupation ?occupationLabel WHERE { 

?person wdt:P27 wd:Q148.            # 중국 국적
?person wdt:P106 ?occupation.        # 직업
FILTER (?occupation IN (wd:Q937857,wd:Q628099))   # 선수/감독
OPTIONAL { ?person wdt:P54 ?team }    # 소속 팀 (있을 경우만)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh".}}
LIMIT 200


중국 국적의 축구선수 또는 축구감독 중에서, 1994년 이후에 출범한 축구 리그에 속한 팀에서 활동한 적이 있는 사람은 누구인가?
SELECT ?person ?personLabel ?team ?teamLabel ?league ?leagueLabel ?occupation ?occupationLabel WHERE { 

 ?person wdt:P27 wd:Q148 .          # 중국 국적
 ?person wdt:P106 ?occupation .     # 직업
 FILTER (?occupation IN (wd:Q937857, wd:Q628099))    # 선수/감독

 ?person wdt:P54 ?team .            # 소속 팀
 ?team wdt:P118 ?league .           # 클럽이 속한 리그
 ?league wdt:P571 ?leagueStart .    # 리그 성립 시점(개시 시기)

 FILTER (YEAR(?leagueStart) >= 1994)  # 1994년 이후 시작된 리그만 선택

 SERVICE wikibase:label {bd:serviceParam wikibase:language "ko, zh, en" .}}
 LIMIT 200


1980~2009년에 태어난 중국 국적 축구선수와 축구감독을 대상으로, 출생연도·나이·경력 시작 연도를 추출해 세대별로 중국 축구의 현대적 인력 구조를 시각화.
#defaultView:Dimensions
SELECT ?personLabel ?occupationLabel ?birthYear ?deathYear ?age ?careerStart WHERE { 

 ?person wdt:P31 wd:Q5;               # 인간이어야 한다
         wdt:P27 wd:Q148;             # 국적이 중국이다
         wdt:P569 ?birth;             # 출생일
         wdt:P106 ?occupation.        # 직업

 FILTER(?occupation IN (wd:Q937857,   # 축구선수
                        wd:Q628099))  # 축구감독

 OPTIONAL { ?person wdt:P570 ?death. }        # 사망일 (있을 경우)
 OPTIONAL { ?person wdt:P2031 ?careerStartDate. }  # 경력 시작일 (있을 경우)

 BIND(YEAR(?birth) AS ?birthYear)             # 출생연도
 BIND(IF(BOUND(?death), YEAR(?death), 2025) AS ?deathYear)  # 사망연도 또는 2025
 BIND(?deathYear - ?birthYear AS ?age)        # (사망연도/2025) - 출생연도 = 나이
 BIND(YEAR(?careerStartDate) AS ?careerStart) # 경력 출발 시점(연도)

 FILTER(?birthYear >= 1980 && ?birthYear <= 2009)  # 현대 중국 축구 핵심 세대
 FILTER(?age > 0)

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
 LIMIT 200

->1980·1990·2000년대생별 인원 분포
->세대별 평균 경력 시작 연도(얼마나 빨리 프로/공식 경력을 시작하는지)
->선수와 감독(전직 선수 출신 등)의 세대 차이

출생 연도·출생지

중국 축구선수들의 출생연도와 출생지는 무엇인가?
SELECT ?person ?personLabel ?birth ?birthplace ?birthplaceLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 OPTIONAL { ?person wdt:P569 ?birth. }        # 출생
 OPTIONAL { ?person wdt:P19 ?birthplace. }    # 출생지
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
 LIMIT 200


1980~2009년 출생 중국 축구선수는 누구인가?
SELECT ?person ?personLabel ?birth WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P569 ?birth.                     # 출생
 FILTER (YEAR(?birth) >= 1980 && YEAR(?birth) < 2010)   # 1980~2009
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
 LIMIT 200



중국 프로 축구 분석

중국 1부리그에 속한 클럽의 구장은 어디에 위치에 있는가?
SELECT ?stadium ?stadiumLabel ?place ?placeLabel ?location WHERE { 

 ?team wdt:P118 wd:Q209318.          # 1부
 ?team wdt:P115 ?stadium.            # 홈경기장
 ?stadium wdt:P31 wd:Q483110.        # 경기장
 ?stadium wdt:P17 wd:Q148.           # 중국
 OPTIONAL { ?stadium wdt:P131 ?place. }    # 지역
 OPTIONAL { ?stadium wdt:P625 ?location. } # 좌표
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}


1부(슈퍼리그) 경기장의 위치를 디지털 지도에 매핑.
#defaultView:Map
SELECT ?stadium ?stadiumLabel ?coord ?clubLabel WHERE { 

 ?club wdt:P118 wd:Q209318;   # 리그: 중국 슈퍼리그)
       wdt:P115 ?stadium.    # 홈 구장(경기장)
 ?stadium wdt:P625 ?coord.   # 경기장 좌표

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}


2부(갑급리그) 경기장의 위치와 좌표.
SELECT ?stadium ?stadiumLabel ?place ?placeLabel ?location WHERE { 

 ?team wdt:P118 wd:Q1207912.         # 2부
 ?team wdt:P115 ?stadium.            # 홈경기장
 ?stadium wdt:P31 wd:Q483110.        # 경기장
 ?stadium wdt:P17 wd:Q148.           # 중국
 OPTIONAL { ?stadium wdt:P131 ?place. }    # 지역
 OPTIONAL { ?stadium wdt:P625 ?location. } # 좌표
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}


1부(슈퍼리그) 경기장 이미지.
#defaultView:ImageGrid
SELECT ?stadium ?stadiumLabel ?image WHERE { 

 ?club wdt:P118 wd:Q209318.     # 중국 슈퍼리그
 ?club wdt:P115 ?stadium.       # 홈 구장
 ?stadium wdt:P18 ?image.       # 이미지가 있는 경기장만
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}



중국 슈퍼리그(CSL) 시즌별 우승 팀은 어디인가?
SELECT ?season ?seasonLabel ?winner ?winnerLabel ?date WHERE { 

 ?season wdt:P3450 wd:Q209318.                # 중국 슈퍼리그
 ?season wdt:P1346 ?winner.                   # 우승 팀
 OPTIONAL { ?season wdt:P585 ?date. }         # 시점
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
 ORDER BY ?date


2000년 이후 중국 슈퍼리그(CSL)에서 가장 많이 우승한 팀은 어디인가?
#defaultView:BarChart
SELECT ?winnerLabel (COUNT(?season) AS ?titles) WHERE { 

 ?season wdt:P3450 wd:Q209318;   # 중국 슈퍼리그의 각 시즌
         wdt:P1346 ?winner;      # 시즌 우승 팀
         wdt:P585 ?date.         # 시즌 시점 (대부분 연도 단위)
 
 FILTER (YEAR(?date) >= 2000)    # 2000년 이후 시즌만 포함

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
 GROUP BY ?winnerLabel
 ORDER BY DESC(?titles)


수용 인원이 큰 홈 경기장을 사용하는 클럽일수록 중국 슈퍼리그(CSL) 우승을 더 많이 차지했는가?
#defaultView:ScatterChart
SELECT ?capacity ?titles ?clubLabel WHERE { 

 # 1단계: 클럽별 중국 슈퍼리그 우승 횟수 집계
 {
   SELECT ?club (COUNT(?season) AS ?titles)
   WHERE {
     ?season wdt:P3450 wd:Q209318;  # 중국 슈퍼리그
             wdt:P1346 ?club.       # 시즌 우승 팀
   }
   GROUP BY ?club
 }

 # 2단계: 각 클럽의 홈구장 수용 인원 가져오기
 ?club wdt:P115 ?stadium.          # 홈 경기장
 ?stadium wdt:P1083 ?capacity.     # 경기장 수용 인원

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}


중국 슈퍼리그(CSL)에서 우승한 클럽들을 대상으로 각 클럽의 창단 연도, 첫 우승 연도, 총 우승 횟수, 홈 경기장 수용 인원을 한 번에 비교한 후, 중국 프로 축구의 강팀들이 어떤 시기에 등장했고 어떤 인프라를 갖추고 있는지 시각화.
#defaultView:Dimensions
SELECT ?clubLabel ?foundedYear ?firstTitleYear ?titles ?capacity WHERE { 

 # 1단계: CSL 우승 클럽별 우승 횟수와 첫 우승 연도 집계
 {
   SELECT ?club (COUNT(?season) AS ?titles) (MIN(YEAR(?date)) AS ?firstTitleYear)
   WHERE {
     ?season wdt:P3450 wd:Q209318;   # 중국 슈퍼리그 시즌
             wdt:P1346 ?club;       # 시즌 우승 팀
             wdt:P585 ?date.        # 시즌 시점
   }
   GROUP BY ?club
 }

 # 2단계: 각 클럽의 기본 정보(창단 연도, 홈구장 수용 인원)
 OPTIONAL {
   ?club wdt:P571 ?founded.         # 클럽 창단일
   BIND(YEAR(?founded) AS ?foundedYear)
 }

 OPTIONAL {
   ?club wdt:P115 ?stadium.         # 홈경기장
   ?stadium wdt:P1083 ?capacity.    # 경기장 수용 인원
 }

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}
 LIMIT 50

-> 과거에 창단한 전통 구단일수록 우승 첫 시점이 빠르다.
-> 신생 구단 중에서도 폭발적으로 성장한 팀이 있다.
-> 경기장 규모(=투자 규모)와 우승 경험은 강한 상관 관계가 있다.


연령별 대표팀 구조(U17/U20/U23/A대표)

중국 U-17 대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q3589928.                 # U-17
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}


중국 U-20 대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q5100058.                 # U-20
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}


중국 U-23 대표팀(올림픽대표) 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q987926.                  # U-23
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}


중국 A대표팀 출신 선수는 누구인가?
SELECT ?person ?personLabel WHERE { 

 ?person wdt:P27 wd:Q148.                     # 중국 국적
 ?person wdt:P106 wd:Q937857.                 # 축구선수
 ?person wdt:P54 wd:Q130582.                  # A대표
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}


2025년 기준으로 중국 U-23(올림픽대표) 대표팀에서 현재 활동 중인 선수들을 TreeMap으로 시각화.
#defaultView:TreeMap
SELECT ?teamLabel ?athleteLabel WHERE { 

 ?athlete wdt:P31 wd:Q5;                    # 인간
          wdt:P27 wd:Q148;                  # 중국 국적
          wdt:P106 wd:Q937857.              # 축구선수

 # 대표팀(U-23) 소속 기간 
 ?athlete p:P54 ?ntStatement.
 ?ntStatement ps:P54 wd:Q987926.            # 중국 U-23 대표팀
 OPTIONAL { ?ntStatement pq:P580 ?ntStart. }# 대표팀 시작일
 OPTIONAL { ?ntStatement pq:P582 ?ntEnd. }  # 대표팀 종료일

 # 2025년 현재 U-23에 해당
 FILTER ( !BOUND(?ntStart) || YEAR(?ntStart) <= 2025 )
 FILTER ( !BOUND(?ntEnd)   || YEAR(?ntEnd)   >= 2025 )

 # 클럽 소속 기간(현재 클럽만) 
 ?athlete p:P54 ?clubStatement.
 ?clubStatement ps:P54 ?team.               # 소속 팀
 ?team wdt:P31 wd:Q476028.                  # 축구 클럽(국가대표팀 등 제외)

 OPTIONAL { ?clubStatement pq:P580 ?clubStart. } # 클럽 합류일
 OPTIONAL { ?clubStatement pq:P582 ?clubEnd. }   # 클럽 퇴단일

 # 2025년 현재 클럽에 해당
 FILTER ( !BOUND(?clubStart) || YEAR(?clubStart) <= 2025 )
 FILTER ( !BOUND(?clubEnd)   || YEAR(?clubEnd)   >= 2025 )

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}


2025년 기준으로 중국 A대표팀에서 활동 중인 선수들을 TreeMap으로 시각화.
#defaultView:TreeMap
SELECT ?teamLabel ?athleteLabel WHERE { 

 ?athlete wdt:P31 wd:Q5;                    # 인간
          wdt:P27 wd:Q148;                  # 중국 국적
          wdt:P106 wd:Q937857.              # 축구선수

 # A대표팀 소속 기간 조건
 ?athlete p:P54 ?ntStatement.
 ?ntStatement ps:P54 wd:Q130582.            # 중국 A대표팀
 OPTIONAL { ?ntStatement pq:P580 ?ntStart. }# 대표팀 시작일
 OPTIONAL { ?ntStatement pq:P582 ?ntEnd. }  # 대표팀 종료일

 # 2025년 현재도 대표팀 소속
 FILTER ( !BOUND(?ntStart) || YEAR(?ntStart) <= 2025 )
 FILTER ( !BOUND(?ntEnd)   || YEAR(?ntEnd)   >= 2025 )

 # 2025년 기준 '현 소속 클럽'
 ?athlete p:P54 ?clubStatement.
 ?clubStatement ps:P54 ?team.               # 소속 클럽
 ?team wdt:P31 wd:Q476028.                  # 클럽(국가대표팀 제외)

 OPTIONAL { ?clubStatement pq:P580 ?clubStart. } # 클럽 합류일
 OPTIONAL { ?clubStatement pq:P582 ?clubEnd. }   # 클럽 퇴단일

 # 2025년 현재 클럽에 해당
 FILTER ( !BOUND(?clubStart) || YEAR(?clubStart) <= 2025 )
 FILTER ( !BOUND(?clubEnd)   || YEAR(?clubEnd)   >= 2025 )

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}


중국 U-17, U-20, U-23 대표팀을 거쳐 최종적으로 중국 A대표팀에 승격한 선수들을 찾아서, 이들의 대표팀 단계별 소속 시점(시작·종료 연도)을 함께 비교한 후, 중국 유소년 대표팀 시스템에서 실제로 A대표로 성장한 선수 라인을 시각화.
#defaultView:Dimensions
SELECT 

 ?playerLabel 
 ?u17StartYear ?u17EndYear
 ?u20StartYear ?u20EndYear
 ?u23StartYear ?u23EndYear
 ?aStartYear   ?aEndYear
 WHERE {

 # 기본 조건: 중국 국적 + 축구선수
 ?player wdt:P31 wd:Q5;              # 인간
         wdt:P27 wd:Q148;            # 중국 국적
         wdt:P106 wd:Q937857.        # 축구선수

 # ① U-17 대표팀 경력
 OPTIONAL {
   ?player p:P54 ?u17Statement.
   ?u17Statement ps:P54 wd:Q3589928;   # 중국 U-17 대표팀
                   pq:P580 ?u17Start;  # 시작 시점
                   pq:P582 ?u17End.    # 종료 시점
   BIND(YEAR(?u17Start) AS ?u17StartYear)
   BIND(YEAR(?u17End)   AS ?u17EndYear)
 }

 # ② U-20 대표팀 경력
 OPTIONAL {
   ?player p:P54 ?u20Statement.
   ?u20Statement ps:P54 wd:Q5100058;   # 중국 U-20 대표팀
                   pq:P580 ?u20Start;
                   pq:P582 ?u20End.
   BIND(YEAR(?u20Start) AS ?u20StartYear)
   BIND(YEAR(?u20End)   AS ?u20EndYear)
 }

 # ③ U-23 대표팀 경력
 OPTIONAL {
   ?player p:P54 ?u23Statement.
   ?u23Statement ps:P54 wd:Q987926;    # 중국 U-23 대표팀
                   pq:P580 ?u23Start;
                   pq:P582 ?u23End.
   BIND(YEAR(?u23Start) AS ?u23StartYear)
   BIND(YEAR(?u23End)   AS ?u23EndYear)
 }

 # ④ A대표팀 경력 (최종 목표)
 OPTIONAL {
   ?player p:P54 ?aStatement.
   ?aStatement ps:P54 wd:Q130582;      # 중국 A대표팀
                 pq:P580 ?aStart;
                 pq:P582 ?aEnd.
   BIND(YEAR(?aStart) AS ?aStartYear)
   BIND(YEAR(?aEnd)   AS ?aEndYear)
 }

 # '승격자'만 보기 → A대표팀 경력이 있는 선수만 필터링
 FILTER(BOUND(?aStart))

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
 LIMIT 50

-> U-17 → U-20 → U-23 → A 대표로 이어지는 ‘육성 사다리’가 없다.
-> 대부분 선수는 유소년 단계를 건너뛰고 바로 A대표로 선발.
-> 유소년 대표 출신이 A대표로 승격되는 비율은 매우 낮음.
-> 강한 투자에도 불구하고, 체계적인 육성 구조가 부재함.

1990년 이후 출생한 중국 국적 축구선수 중에서 U-17, U-20, U-23 대표팀 가운데 하나라도 거친 선수들이 현재 중국 1부(슈퍼리그) 또는 2부(갑급리그) 클럽에서 활동하고 있는 비율(인원 수)을 바 차트 형태로 비교.
#defaultView:BarChart
SELECT ?category ?count WHERE { 

 #1) 대표팀(U17/U20/U23)을 거쳐 + 1부/2부 리그에서도 뛴 선수 수 
 {
   SELECT ("대표+프로" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
   WHERE {
     ?player wdt:P31 wd:Q5;          # 인간
             wdt:P27 wd:Q148;        # 중국 국적
             wdt:P106 wd:Q937857;    # 축구선수
             wdt:P569 ?birth.

     BIND(YEAR(?birth) AS ?birthYear)
     FILTER(?birthYear >= 1990)       # 1990년 이후 출생

     # U17 / U20 / U23 중 하나라도 소속
     VALUES ?youthNT { wd:Q3589928 wd:Q5100058 wd:Q987926 }
     ?player wdt:P54 ?youthNT.

     # 중국 1부(슈퍼리그) 또는 2부(갑급리그) 클럽 경험
     ?player wdt:P54 ?club.
     ?club wdt:P118 ?league.
     FILTER(?league IN (wd:Q209318, wd:Q1207912))  # 1부·2부 리그
   }
 }

 UNION

 #2) U17/U20/U23 대표팀을 하나라도 거친 전체 선수 수 
 {
   SELECT ("대표 전체" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
   WHERE {
     ?player wdt:P31 wd:Q5;          # 인간
             wdt:P27 wd:Q148;        # 중국 국적
             wdt:P106 wd:Q937857;    # 축구선수
             wdt:P569 ?birth.

     BIND(YEAR(?birth) AS ?birthYear)
     FILTER(?birthYear >= 1990)

     VALUES ?youthNT { wd:Q3589928 wd:Q5100058 wd:Q987926 }
     ?player wdt:P54 ?youthNT.
   }
 }

}

-> 유소년 대표팀 출신 선수 중 프로 상위리그(1·2부)에 도달한 비율
-> 1990년대 이후 중국 유소년 대표팀을 경험한 선수들은 사실상 100% 중국 프로 상위리그(1부·2부)에 진출한다.

1990년 이후에 태어난 중국 국적 축구선수 가운데 U-17, U-20, U-23, A대표 중 하나 이상을 경험한 선수들을 대상으로, 그중에서 해외 클럽(중국이 아닌 나라 클럽)에서 뛴 적이 있는 선수 비율을 바 차트로 비교.
#defaultView:BarChart
SELECT ?category ?count WHERE { 

 {
   # ① 대표팀(U17/U20/U23/A) + 해외 클럽(중국 외 국가) 경험이 있는 선수 수
   SELECT ("해외 진출" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
   WHERE {
     ?player wdt:P31 wd:Q5;           # 인간
             wdt:P27 wd:Q148;         # 중국 국적
             wdt:P106 wd:Q937857;     # 축구선수
             wdt:P569 ?birth.         # 출생일

     BIND(YEAR(?birth) AS ?birthYear)
     FILTER(?birthYear >= 1990)       # 1990년 이후 출생

     # U-17 / U-20 / U-23 / A대표 중 하나라도 경험
     VALUES ?natTeam { wd:Q3589928 wd:Q5100058 wd:Q987926 wd:Q130582 }
     ?player wdt:P54 ?natTeam.

     # 해외 클럽 경험: 클럽의 국가가 중국이 아닌 경우
     ?player wdt:P54 ?club.
     ?club wdt:P17 ?clubCountry.
     FILTER(?clubCountry != wd:Q148)  # 중국이 아닌 나라
     SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }
   }
 }

 UNION

 {
   # ② 대표팀(U17/U20/U23/A) 경험이 있는 전체 선수 수
   SELECT ("대표 전체" AS ?category) (COUNT(DISTINCT ?player) AS ?count)
   WHERE {
     ?player wdt:P31 wd:Q5;           # 인간
             wdt:P27 wd:Q148;         # 중국 국적
             wdt:P106 wd:Q937857;     # 축구선수
             wdt:P569 ?birth.

     BIND(YEAR(?birth) AS ?birthYear)
     FILTER(?birthYear >= 1990)       # 1990년 이후 출생

     VALUES ?natTeam { wd:Q3589928 wd:Q5100058 wd:Q987926 wd:Q130582 }
     ?player wdt:P54 ?natTeam.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }}}}

-> 대표팀(U17/U20/U23/A 중 하나라도 거친 선수 4명 중 1명만 해외에 나갔다.
-> 중국 유소년·성인 대표 시스템은 해외 진출로 거의 연결되지 않는다.
-> 중국 대표팀 라인의 '폐쇄성'이 수치로 드러난다.

결과해석


(내용 서술)


참고자원


(내용 서술)


주석






원본 주소 "https://dh.aks.ac.kr/~cnudh/wiki/index.php?title=RCCTD_WikiDataCuration03&oldid=24794"