RCCTD(2026)Report04

데이터로 읽는 중국문화(강의) 페이지로 가기

중국 바둑의 황금기와 변화

- 1988년 이후 한·중 세계대회 우승 양상 비교를 중심으로-

사학과 송영준

목차

Contents

---

연구배경 연구목적 연구내용 참고자원

---

연구배경

상단으로 이동

바둑은 고대 중국에서 기원한 것으로 알려진 전통 보드게임으로, 사마천의 「사기(史記)」 속에도 주나라 시기 바둑에 대한 언급이 있다는 점에서, 최소 3000년 이상의 역사를 지닌 중국 유구의 마인드 스포츠이다. 특히 중국에서 바둑은 선비의 필수 교양으로 여겨진 금기서화(琴棋書畵) 중 하나로, 단순한 오락을 넘어 예술과 주요 문화로 인식돼 왔다.

오늘날에도 바둑은 종주국인 중국에서 인기 있는 종목이다. 중국의 바둑 인구는 약 6000만명으로, 900만 명 전후인 한국의 7배에 달한다. 비공인 세계랭킹인 고레이팅(GoRating)에 따르면, 2026년 10월 12일 기준 세계랭킹 1위부터 20위까지 중국 기사가 15명에 이를 정도로 중국은 가장 두터운 선수층을 보유한 국가이기도 하다.

그러나 압도적인 양적 우세에도 불구하고, 중국은 오랫동안 세계 대회에서 한국에 밀린다는 평가를 받아왔다. 바둑의 인기가 절정이던 90년대~2000년대는 이창호, 조훈현, 유창혁, 이세돌로 대표되는 한국 선수들이 세계대회를 휩쓸었다. 이러한 상황 속에서 중국은 2010년대 한·일 바둑계를 압도하며 동아시아 3국의 바둑 패권을 장악했다. 이 시기를 이른바 '중국 바둑의 황금기'라고 부른다. 이후로도 중국 바둑계는 성장을 거듭하며, 현재까지 바둑 패권을 두고 한국과 팽팽히 맞서고 있다.

주목할 점은 소수의 강자가 오랜 기간 동안 집중적으로 우승을 차지해 온 한국 바둑계와 달리, 중국 바둑계는 수많은 기사가 세계대회를 번갈아 우승하는 선수층의 차이를 보인다는 점이다. 특히 황금기엔 90년대생 신예 기사들이 세계 정상에 오르며 세대 교체가 이루어졌는데, 이는 중국 바둑계의 여러 역사, 문화적 배경에서 기인한다고 추론할 수 있다.

이러한 중국 바둑계의 변화를 확인하기 위해선 1988년 이후 진행된 세계대회 기록과 기사들의 인적 데이터를 연결해야 한다. 기존의 바둑 기록은 세계대회 기록과 인적 데이터를 별개로 다뤘지, 입체적으로 연결하는 시도는 부족했다. 따라서 본 연구는 위키데이터의 다양한 데이터를 통해, 세계대회 우승자의 국적, 연령, 출생지(학습 도장) 등을 세계대회 우승과 연결하여 시각화 하고자 한다.
이는 바둑을 매개로 중국 문화를 이해하고, 나아가 동아시아 3국 간 문화적 공감대와 유대감을 넓히는 시도가 될 것이다.

연구목적

상단으로 이동

1.) 메이저 세계바둑대회 우승 기록 데이터화
1988년 세계대회 출범 이후 현재까지의 우승 기록을 위키데이터 쿼리를 통해 추출한다. 제한기전과 메이저 세계대회를 구분하고, 대회 정보를 기사의 국적, 스포츠 국적과 연결한다.

2.) 중국 바둑의 황금기 분석
2010년대 중국 바둑에 황금기가 도래한 이유를, 당시 세계대회 우승자를 그들의 출생 연도, 우승 당시 연령, 출생지, 출신 도장 등의 데이터와 연결하여 분석한다.

3.) 결과 분석 및 시각화
위키데이터가 2번까지의 과정을 수행해 줄 수는 있지만, 이 데이터를 기반으로 "왜 중국 바둑의 황금기가 그때 도래했는가?"라는 질문에 답할 순 없다. 따라서 데이터와 기타 자료를 바탕으로 인문학적 소양을 발휘해 위 질문을 해결한다.

