"RCCTD WikiDataCuration08"의 두 판 사이의 차이
CNUDH
(→연구목적) |
(→1. 불교 문화의 중심지) |
||
| 144번째 줄: | 144번째 줄: | ||
?temple wdt:P1435 wd:Q1188574. | ?temple wdt:P1435 wd:Q1188574. | ||
?temple wdt:P17 wd:Q148. | ?temple wdt:P17 wd:Q148. | ||
| − | + | ?temple wdt:P131 ?location. #행정구역 | |
| − | |||
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } | SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } | ||
} | } | ||
| + | |||
2025년 12월 15일 (월) 05:02 판
목차
Contents
연구배경
중국 불교는 아주 긴 역사를 가지고 있고 그만큼 스님들과 사찰에 대한 기록도 엄청나게 많습니다. 지금까지의 연구들은 문헌을 꼼꼼히 읽으면서 이런 기록들을 아주 잘 정리해 왔습니다. 덕분에 불교의 역사를 깊이 이해할 수 있게 되었습니다.
하지만 책에 적힌 글자만으로는 수많은 사찰이 중국 땅 어디에 퍼져 있는지, 사찰이 위치와 승려들의 출생지와 관련있는지 같은 자세한 정보를 한눈에 알아보기가 어렵습니다. "어느 지역에 절이 제일 많지?", "문화대혁명 때 얼마나 많은 절이 사라졌을까?" 같은 질문은 글만 읽어서는 답을 찾기가 쉽지 않기 때문입니다.
그래서 이런 역사 기록들을 컴퓨터가 이해할 수 있는 데이터로 만들어서 분석하려고 합니다. 위키데이터 같은 곳에 정리된 정보를 활용하면 복잡한 불교 역사를 지도 위에 그리거나 그래프로 만들어서 쉽게 볼 수 있습니다.
이 연구는 기존의 훌륭한 역사 기록들을 SPARQL을 이용해 정리해 보는 시도입니다. 특히 사찰의 위치와 스님들의 활동을 연결해서 분석해 보면 예전에는 미처 발견하지 못했던 중국 불교의 새로운 흐름이나 특징을 찾아낼 수 있을 것입니다.
연구목적
1. 불교 문화의 중심지가 어디인지 지역별로 분석합니다.
현재 중국의 행정구역 중 가장 많은 사원이 남아있는 곳이 어디인지 데이터를 통해 확인합니다. 또한 승려들의 출생지를 함께 분석하여 사찰이 많은 지역과 인물을 많이 배출한 지역이 일치하는지, 아니면 시대에 따라 불교의 중심지가 달랐는지 비교합니다.
2. 역사의 흐름에 따른 사찰의 흥망성쇠를 시각화합니다.
과거부터 현재까지 사원이 가장 많이 건립된 시기가 언제인지 파악하여 불교의 전성기를 데이터로 증명합니다. 반대로 문화대혁명과 같은 역사적 사건 당시에 구체적으로 얼마나 많은 사원이 소실되었는지 수치로 확인하여, 정치적 사건이 불교에 미친 영향을 분석합니다.
3. 승려들의 스승과 제자 관계를 연결하여 인물들을 살펴봅니다.
문헌에 기록된 승려들의 스승과 제자 관계 데이터를 연결하여 불교의 가르침이 인물과 인물을 통해 어떻게 이어져 왔는지 관계를 파악합니다. 이를 통해 가장 많은 제자를 배출한 핵심적인 스승이 누구인지 찾고 더 나아가 불교를 종교로 가진 현대의 유명 배우 데이터를 수집하여 과거의 승려 중심 데이터와는 다른 현대의 불교와 관련된 인물들의 일면을 분석합니다.
대상주제
본 연구는 위키데이터에 등록된 데이터 중, 중국의 불교 사원과 승려를 핵심 분석 대상으로 삼습니다. 구체적인 범위는 다음과 같습니다.
1. 중국 불교 사원 데이터
위키데이터에서 '중국'에 위치한 '불교 사원'을 대상으로 하며, 다음 세 가지 정보를 중점적으로 수집합니다.
행정구역 정보: 사원이 현재 중국의 어느 성(省)이나 시(市)에 속해 있는지 파악하여 지역별 분포를 봅니다.
건립 시기: 사원이 처음 세워진 날짜(연도)를 수집하여 시대별 사원 건립 추이를 분석합니다.
문화재 지정 현황: 문화재로 등록된 사원의 데이터를 수집합니다. 이를 통해 역사적 가치를 인정받아 현재까지 보존되고 있는 사원들의 현황과 분포를 파악합니다.
2. 중국 승려 인물 데이터
중국 역사 속에 존재했던 승려들을 대상으로 하며, 다음 두 가지 정보를 중심으로 분석합니다
출생지 정보: 승려들이 태어난 지역 데이터를 수집하여, 시대별로 어느 지역에서 승려가 많이 배출되었는지 확인합니다.
출생 시기: 승려가 태어난 연도를 함께 수집하여, 특정 시기에 특정 지역에서 인물이 집중되는 경향이 있는지 봅니다.
쿼리작성
1. 불교 문화의 중심지
1.현재 중국 내 1급 행정구역(성/직할시) 중 불교 사원이 가장 많이 분포한 지역은 어디?
#defaultView:BubbleChart
SELECT ?province ?provinceLabel (COUNT(DISTINCT ?temple) AS ?templeCount)
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308. #사원
?temple wdt:P17 wd:Q148. #중국
?temple wdt:P131+ ?province. #상위행정구역을찾음
?province wdt:P131 wd:Q148. #찾은행정구역을제한(성단위로묶음)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
GROUP BY ?province ?provinceLabel ORDER BY DESC(?templeCount) LIMIT 50
2.중국의 전국중점문물보호단위(국보급 문화재)로 지정된 사찰이 많은 지역은?
#defaultView:BubbleChart
SELECT ?province ?provinceLabel (COUNT(DISTINCT ?temple) AS ?templeCount)
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308.
?temple wdt:P1435 wd:Q1188574. #국보급문화재를찾음
?temple wdt:P17 wd:Q148.
?temple wdt:P131+ ?province.
?province wdt:P131 wd:Q148.
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}GROUP BY ?province ?provinceLabel
ORDER BY DESC(?templeCount)
3.중국의 전국중점문물보호단위 사찰의 위치는?
SELECT ?temple ?templeLabel ?location ?locationLabel ?coord
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308.
?temple wdt:P1435 wd:Q1188574.
?temple wdt:P17 wd:Q148.
?temple wdt:P131 ?location. #행정구역
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}
4.승려들의 출생지 분포
#defaultView:Map
SELECT ?monk ?monkLabel ?birthPlace ?birthPlaceLabel ?coord ?layer
WHERE {
?monk wdt:P106 wd:Q854997.
VALUES ?layer {
wd:Q9683 wd:Q8733
wd:Q7462 wd:Q7209
wd:Q7209 wd:Q148
wd:Q9903 wd:Q29520} #국적
?monk wdt:P27 ?layer.
?monk wdt:P19 ?birthPlace. #출생지
?birthPlace wdt:P625 ?coord. #출생지좌표
SERVICE wikibase:label { bd:serviceParam wikibase:language
"[AUTO_LANGUAGE],ko,zh,en". }}
LIMIT 500
5.현재는 사라진 사원은?
SELECT DISTINCT ?place ?placeLabel ?demolishedDate ?image
WHERE {
?place wdt:P576 ?demolishedDate.
?place wdt:P17 wd:Q148.
{ ?place wdt:P31/wdt:P279* wd:Q5393308. }
UNION
{ ?place wdt:P31/wdt:P279* wd:Q21550442. }
OPTIONAL { ?place wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }
}
ORDER BY DESC(?demolishedDate)
2. 시대의 흐름으로 본 중국 불교의 전성기와 쇠퇴기
1.불교 사찰 건립 연도별/세기별 추이 그래프
(연도별)
#defaultView:LineChart
SELECT ?year (COUNT(?temple) AS ?count)
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308.
?temple wdt:P17 wd:Q148.
?temple wdt:P571 ?date.
BIND(YEAR(?date) AS ?year)
}
GROUP BY ?year
ORDER BY ?year
1.불교 사찰 건립 연도별/세기별 추이 그래프
(세기별)
#defaultView:BarChart
SELECT ?centuryLabel (COUNT(?temple) AS ?count)
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308.
?temple wdt:P17 wd:Q148.
?temple wdt:P571 ?date.
BIND(YEAR(?date) AS ?year)
# 수식: (연도-1) 나누기 100 한 뒤 내림(FLOOR) + 1 = 세기
# 예: 618년 -> 6.17 -> 6 + 1 = 7세기
BIND(FLOOR((?year - 1) / 100) + 1 AS ?century)
# 그래프 X축에 "7 C" 처럼 표시하기 위해 라벨 생성
BIND(CONCAT(STR(?century), " C") AS ?centuryLabel)
}
GROUP BY ?century ?centuryLabel
ORDER BY ?century
2.국보급(전국중점문물보호단위) 사찰의 건립 시기는?
#defaultView:BarChart
SELECT ?centuryLabel (COUNT(?temple) AS ?count)
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308.
?temple wdt:P17 wd:Q148.
?temple wdt:P1435 wd:Q1188574.
?temple wdt:P571 ?date.
BIND(YEAR(?date) AS ?year)
BIND(FLOOR((?year - 1) / 100) + 1 AS ?century)
BIND(CONCAT(STR(?century), " C") AS ?centuryLabel)
}
GROUP BY ?century ?centuryLabel
ORDER BY ?century
3.20세기 이후 연대별(10년 단위) 사찰 건립 현황
#defaultView:BarChart
SELECT ?decadeLabel (COUNT(?temple) AS ?count)
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308.
?temple wdt:P17 wd:Q148.
?temple wdt:P571 ?date.
BIND(YEAR(?date) AS ?year)
FILTER(?year >= 1900 && ?year < 2020)
BIND(FLOOR(?year / 10) * 10 AS ?decade)
BIND(CONCAT(STR(?decade), "s") AS ?decadeLabel)
}
GROUP BY ?decade ?decadeLabel
ORDER BY ?decade
4.중국 승려들의 출생 시기는?!?!
#defaultView:BarChart
SELECT ?centuryLabel (COUNT(?monk) AS ?count)
WHERE {
?monk wdt:P106 wd:Q854997.
?monk wdt:P19/wdt:P131* wd:Q148.
?monk wdt:P569 ?dob.
BIND(YEAR(?dob) AS ?year)
BIND(FLOOR((?year - 1) / 100) + 1 AS ?century)
BIND(CONCAT(STR(?century), " C") AS ?centuryLabel)
}
GROUP BY ?century ?centuryLabel
ORDER BY ?century
5.문화대혁명 시기에 건립된 사찰 목록
SELECT ?year ?temple ?templeLabel ?locationLabel
WHERE {
?temple wdt:P31/wdt:P279* wd:Q5393308.
?temple wdt:P17 wd:Q148.
?temple wdt:P571 ?date.
BIND(YEAR(?date) AS ?year)
FILTER(?year >= 1966 && ?year <= 1976)
OPTIONAL { ?temple wdt:P131 ?location. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}
ORDER BY ?year
3. 인물로 보는 중국 불교
1.스승과 제자로 이어진 중국 승려
#defaultView:Graph
SELECT ?monk ?monkLabel ?teacher ?teacherLabel
WHERE {
?monk wdt:P106 wd:Q854997.
VALUES ?country {
wd:Q9683 # 당나라
wd:Q7462 # 송나라
wd:Q7170 # 원나라
wd:Q9903 # 명나라
wd:Q8733 # 청나라
wd:Q7209 # 한나라
wd:Q148 # 중화인민공화국
wd:Q29520 }
?monk wdt:P27 ?country.
?monk wdt:P1066 ?teacher.
SERVICE wikibase:label { bd:serviceParam wikibase:language
"[AUTO_LANGUAGE],ko,zh,en". }
}
LIMIT 50
2.가장 많은 제자를 배출한 승려들의 다른 직업은?
#defaultView:Table
SELECT ?monkLabel ?dynastyLabel (COUNT(DISTINCT ?student) AS ?studentCount)
(GROUP_CONCAT(DISTINCT ?otherJobLabel; separator=", ") AS ?otherProfessions)
WHERE {
?monk wdt:P106 wd:Q854997.
VALUES ?dynasty {
wd:Q9683 wd:Q8733
wd:Q7462 wd:Q7209
wd:Q7209 wd:Q148
wd:Q9903 wd:Q29520}
?monk wdt:P27 ?dynasty.
?monk wdt:P802 ?student.
OPTIONAL {
?monk wdt:P106 ?job.
FILTER(?job != wd:Q854997)
?job rdfs:label ?otherJobLabel.
FILTER(LANG(?otherJobLabel) = "ko") }
SERVICE wikibase:label { bd:serviceParam wikibase:language
"[AUTO_LANGUAGE],ko,zh,en". }}
GROUP BY ?monkLabel ?dynastyLabel
ORDER BY DESC(?studentCount)
LIMIT 50
3.과거의 승려들이 가장 많이 가진 직업은?
#defaultView:BarChart
SELECT ?otherJobLabel (COUNT(DISTINCT ?person) AS ?count)
WHERE {
VALUES ?country {
wd:Q9683 wd:Q8733
wd:Q7462 wd:Q7209
wd:Q7209 wd:Q9903 }
?person wdt:P27 ?country.
?person wdt:P106 wd:Q854997.
?person wdt:P106 ?otherJob.
FILTER(?otherJob != wd:Q854997)
FILTER(?otherJob != wd:Q733786)
SERVICE wikibase:label { bd:serviceParam wikibase:language
"[AUTO_LANGUAGE],ko,zh,en". }}
GROUP BY ?otherJobLabel ORDER BY DESC(?count) LIMIT 20
4.불교를 믿는 유명한 배우는?
SELECT ?person ?personLabel ?sitelinks (SAMPLE(?image) AS ?oneImage)
WHERE {
?person wdt:P31 wd:Q5.
?person wdt:P27 wd:Q148.
?person wdt:P140 wd:Q748.
?person wdt:P106 wd:Q33999.
?person wikibase:sitelinks ?sitelinks.
OPTIONAL { ?person wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
GROUP BY ?person ?personLabel ?sitelinks
ORDER BY DESC(?sitelinks)
LIMIT 20
결과해석
(내용 서술)
참고자원
(내용 서술)
주석