RCCTD WikiDataCuration01

데이터로 읽는 중국문화(강의) 페이지로 가기

중국의 게임시장의 발전

:E-sports(중 league of legend) 중심으로

최다혜

목차

Contents

---

연구배경 연구목적 대상주제 쿼리작성 결과해석 참고자원

---

연구배경

상단으로 이동

21세기 들어 중국의 디지털 오락·여가 산업은 인터넷 보급과 모바일 기술의 발달로 빠르게 변화해 왔다.
특히 게임 산업은 이러한 변화의 중심에 서 있으며, 이제는 단순한 놀이가 아니라 하나의 문화로 자리 잡았다.
그중 e스포츠의 성장 등은 중국 사회에서 게임이 차지하는 의미를 크게 확장시키고 있다.

현재 중국에서는 텐센트(Tencent)와 같은 대형 플랫폼 기업을 중심으로 게임 생태계가 구축되어 있다.
이 생태계는 개발과 퍼블리싱뿐 아니라 서비스, 커뮤니티, e스포츠까지 하나의 구조 안에서 이루어지는 특징을 가지고 있다.
이러한 방식은 게임을 단순한 콘텐츠가 아닌 문화적 공간으로 만들며, 많은 청소년과 성인들이 일상적으로 참여하는 중요한 여가 방식으로 자리 잡게 했다.

흥미로운 점은 중국 정부가 강력한 게임 규제를 시행하고 있음에도 중국 게임시장은 계속 성장해 왔다는 사실이다.
청소년 게임 시간 제한이나 판호 규제 같은 정책들이 존재하지만, 이는 게임 산업의 성장과 이용자 행동에 서로 다른 방식으로 영향을 미치고 있다.
이처럼 규제와 산업이 동시에 작동하는 구조는 다른 나라와 비교해 독특한 특징을 보여준다.

이러한 변화 속에서 중국 내 게임문화의 형성과 발전을 체계적으로 이해하기 위해서는,
① 중국 내 게임산업에 대한 이해
② 중국 내 모바일 / e스포츠산업의 성장
등을 데이터 기반으로 분석하는 작업이 필수적이다.

중국의 게임문화를 이해하기 위해서는 단순히 “게임이 인기다”라는 사실을 넘어서,
어떤 산업 구조가 형성되어 있는지, 이용자들이 어떤 방식으로 게임을 소비하는지, 그리고 e스포츠가 어떻게 운영되는지를 함께 살펴볼 필요가 있다.

중국 게임문화는 사회·경제·기술적 요인이 맞물리며 빠르게 변화하고 있으며, 이러한 복합적인 흐름 속에서 성장해 왔다.
따라서 중국 게임시장의 대표적 사례를 분석하는 일은 중국 디지털 게임문화의 형성과정은 물론, 앞으로 글로벌 게임산업에서 중국이 어떤 역할을 하게 될지 이해하는 데 중요한 의미를 가진다.

연구목적

상단으로 이동

본 연구의 목적은 급속히 성장하고 있는 중국의 디지털 게임문화를 산업적으로, 사회문화적인 방면에서 데이터에 근거하여 분석해보고,
그 형성과 발전 과정에 영향을 시대에 발맞추어 분석해보고자 한다.

이를 위해 먼저 중국 게임산업의 구조와 특징등을 다방면에서 살펴보고,
e스포츠 문화가 어떻게 발전되어 왔는지 알아보고자 한다.
또한 중국 e스포츠 산업의 성장 과정과 그 내부 구조를 조사함으로써,
e스포츠가 중국 사회에서 중요한 문화적 영역으로 자리 잡게 된 배경을 이해하고자 한다.

궁극적으로 본 연구는 중국 게임시장의 대표적 사례들을 토대로 미래전망을 분석할 수 있을 것이라 예측하며
① 중국 디지털 게임문화가 어떠한 방식으로 형성·발전해 왔는지
② 이러한 문화가 글로벌 게임산업 속에서 어떤 의미를 갖는지
③ 앞으로 중국이 게임·e스포츠 분야에서 어떤 역할을 수행하게 될지를 전망
하는데에 그 목적이 있다.