또한 데이터 결과를 공간축과 시간축 두 가지로 나눠 시각화한다. 공간축은 우승자의 출생지와 출신 도장을 지도 API에 연결해 어느 지역에서 우승자를 많이 배출했는지를 시간의 흐름과 함께 볼 수 있게 한다. 시간축은 우승자의 출생 연도와 우승 당시 연령을 시계열 그래프로 나타내어, 시간에 따른 국가 간 패권의 이동과 90년대생 젊은 기사의 등장과 활약을 확인할 수 있게 한다.

연구과정

상단으로 이동

1.) 바둑기사 분류

본 연구의 대상은 프로 바둑기사이므로, 직업 분류인 P106에서 바둑기사에 해당하는 항목인 Q3186699 (go professional)를 통해 바둑기사를 분류한다.

SELECT ?person ?personLabel
WHERE {
  ?person wdt:P106 wd:Q3186699.     # 프로 바둑기사 (직업)
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "ko,en".
  }
}

---

2.) 바둑기사 국적 분류

세계대회 우승 경험이 있는 국가인 한국, 중국, 일본, 대만의 바둑기사의 국적을 분류한다.
국적 분류인 P27을 활용한다.

유의할 점은 바둑기사의 국적과 소속 기원이 다른 경우이다. 예를 들어 2003년 삼성화재배 우승자인 조치훈의 국적은 대한민국이지만 소속 기원은 일본기원이기에, 이는 일본의 세계대회 우승으로 분류해야 한다.
따라서 국적과 별개로 country for sport (P1532) 속성을 활용해, 국적과 활동 국가(스포츠 국적)를 모두 표기한다.

SELECT DISTINCT ?person ?personLabel ?nationalityLabel ?sportCountryLabel
WHERE {
  ?person wdt:P106 wd:Q3186699;     # 프로 바둑기사 (직업)
          wdt:P27 ?nationality.     # 국적
  OPTIONAL { ?person wdt:P1532 ?sportCountry. } # 활동 국가 (스포츠 국적)

  VALUES ?nationality {
    wd:Q884 # 한국 국적
    wd:Q148 # 중국 국적
    wd:Q17 # 일본 국적
    wd:Q865 # 대만 국적
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "ko,en".
  }
}
ORDER BY ?nationalityLabel ?sportCountryLabel ?personLabel

여기서 Q884는 한국 국적이다. 중국 국적은 Q148, 일본 국적은 Q17이다. 대만 국적은 Q865이다.

---

3.) 세계대회 우승자와 국적별 분류

위 과정을 통해 직업이 바둑기사인 인물을 국적, 소속별로 분류했다.
이제 세계대회 우승 경험이 있는 바둑기사를 국적, 소속별로 분류해야 한다.

그러나 일반적으로 쓰이는 competition won (P2522)이나 winner (P1346) 속성은 말 그대로 특정 선수가 우승한 대회나 대회의 우승자를 뜻하는 속성이다. 이 두 속성만으로 쿼리를 짠다면 아래와 같은 문제가 발생할 수 있다.

두 속성은 모든 바둑대회에 대한 속성으로, 해당 대회가 세계대회인지 국내대회인지, 이벤트 대회인지를 직접 구분할 수는 없다. 따라서 두 속성만으로 검색할 시 세계대회뿐 아니라 다른 유형의 대회까지 포함됨을 확인할 수 있다.
누적 우승이 100회가 넘는 기사들도 존재하기에, 이런 방식으로 분류하는 것은 비효율적이라 할 수 있다.

따라서 본 연구에선 ‘세계대회’를 우선으로 분류하고, 그 대회의 우승자 속성을 통해 세계대회 우승자를 분류하고자 한다.

SELECT ?item ?itemLabel
WHERE {
  ?item rdfs:label "world Go competition"@en. # 영문 라벨이 'world Go competition'인 항목 검색
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "ko,en".
  }
}

이 쿼리를 통해 world Go competition의 QID는 (Q10869075)임을 확인할 수 있다.

---

4.) 세계대회 구분과 분류

이제 위키데이터에서 Q10869075로 분류된 세계대회 항목을 검색해 보자.

world Go competition

SELECT ?competition ?competitionLabel
WHERE {
  ?competition wdt:P279* wd:Q10869075.        # 세계 바둑 대회(Q10869075)의 하위 분류
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "ko,en".
  }
}

이 중 제한 기전인 World Amateur Go Championship, 중환배, 보해배, 글로비스배, 월드바둑챔피언십은 본 연구에서 제외해야 한다.
FILTER 조건을 추가하여, 지정한 다섯 대회를 출력에서 제외한다. 개별 대회명이 아닌 상위 분류 항목(world Go competition) 역시 제외한다.

