RCCTD(2025)WikiDataQueries

데이터로 읽는 중국문화(강의) 페이지로 가기

WikiData Query 샘플
: 중국 문화를 중심으로

목차

Contents

---

인물 관련 질의어 사건 관련 질의어 장소 관련 질의어 문화유산 관련 질의어 조합

---

Person

상단으로 이동

① 한글 명칭으로 특정 인물(예:마오쩌둥) 찾기

SELECT ?person ?personLabel
WHERE {
?person rdfs:label "마오쩌둥"@ko.
SERVICE wikibase:label { bd:serviceParam wikibase:language
"[AUTO_LANGUAGE],ko,en". }
}

② 기본 정보(생몰년, 출생지)를 포함한 당나라 시대 사람들 찾기

SELECT ?person ?personLabel ?birth ?death ?birthplaceLabel ?occupationLabel
WHERE {
?person wdt:P27 wd:Q9683.      # 국적: 당나라

OPTIONAL { ?person wdt:P569 ?birth. }

OPTIONAL { ?person wdt:P570 ?death. }

OPTIONAL { ?person wdt:P19 ?birthplace. }

OPTIONAL { ?person wdt:P106 ?occupation. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }
}
LIMIT 100

③ 1950년 이후의 드라마와 영화에 가장 많이 출연한 인물 찾기

#defaultView:BubbleChart
SELECT ?person (COUNT(?work) AS ?count) ?personLabel
WHERE {

VALUES ?type { wd:Q11424 wd:Q5398426 }

?work wdt:P31 ?type.

?work wdt:P577 ?date.

FILTER (YEAR(?date) >= 1950)

?work wdt:P161 ?person.

?person wdt:P27 wd:Q148.

SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, ko, en". }

}

GROUP BY ?person ?personLabel
ORDER BY DESC(?count)
LIMIT 50

Event

상단으로 이동

① 중국에서 발생한 운동(Campaign) 찾기

SELECT  ?campaign ?campaignLabel ?start ?end
WHERE {

?campaign wdt:P31/wdt:P279* wd:Q6056746;

wdt:P17 wd:Q148.

OPTIONAL { ?campaign wdt:P580 ?start. }

OPTIONAL { ?campaign wdt:P582 ?end. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}

② 당나라의 주요 사건을 타임라인으로 보기

#defaultView:Timeline
SELECT ?event ?eventLabel ?date ?image
WHERE {

?event wdt:P585 ?date.   #특정 시점

?event wdt:P17|wdt:P276/wdt:P17 wd:Q148.    #중국 관련

FILTER(YEAR(?date) >= 618 && YEAR(?date) <= 907)    # 당나라 시기

OPTIONAL { ?event wdt:P18 ?image. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}

ORDER BY ?date

Place

상단으로 이동

① 중국의 2000m 이상의 산과 봉우리 찾기

# defaultView:Map
SELECT ?mountaintap ?mountaintapLabel ?tapPoint ?altitude
WHERE {

VALUES ?type { wdt:Q8502 wd:Q207326 }

?mountaintap wdt:P31 ?type;

p:P2044/psn:P2044/wikibase:quantityAmount ?altitude;

wdt:P17 wd:Q148;

wdt:P625 ?tapPoint.

FILTER (?altitude >= 2000)

SERVICE wikibase:label {bd:serviceParam wikibase:language "ko, zh, en".}

}

② 당나라 인물들의 출생지별 좌표맵 찾기

#defaultView:Map
SELECT ?personLabel ?birthplace ?birthplaceLabel (COUNT(?person) AS ?count) (SAMPLE (?lacation) AS ?Location)
WHERE {

?person wdt:P27 wd:Q9683;    #당나라 사람

wdt:P19 ?birthplace.    #출생지

OPTIONAL { ?birthplace wdt:P625 ?lacation. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "zh, en". }

}
GROUP BY ?birthplace ?birthplaceLabel ?personLabel
ORDER BY DESC(?count)

CulturalHeritage

상단으로 이동

① 유네스코 세계유산에 등재된 중국의 문화재 찾기

#defaultView:ImageGrid
SELECT ?heritage ?heritageLabel (SAMPLE (?location) AS ?Location) (SAMPLE (?image) AS ?Image)
WHERE {

?heritage wdt:P1435 wd:Q9259.

VALUES ?china { wd:Q148 wd:Q29520 }

?heritage wdt:P17 ?china;

wdt:P625 ?location.

OPTIONAL { ?heritage wdt:P18 ?image. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, en". }

}
GROUP BY ?heritage ?heritageLabel

② 당나라 황제의 무덤과 능묘의 이미지, 좌표 찾기

SELECT ?tomb ?tombLabel ?coordinates ?emperorLabel
WHERE {

?emperor p:P39 ?position.     #?emperor가 ?position을 가진다

?position ps:P39 wd:Q268218.     #?position은 중국의 황제다

?position pq:P1001 wd:Q9683.     #?position의 관할권은 당나라다

?emperor wdt:P119 ?tomb.

?tomb wdt:P625 ?coordinates.

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}

Combination

상단으로 이동

① 당나라 시인과 그의 대표작 찾기

SELECT ?poet ?poetLabel ?work ?workLabel
WHERE {

?poet wdt:P27 wd:Q9683;

wdt:P106 wd:Q49757.

OPTIONAL { ?poet wdt:P800 ?work. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "zh,en". }

}
LIMIT 50