대상주제

상단으로 이동

다음 중국의 게임산업을 중심으로 다음 4가지의 방면에서 분석해 보고자 한다.

(1) 중국 게임산업 구조 분석 — 기업·게임·장르 중심
중국에서 개발·퍼블리싱된 게임
텐센트 등 주요 기업의 게임 포트폴리오
출시 연도, 장르, 플랫폼
을 분석하여 게임산업의 전체 구조를 파악.

(2) 게임 플랫폼·e스포츠 생태계 분석
e스포츠 리그(LoL, 왕자영요, PUBG 등)
리그 운영 기업
관련 경기장, 개최 지역
상금 규모, 참가 팀 수

(3) 그 중에서도 특별하게 lol을 주제로
인기 게임의 평가·수상 경력
게임 장르별 인기 추세(출시량 기준)
플레이어 국가·지역 통계(가능한 범위 내)
이를 통해 중국 게임문화의 소비 흐름을 파악.

(4) 중국 게임문화의 글로벌 확장 분석
중국 게임의 해외 출시 현황
해외 수상·평가
글로벌 리그 참가 팀 및 선수
을 분석하여 중국 게임의 글로벌 산업적 위치를 파악.

쿼리작성

상단으로 이동

1. 중국 게임 산업구조 분석

1. 게임관련 회사 분석
자연어 질의 : 중국 본사 또는 중국 기업 계열의 게임 산업 관련 회사들을 설립 연도순으로 나열해서 타임라인표로 봐보자..

#defaultView:Timeline
SELECT DISTINCT ?company ?companyLabel ?inception