SELECT ?competition ?competitionLabel
WHERE {
  ?competition wdt:P279* wd:Q10869075.        # 세계 바둑 대회(Q10869075)의 하위 분류
  FILTER(?competition != wd:Q10869075)        # 상위 분류(world Go competition) 자체 제외

  FILTER NOT EXISTS {
    ?competition rdfs:label ?excludedName.    # 제외할 대회 라벨 지정
    FILTER(LANG(?excludedName) IN ("ko", "en")) # 한국어 및 영어 라벨 대상
    FILTER(REGEX(
      STR(?excludedName),
      "World Amateur Go Championship|중환배|Zhonghuan Cup|보해배 세계여자바둑선수권|Bohae Cup|글로비스배|Globis Cup|월드바둑챔피언십|World Go Championship", # 제한 기전 및 제외 대상 대회 필터링
      "i"
    ))
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "ko,en".
  }
}

본 연구에서 다룰 메이저 세계대회만 출력됨을 볼 수 있다.

• 단, 2023년 창설된 ‘취저우 란커배 세계 바둑 오픈전’ 대회는 위키데이터 자체에 등록되지 않았기에 별도로 확인해야 한다.
  
• 또한 유일한 메이저 국가대항전인 ‘농심신라면배 국가대항전’은 일반 세계대회의 속성으론 찾을 수 없기에 별도로 확인해야 한다.
  

---

5.) 세계대회 우승과 인적 데이터 연결

4번까지의 과정을 통해 바둑기사와 대회 목록을 정리했기에, 이젠 이를 누가 언제 어느 대회에서 우승했는지와 연결해야 한다.
메이저 세계대회, 바둑기사의 국적, 스포츠 국적 이 세 조건을 결합해, 각 대회의 우승자를 출력한다.

다만 대회와 우승자가 모두 동일한 방식으로 연결되지 않았을 가능성을 고려해야 한다. UNION(합집합)을 사용해, 아래 세 가지 경로를 모두 수집한다.

1.) 세계대회(?competition)의 하위 회차 항목(?edition)에 우승자(P1346)가 등록된 경우 (P31, P361, P179 활용)
2.) 회차 구분 없이 세계대회 항목 자체에 우승자(P1346)와 시점 한정자(pq:P585)가 직접 등록된 경우
3.) 바둑기사(?person) 항목에 우승한 대회(P2522) 속성이 등록된 경우

또한 바둑대회는 해를 넘겨 진행되는 경우가 많기에, 편집자에 따라 대회 연도의 분류가 시점(P585)과 시작 시점(P580)으로 나뉘어 있다.
따라서 | 기호를 사용하여 두 가지 모두를 쿼리에 담아야 한다.

앞서 국적과 스포츠 국적이 다른 조치훈의 예를 통해 스포츠 국적의 필요성을 설명한 바 있다. 그러나 이 속성이 입력되지 않은 경우의 수를 고려해 OPTIONAL을 사용한다. OPTIONAL은 일종의 안전장치로, 해당 속성이 없다 할지라도 결과에서 제외하지 않고 공백으로 표기하라는 뜻의 문법이다.

SELECT DISTINCT ?competition ?competitionLabel ?editionLabel ?year ?person ?personLabel ?nationalityLabel ?sportCountryLabel
WHERE {
  # 1. 메이저 세계대회 분류 및 제한기전 제외 (3번 쿼리 조건)
  ?competition wdt:P279* wd:Q10869075.
  FILTER(?competition != wd:Q10869075)
  FILTER NOT EXISTS {
    ?competition rdfs:label ?excludedName.
    FILTER(LANG(?excludedName) IN ("ko", "en"))
    FILTER(REGEX(
      STR(?excludedName),
      "World Amateur Go Championship|중환배|Zhonghuan Cup|보해배 세계여자바둑선수권|Bohae Cup|글로비스배|Globis Cup|월드바둑챔피언십|World Go Championship",
      "i"
    ))
  }

  # 2. 대회(또는 회차별 대회)와 우승자 연결 (위키데이터 내 3가지 입력 방식 모두 수집)
  {
    # 방식 A: 회차별 항목(?edition)이 세계대회(?competition)의 하위/부분/인스턴스이고 우승자(P1346)가 등록된 경우
    ?edition (wdt:P31|wdt:P361|wdt:P179) ?competition;
             wdt:P1346 ?person.
    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }
  }
  UNION
  {
    # 방식 B: 세계대회(?competition) 항목 자체에 우승자(P1346)와 시점 한정자(pq:P585)가 직접 등록된 경우
    ?competition p:P1346 ?winnerStmt.
    ?winnerStmt ps:P1346 ?person.
    BIND(?competition AS ?edition)
    OPTIONAL { ?winnerStmt pq:P585 ?date. }
  }
  UNION
  {
    # 방식 C: 기사(?person) 항목에 우승한 대회(P2522)로 세계대회 또는 그 회차가 등록된 경우
    ?person wdt:P2522 ?edition.
    ?edition (wdt:P31*|wdt:P361*|wdt:P179*) ?competition.
    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }
  }

  # 3. 프로 바둑기사 및 4개국 국적 분류 (1~2번 쿼리 조건)
  ?person wdt:P106 wd:Q3186699;
          wdt:P27 ?nationality.
  VALUES ?nationality {
    wd:Q884 # 한국 국적
    wd:Q148 # 중국 국적
    wd:Q17 # 일본 국적
    wd:Q865 # 대만 국적
  }

  OPTIONAL { ?person wdt:P1532 ?sportCountry. } # 스포츠 국적(소속 기원 국가)이 있는 경우 함께 표기
  BIND(YEAR(?date) AS ?year)                    # 날짜에서 연도만 추출

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "ko,en,zh".
  }
}
ORDER BY ?year ?competitionLabel ?personLabel

이 쿼리를 수행할 시 다음과 같은 문제점을 확인할 수 있다.

1.) 대회 중복
상기했듯 해를 넘겨 진행되는 대회가 중복 출력된다.

2.) 대회 누락
1991년 이전과 2021년 이후 세계대회 누락이 발생한다.

3.) 대회명 표기
‘삼성화재배 월드 바둑마스터스' – '신진서'나 ‘잉창치배 – 이치리키 료’와 같이 특정 회차가 아닌 대회명 자체가 표기되는 문제가 발생한다.

해당 문제들은 향후 기말과제까지 필히 개선해야 할 부분이다.

---

6.) 세계대회와 우승자의 인적 데이터 결합 2

일단 상술한 문제점은 남겨둔 채, 원래 계획인 세계대회와 우승자의 인적 데이터를 결합하는 마지막 단계를 진행한다.
기사의 출생일(P569)과 출생지(P19) 속성을 추가하고, BIND 함수를 통해 우승 연도와 출생 연도의 차이를 계산하여 우승 연령을 산출한다. 출력할 변수명은 다음과 같다.

?competitionLabel : 대회명
?editionLabel : 회차
?year : 우승 연도
?personLabel : 우승자
?birthYear : 출생 연도
?winAge : 우승 연령 (?year - ?birthYear)
?birthPlaceLabel : 출생지
?nationalityLabel : 국적
?sportCountryLabel : 스포츠 국적

SELECT DISTINCT ?competitionLabel ?editionLabel ?year ?personLabel ?birthYear ?winAge ?birthPlaceLabel ?nationalityLabel ?sportCountryLabel
WHERE {
  # 1. 메이저 세계대회 분류 및 제한기전 제외 (3번 쿼리 조건)
  ?competition wdt:P279* wd:Q10869075.
  FILTER(?competition != wd:Q10869075)
  FILTER NOT EXISTS {
    ?competition rdfs:label ?excludedName.
    FILTER(LANG(?excludedName) IN ("ko", "en"))
    FILTER(REGEX(
      STR(?excludedName),
      "World Amateur Go Championship|중환배|Zhonghuan Cup|보해배 세계여자바둑선수권|Bohae Cup|글로비스배|Globis Cup|월드바둑챔피언십|World Go Championship",
      "i"
    ))
  }

  # 2. 대회(또는 회차별 대회)와 우승자 연결 (위키데이터 내 3가지 입력 방식 모두 수집)
  {
    # 방식 A: 회차별 항목(?edition)이 세계대회(?competition)의 하위/부분/인스턴스이고 우승자(P1346)가 등록된 경우
    ?edition (wdt:P31|wdt:P361|wdt:P179) ?competition;
             wdt:P1346 ?person.
    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }
  }
  UNION
  {
    # 방식 B: 세계대회(?competition) 항목 자체에 우승자(P1346)와 시점 한정자(pq:P585)가 직접 등록된 경우
    ?competition p:P1346 ?winnerStmt.
    ?winnerStmt ps:P1346 ?person.
    BIND(?competition AS ?edition)
    OPTIONAL { ?winnerStmt pq:P585 ?date. }
  }
  UNION
  {
    # 방식 C: 기사(?person) 항목에 우승한 대회(P2522)로 세계대회 또는 그 회차가 등록된 경우
    ?person wdt:P2522 ?edition.
    ?edition (wdt:P31*|wdt:P361*|wdt:P179*) ?competition.
    OPTIONAL { ?edition (wdt:P585|wdt:P580) ?date. }
  }

  # 3. 프로 바둑기사 및 4개국 국적 분류 (1~2번 쿼리 조건)
  ?person wdt:P106 wd:Q3186699;
          wdt:P27 ?nationality.
  VALUES ?nationality {
    wd:Q884 # 한국 국적
    wd:Q148 # 중국 국적
    wd:Q17 # 일본 국적
    wd:Q865 # 대만 국적
  }

  OPTIONAL { ?person wdt:P1532 ?sportCountry. } # 스포츠 국적(소속 기원 국가)이 있는 경우 함께 표기

  # 4. 인적 데이터(출생일 P569, 출생지 P19) 추가 및 연도·우승 연령 계산
  OPTIONAL { ?person wdt:P569 ?birthDate. }     # 출생일
  OPTIONAL { ?person wdt:P19 ?birthPlace. }     # 출생지

  BIND(YEAR(?date) AS ?year)                    # 날짜에서 우승 연도 추출
  BIND(YEAR(?birthDate) AS ?birthYear)          # 출생일에서 출생 연도 추출
  BIND(?year - ?birthYear AS ?winAge)           # 우승 연령 계산 (우승 연도 - 출생 연도)

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "ko,en,zh".
  }
}
ORDER BY ?year ?competitionLabel ?personLabel