WHERE {

  # 회사
  ?company wdt:P31 wd:Q4830453 .

  # 중국 본사 OR 중국 기업 계열
  {
    # 1. 본사가 중국
    ?company wdt:P159 ?hq .
    ?hq wdt:P17 wd:Q148 .
  }

  UNION
  {
    # 2. 중국 기업의 자회사
    ?company wdt:P749 ?parent .
    ?parent wdt:P17 wd:Q148 .
  }

  UNION
  {
    # 3. 중국 기업이 모회사
    ?parent wdt:P355 ?company .
    ?parent wdt:P17 wd:Q148 .
  }

  # 게임 산업 관련성
  {
    # A. 산업 분류
    ?company wdt:P452 ?industry .
    ?industry wdt:P279* wd:Q941594 .
  }

  UNION
  {
    # B. 게임 퍼블리셔
    ?game wdt:P31 wd:Q7889 ;
      wdt:P123 ?company .
  }

  UNION
  {
    # C. 게임 개발사
    ?game wdt:P31 wd:Q7889 ;
      wdt:P178 ?company .
  }

  # 회사 창립년도 (있으면)
  OPTIONAL {
    ?company wdt:P571 ?inception .
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

ORDER BY ?inception

2. 중국 게임 개발사 중 가장 많은 게임을 제작한 기업은 어디인가?
자연어 질의 : 중국 게임 회사에서 발행한 게임의 갯수를 분석하고, 상위 10개 기업만 바차트로 보여줘. 대신 자회사가 있다면 모회사에 합산해줘.
#defaultView:BarChart
SELECT ?rootCompany ?rootCompanyLabel (COUNT(DISTINCT ?game) AS ?gameCount)

WHERE {

  # 발행된 비디오 게임
  ?game wdt:P31 wd:Q7889 ;
    wdt:P123 ?company .

  # 회사는 company
  ?company wdt:P31 wd:Q4830453 .

  # 중국 본사 OR 중국 기업 계열
  {
    # 1. 본사가 중국
    ?company wdt:P159 ?hq .
    ?hq wdt:P17 wd:Q148 .
  }

  UNION
  {
    # 2. 중국 기업의 자회사
    ?company wdt:P749 ?parent .
    ?parent wdt:P17 wd:Q148 .
  }

  UNION
  {
    # 3. 중국 기업이 모회사
    ?parent wdt:P355 ?company .
    ?parent wdt:P17 wd:Q148 .
  }

  # 🔑 옵션 1 핵심: 모회사 있으면 모회사로 통합
  OPTIONAL {
    ?company wdt:P749 ?parentCompany .
    ?parentCompany wdt:P17 wd:Q148 .
  }

  BIND( COALESCE( ?parentCompany, ?company) AS ?rootCompany)

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

GROUP BY ?rootCompany ?rootCompanyLabel

ORDER BY DESC(?gameCount)

LIMIT 10

3. 대표 10개 기업 게임의 장르 알아보기
자연어 질의 : 중국 주요 게임 기업들이 발행한 비디오 게임들은 어떤 장르로 구성되어 있으며, 각 장르에는 어떤 게임들이 포함되는가?
#defaultView:TreeMap
SELECT ?genreLabel ?gameLabel (COUNT(?game) AS ?value)

WHERE {

  # 분석 대상 기업 (모회사 기준 결과)
  VALUES ?company {
    wd:Q860580   # Tencent
    wd:Q11325442 # NetDragon Websoft
    wd:Q196259   # NetEase
    wd:Q1439934 # Kingsoft
    wd:Q2994389 # Garena
    wd:Q1660544 # Playmates Toys
    wd:Q28691848 # Happy Elements
    wd:Q965133   # Sohu
    wd:Q4765195 # Animoca Brands
    wd:Q18208513 # Yodo1
  }

  # 발행된 비디오 게임 + 장르
  ?game wdt:P31 wd:Q7889 ;
    wdt:P123 ?company ;
    wdt:P136 ?genre .

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

GROUP BY ?genreLabel ?gameLabel

4. 텐센트에서 발행한 게임 나열해보기
자연어 질의 : 텐센트가 발행한 비디오 게임들을 알아보자..
SELECT DISTINCT ?game ?gameLabel

WHERE {

  # 비디오 게임
  ?game wdt:P31 wd:Q7889 ;
    wdt:P123 ?publisher .

  # 퍼블리셔가 텐센트이거나 텐센트 자회사인 경우
  {
    # 1. 퍼블리셔 = Tencent 또는 Tencent Games
    VALUES ?publisher {
      wd:Q860580 # Tencent
      wd:Q39057776 # Tencent Games
    }
  }

  UNION
  {
    # 2. 퍼블리셔가 Tencent의 자회사
    ?publisher wdt:P749 wd:Q860580 .
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

ORDER BY ?gameLabel

5. 텐센트에서 발행한 게임중 대중에게 인기가 많은 작품은 어떤것이 있을까
자연어 질의 : 텐센트가 발행한 비디오 게임들 중, 소셜 미디어 팔로워 수가 기록된 게임은 무엇이며,어떤 소셜 미디어 플랫폼에서 형성된 것인가?.
#defaultView:BarChart
SELECT ?game ?gameLabel ?followers ?platform

WHERE {

  ?game wdt:P31 wd:Q7889 ; # video game
    wdt:P123 ?publisher ; # publisher
    p:P8687 ?statement . # social media followers statement

  ?statement ps:P8687 ?followers . # follower count

  # 어떤 계정 qualifier가 붙어 있는지로 플랫폼 판별
  BIND(
    IF(EXISTS { ?statement pq:P2397 ?id }, "YouTube",
    IF(EXISTS { ?statement pq:P2013 ?id }, "Facebook",
    IF(EXISTS { ?statement pq:P6552 ?id }, "X (Twitter)",
    "Other")))
  AS ?platform
  )

  VALUES ?publisher {
    wd:Q860580 # Tencent
    wd:Q39057776 # Tencent Games
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

ORDER BY DESC(?followers)

2. 게임 플랫폼·e스포츠 생태계 분석

1. 중국국적의 esports 선수
자연어 질의 : 중국 e스포츠 선수들을 이름과 게임 종목 기준으로 나열하고, 출생연도 정보가 존재하는 경우에 한해 함께 나열해보자.

SELECT DISTINCT
  ?player ?playerLabel
  ?birthYear
  ?game ?gameLabel

WHERE {

  ?player wdt:P31 wd:Q5 ; # human
    wdt:P106 wd:Q4379701 ; # esports player
    wdt:P27 wd:Q148 . # nationality = China

  # 출생연도 (있으면)
  OPTIONAL {
    ?player wdt:P569 ?birthDate .
    BIND( YEAR(?birthDate) AS ?birthYear)
  }

  # 플레이한 게임 종목 (있으면)
  OPTIONAL {
    ?player wdt:P2416 ?game .
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

ORDER BY ?gameLabel ?playerLabel

2. 중국내에서 e스포츠를 개최할 수 있는 경기장의 위치를 매핑해보자.
자연어 질의 : 매핑.

SELECT DISTINCT

      ?venue ?venueLabel
      ?location

WHERE {

 # 경기장 / 아레나
 ?venue wdt:P31 ?type ;
        wdt:P17 wd:Q148 ;        # China
        wdt:P625 ?location ;     # 좌표
        wdt:P641 wd:Q300920 .    # 🔑 sport = esports

 VALUES ?type {
   wd:Q483110     # stadium
   wd:Q641226     # arena
 }

 SERVICE wikibase:label {
   bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en".
 }

}

3. 중국국적의 esports 프로게이머중 해외에서 활동 한 사람
자연어 질의 : 해외 팀(중국 외 국가의 팀)에 소속된 중국 e스포츠 선수는 누구인가?

SELECT DISTINCT
  ?player ?playerLabel
  ?team ?teamLabel
  ?teamCountry ?teamCountryLabel

WHERE {

  # 중국 e스포츠 선수
  ?player wdt:P31 wd:Q5 ; # human
    wdt:P106 wd:Q4379701 ; # esports player
    wdt:P27 wd:Q148 ; # nationality = China
    wdt:P54 ?team . # member of team

  # 팀의 국가
  ?team wdt:P17 ?teamCountry .

  # 해외 팀 (중국 제외)
  FILTER( ?teamCountry != wd:Q148 )

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

ORDER BY ?teamCountryLabel ?playerLabel

4. 해외국적의 esports 프로게이머중 중국에서 활동 한 사람
자연어 질의 : 중국 팀에 소속된 외국인(e스포츠) 선수는 누구인가?

SELECT DISTINCT
  ?player ?playerLabel
  ?playerCountry ?playerCountryLabel
  ?team ?teamLabel

WHERE {

  # e스포츠 선수
  ?player wdt:P31 wd:Q5 ; # human
    wdt:P106 wd:Q4379701 ; # esports player
    wdt:P27 ?playerCountry ; # nationality
    wdt:P54 ?team . # member of team

  # 중국 팀
  ?team wdt:P17 wd:Q148 . # team country = China

  # 외국인 선수 (중국 국적 제외)
  FILTER( ?playerCountry != wd:Q148 )

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en" .
  }

}

ORDER BY ?teamLabel ?playerLabel

5. 중국 내 스포츠리그 _ 중국 내에서 메이저 스포츠 리그가 있다면 어떤 리그가 있고, 롤 리그는 그중 얼마나 최근에 생겼을까
자연어 질의 : 중국 본사 또는 중국 기업 계열의 게임 산업 관련 회사들을 설립 연도순으로 나열해서 타임라인표로 봐보자..

자연어 질의 : 중국에서의 스포츠 리그에 대해 알아보자 SELECT ?league ?leagueLabel ?sport ?sportLabel ?countryLabel ?inception WHERE {

 # 스포츠 리그
 ?league wdt:P31 wd:Q623109.  # sports league

 # 운영 국가 = 중국
 OPTIONAL { ?league wdt:P17 ?country. }
 FILTER (?country = wd:Q148)

 # 종목 / 설립년도
 OPTIONAL { ?league wdt:P641 ?sport. }
 OPTIONAL { ?league wdt:P571 ?inception. }

 SERVICE wikibase:label { 
   bd:serviceParam wikibase:language "ko,en,zh". 
 }

} ORDER BY (?inception)

6. 중국 스포츠리그의 인기
자연어 질의 : 국내의 sports league 중에서 소셜미디어 팔로워중 유튜브 팔로워가 많은 순서대로 나열해보자.

SELECT ?league ?leagueLabel ?countryLabel ?youTubeChannelID ?youTubeHandle ?subs_wdt ?subs_social WHERE {

 # 항목이 sports league(또는 그 하위 클래스)이고, 국가가 중국(Q148)인 항목
 ?league (wdt:P31/wdt:P279*) wd:Q623109;   # instance of / subclass of sports league
         wdt:P17 wd:Q148.                  # country = China

​

 # YouTube 채널 ID (P2397) — 예: UC...
 OPTIONAL { ?league wdt:P2397 ?youTubeChannelID. }

​

 # YouTube handle (P11245) — 예: channel handle without '@'
 OPTIONAL { ?league wdt:P11245 ?youTubeHandle. }

​

 # 구독자 수(가능하면) — P3744 (number of subscribers)
 OPTIONAL { ?league wdt:P3744 ?subs_wdt. }

​

 # 또는 social media followers (P8687)로 기록된 경우 (종종 시점 qualifier와 함께)
 OPTIONAL {
   ?league p:P8687 ?sf.
   ?sf ps:P8687 ?subs_social.
   # (권장) 시점(point in time) qualifier 확인 가능:
   # OPTIONAL { ?sf pq:P585 ?subs_pointInTime. }
 }

​

 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }

}

1. 구독자 수가 둘 중 하나면 COALESCE로 정렬 (문자->숫자 변환 문제로 완벽하지 않을 수 있음)

ORDER BY DESC(COALESCE(xsd:integer(?subs_wdt), xsd:integer(?subs_social), 0)) LIMIT 200

중국 선수나이 SELECT ?birthYear (COUNT(?player) AS ?count) WHERE {

 ?player wdt:P31 wd:Q5 ;              # human
         wdt:P106 wd:Q4379701 ;       # occupation = esports player
         wdt:P27 wd:Q148 ;            # nationality = China
         wdt:P569 ?birthDate .        # date of birth

 BIND(YEAR(?birthDate) AS ?birthYear)

} GROUP BY ?birthYear ORDER BY ?birthYear

3. 리그 오브 레전드 리그

1. 중국 리그 오브 레전드 팀
2. 중국 리그 오브 레전드 선수 _ tree map 이용하면 좋을듯
자연어질의 : 중국사람인 리그오브레전드 선수를 찾아보자. _ 본명과 게임명
SELECT DISTINCT ?person ?personlabel WHERE {

 ?person wdt:P27 wd:Q148;

 wdt:P106 wd:Q4379701.

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko, zh, en" . }

}

3. 한국 리그에서 활동중인 중국인 선수 _ tree map 이용하면 좋을듯
자연어질의 : 한국 리그에서 활동중인 중국인 선수를 알아보자.

4. 중국 리그 오브 레전드 경기장
자연어질의 : 중국에서 리그오브 레전드 경기가 열리는 경기장의 위치를 지도에표시해보자.

5. 중국 리그 오브 레전드 우승횟수
1. 중국내 리그
2. 롤드컵

6. 베스트 이스포츠 팀에 뽑혀본 롤 팀
자연어질의 : The Game Awards − Best Esports Team에 뽑혀본 중국 팀

어떤 포지션의 선수가 제일 많은지 알아보기

4. 중국 게임문화의 글로벌 확장 분석

1. 중국 게임의 해외 출시 현황

2. 해외 수상작 유무

3. 대표게임별 글로벌 리그 참가 팀 및 선수

결과해석

상단으로 이동

===1. 분석결과===

===2. 쿼리 사용하며 아쉬웠던 점===

1. 원하는 데이터가 존재하지 않는것들이 많았다.

2. 연구 주제 설정의 한계가 발생.

3. 사회현상에 대한 자료를 분석하기는 한계가 보인다.

4. 어떻게 설정하는지에 따라 값이 바뀌다보니 디테일하게 설정해야 된다는걸 깨닳았다.

참고자원

상단으로 이동

(내용 서술)

주석

상단으로 이동