다음과 같이 세계대회와 선수들의 인적 데이터가 결합된 것을 볼 수 있다.

위 과정까지로 1차(중간) 연구는 끝났다. 2차(기말) 연구는 다음 순서로 진행할 것이다.

1.) 상술한 세계대회 출력 문제(중복·누락·대회명 표기) 해결
2.) 세계대회에 출력되지 않는 란커배와 농심배 해결
3.) 결합된 데이터와 중국 지도 GIS 결합 등 시공간 시각화
4.) 연구 결과 분석

---

참고자원

상단으로 이동

참고자원

상단으로 이동

[현재 연구에 참고한 자료]

1. Wikidata Query Service
  - https://query.wikidata.org/

2. 관련 속성

  - Occupation(P106): https://www.wikidata.org/wiki/Property:P106
  - Country of citizenship(P27): https://www.wikidata.org/wiki/Property:P27
  - Country for sport(P1532): https://www.wikidata.org/wiki/Property:P1532
  - Subclass of(P279): https://www.wikidata.org/wiki/Property:P279
  - Instance of(P31): https://www.wikidata.org/wiki/Property:P31
  - Part of(P361): https://www.wikidata.org/wiki/Property:P361
  - Part of the series(P179): https://www.wikidata.org/wiki/Property:P179
  - Winner(P1346): https://www.wikidata.org/wiki/Property:P1346
  - Victory(P2522): https://www.wikidata.org/wiki/Property:P2522
  - Point in time(P585): https://www.wikidata.org/wiki/Property:P585
  - Start time(P580): https://www.wikidata.org/wiki/Property:P580
  - Date of birth(P569): https://www.wikidata.org/wiki/Property:P569
  - Place of birth(P19): https://www.wikidata.org/wiki/Property:P19

3. 원 출처

  - GoRatings: https://www.goratings.org/
    → 바둑기사의 직업, 종목 특성
  - 한국기원: https://www.baduk.or.kr/
    → 한국기사의 국적, 출생 정보 등 인적 사항
  - 일본기원·관서기원: https://www.nihonkiin.or.jp / https://kansaikiin.jp/
    → 일본기사의 국적, 출생 정보 등 인적 사항
  - 시나바둑: http://sports.sina.com.cn/go/
    → 중국기사의 국적, 출생 정보 등 인적 사항
  - 위키백과: https://zh.wikipedia.org/wiki/%E4%B8%96%E7%95%8C%E5%9B%B4%E6%A3%8B%E5%A4%A7%E8%B5%9B%E5%88%97%E8%A1%A8
    → 세계대회 목록

---

  - 사진 출처: https://sports.sina.com.cn/go/2026-10-16/doc-inivkwti7031200.shtml

https://www.goratings.org/ko/.shtml

---

[앞으로 조사할 참고자료]

1. 중국 지도 GIS

주석

상단으로 이동