RCCTD WikiDataCuration08

데이터로 읽는 중국문화(강의) 페이지로 가기

중국 불교의 시공간적 분포와 승려의 사회적 활동

: 사찰의 지리적 위치와 승려의 직업 및 활동 상관관계를 중심으로

김은지

목차

Contents

---

연구배경 연구목적 대상주제 쿼리작성 결과해석 참고자원 연구후기

---

연구배경

상단으로 이동

중국 불교는 아주 긴 역사를 가지고 있고 그만큼 스님들과 사찰에 대한 기록도 엄청나게 많습니다. 지금까지의 연구들은 문헌을 꼼꼼히 읽으면서 이런 기록들을 아주 잘 정리해 왔습니다. 덕분에 불교의 역사를 깊이 이해할 수 있게 되었습니다.

하지만 책에 적힌 글자만으로는 수많은 사찰이 중국 땅 어디에 퍼져 있는지, 사찰이 위치와 승려들의 출생지와 관련있는지 같은 자세한 정보를 한눈에 알아보기가 어렵습니다. "어느 지역에 절이 제일 많지?", "문화대혁명 때 얼마나 많은 절이 사라졌을까?" 같은 질문은 글만 읽어서는 답을 찾기가 쉽지 않기 때문입니다.

그래서 이런 역사 기록들을 컴퓨터가 이해할 수 있는 데이터로 만들어서 분석하려고 합니다. 위키데이터 같은 곳에 정리된 정보를 활용하면 복잡한 불교 역사를 지도 위에 그리거나 그래프로 만들어서 쉽게 볼 수 있습니다.

이 연구는 기존의 훌륭한 역사 기록들을 SPARQL을 이용해 정리해 보는 시도입니다. 특히 사찰의 위치와 스님들의 정보를 연결해서 분석해 보면 예전에는 미처 발견하지 못했던 중국 불교의 새로운 흐름이나 특징을 찾아낼 수 있을 것입니다.

연구목적

상단으로 이동

1. 불교 문화의 중심지가 어디인지 지역별로 분석합니다.

현재 중국의 행정구역 중 가장 많은 사원이 남아있는 곳이 어디인지 데이터를 통해 확인합니다. 또한 승려들의 출생지를 함께 분석하여 사찰이 많은 지역과 인물을 많이 배출한 지역이 일치하는지, 아니면 시대에 따라 불교의 중심지가 달랐는지 비교합니다.

2. 역사의 흐름에 따른 사찰의 흥망성쇠를 시각화합니다.

과거부터 현재까지 사원이 가장 많이 건립된 시기가 언제인지 파악하여 불교의 전성기를 데이터로 증명합니다. 반대로 문화대혁명과 같은 역사적 사건 당시에 구체적으로 얼마나 많은 사원이 소실되었는지 수치로 확인하여, 정치적 사건이 불교에 미친 영향을 분석합니다.

3. 승려들의 스승과 제자 관계를 연결하여 인물들을 살펴봅니다.

문헌에 기록된 승려들의 스승과 제자 관계 데이터를 연결하여 불교의 가르침이 인물과 인물을 통해 어떻게 이어져 왔는지 관계를 파악합니다. 이를 통해 가장 많은 제자를 배출한 핵심적인 스승이 누구인지 찾고 과거의 승려 중심 데이터와는 다른 불교와 관련된 현대인의 직업들을 분석합니다.

대상주제

상단으로 이동

본 연구는 위키데이터에 등록된 데이터 중, 중국의 불교 사원과 승려를 핵심 분석 대상으로 삼습니다. 구체적인 범위는 다음과 같습니다.

1. 중국 불교 사원 데이터

위키데이터에서 '중국'에 위치한 '불교 사원'을 대상으로 하며, 다음 세 가지 정보를 중점적으로 수집합니다.

행정구역 정보: 사원이 현재 중국의 어느 성(省)이나 시(市)에 속해 있는지 파악하여 지역별 분포를 봅니다.

건립 시기: 사원이 처음 세워진 날짜(연도)를 수집하여 시대별 사원 건립 추이를 분석합니다.

문화재 지정 현황: 문화재로 등록된 사원의 데이터를 수집합니다. 이를 통해 역사적 가치를 인정받아 현재까지 보존되고 있는 사원들의 현황과 분포를 파악합니다.

2. 중국 승려 인물 데이터

중국 역사 속에 존재했던 승려들을 대상으로 하며, 다음 두 가지 정보를 중심으로 분석합니다

출생지 정보: 승려들이 태어난 지역 데이터를 수집하여, 시대별로 어느 지역에서 승려가 많이 배출되었는지 확인합니다.

출생 시기: 승려가 태어난 연도를 함께 수집하여, 특정 시기에 특정 지역에서 인물이 집중되는 경향이 있는지 봅니다.

쿼리작성

상단으로 이동

1. 불교 문화의 중심지

1.현재 중국 내 1급 행정구역(성/직할시) 중 불교 사원이 가장 많이 분포한 지역은 어디?

 #defaultView:BubbleChart
SELECT ?province ?provinceLabel (COUNT(DISTINCT ?temple) AS ?templeCount)

WHERE {
   ?temple wdt:P31/wdt:P279* wd:Q5393308. #사원
   ?temple wdt:P17 wd:Q148. #중국
   ?temple wdt:P131+ ?province. #사원이 속한 행정구역 찾음
   ?province wdt:P131 wd:Q148. #1급 행정구역(성/직할시)만 남김
 SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
}
GROUP BY ?province ?provinceLabel ORDER BY DESC(?templeCount) LIMIT 50


2.중국의 전국중점문물보호단위(국보급 문화재)로 지정된 사원이 많은 지역은?

 #defaultView:BubbleChart
SELECT ?province ?provinceLabel (COUNT(DISTINCT ?temple) AS ?templeCount) 

WHERE {
  ?temple wdt:P31/wdt:P279* wd:Q5393308. 
  ?temple wdt:P1435 wd:Q1188574. #국보급 문화재로 등록된 사원을찾음
  ?temple wdt:P17 wd:Q148.         
  ?temple wdt:P131+ ?province.     
  ?province wdt:P131 wd:Q148.     
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }

}GROUP BY ?province ?provinceLabel
 ORDER BY DESC(?templeCount)


3.중국의 전국중점문물보호단위 사원의 위치는?

SELECT ?temple ?templeLabel ?location ?locationLabel ?coord 

WHERE {
  ?temple wdt:P31/wdt:P279* wd:Q5393308.
  ?temple wdt:P1435 wd:Q1188574.
  ?temple wdt:P17 wd:Q148.
  ?temple wdt:P131 ?location. #행정구역
  ?temple wdt:P625 ?coord #좌표
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}


4.승려들의 출생지 분포

 #defaultView:Map
SELECT ?monk ?monkLabel ?birthPlace ?birthPlaceLabel ?coord ?layer

WHERE {
  ?monk wdt:P106 wd:Q854997.
  VALUES ?layer { 
    wd:Q9683  # 당나라주황
    wd:Q7462  # 송나라보라
    wd:Q7313  # 원나라핑크
    wd:Q9903  # 명나라갈색
    wd:Q8733  # 청나라초록
    wd:Q148   # 중화인민공화국파랑
    wd:Q29520 # 중국(포괄적의미)빨강
  }
  ?monk wdt:P27 ?layer. #왕조별 색 구분
  ?monk wdt:P19 ?birthPlace.  #출생지
  ?birthPlace wdt:P625 ?coord. #출생지좌표
  ?birthPlace wdt:P131* ?modernCountry. 
  VALUES ?modernCountry { wd:Q148 wd:Q29520 } #국적
  SERVICE wikibase:label { bd:serviceParam wikibase:language 
"[AUTO_LANGUAGE],ko,zh,en". }
} LIMIT 500

5.현재는 사라진 사원은?

SELECT DISTINCT ?place ?placeLabel ?demolishedDate ?image

WHERE {
  ?place wdt:P576 ?demolishedDate. #파괴되거나 없어진 날짜가 기록된 곳
  ?place wdt:P17 wd:Q148.
  { ?place wdt:P31/wdt:P279* wd:Q5393308. } #사원이나
  UNION
  { ?place wdt:P31/wdt:P279* wd:Q21550442. } #석굴사원인곳
  OPTIONAL { ?place wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". }
}
ORDER BY DESC(?demolishedDate) 

2. 시대의 흐름으로 본 중국 불교의 전성기와 쇠퇴기

1.불교 사원 건립 연도별/세기별 추이 그래프
(연도별)
 #defaultView:LineChart
SELECT ?year (COUNT(?temple) AS ?count)
 WHERE {
  ?temple wdt:P31/wdt:P279* wd:Q5393308. #사원의 하위 개념 모두 포함
  ?temple wdt:P17 wd:Q148. #중국
  ?temple wdt:P571 ?date. #건립일
  BIND(YEAR(?date) AS ?year) #연도만
}
GROUP BY ?year #같은 연도에 지어진 사원끼리 묶음
ORDER BY ?year #과거부터 최근 순서대로 정렬


1.불교 사원 건립 연도별/세기별 추이 그래프
(세기별)
#defaultView:BarChart
SELECT ?centuryLabel (COUNT(?temple) AS ?count)

WHERE {
  ?temple wdt:P31/wdt:P279* wd:Q5393308. 
  ?temple wdt:P17 wd:Q148.               
  ?temple wdt:P571 ?date.                
  BIND(YEAR(?date) AS ?year)             
  #(연도-1) ÷ 100 한 뒤 소수점 버림 + 1 = 세기 
  BIND(FLOOR((?year - 1) / 100) + 1 AS ?century)
  #그래프 X축에 '세기'를 붙여 시각화
  BIND(CONCAT(STR(?century), " 세기") AS ?centuryLabel)
}

GROUP BY ?century ?centuryLabel  #같은 세기에 지어진 사원끼리 묶음
ORDER BY ?century                #1세기부터 시간 순서대로 나열


2.국보급(전국중점문물보호단위) 사원의 건립 시기는?

 #defaultView:BarChart
SELECT ?centuryLabel (COUNT(?temple) AS ?count) 

WHERE {
  ?temple wdt:P31/wdt:P279* wd:Q5393308.
  ?temple wdt:P17 wd:Q148.
  ?temple wdt:P1435 wd:Q1188574. #국보급(전국중점문물보호단위)으로 지정된 사원만
  ?temple wdt:P571 ?date. #사원의 최초 건립일
  BIND(YEAR(?date) AS ?year) 
  BIND(FLOOR((?year - 1) / 100) + 1 AS ?century) #연도를 세기로 변환
  BIND(CONCAT(STR(?century), " 세기") AS ?centuryLabel) 
}
GROUP BY ?century ?centuryLabel #같은 세기끼리 묶어서 수량을 셈
ORDER BY ?century


3.20세기 이후 연대별(10년 단위) 건립된 사원은?

 #defaultView:TreeMap
SELECT ?decadeLabel ?itemLabel (1 AS ?size)

WHERE {
  ?item wdt:P31/wdt:P279* wd:Q5393308.
  ?item wdt:P17 wd:Q148.
  ?item wdt:P571 ?date.
  FILTER(YEAR(?date) >= 1900) #20세기이후
   #5.연대 계산 (예: 1953 -> 1950)
  BIND(FLOOR(YEAR(?date)/10)*10 AS ?decade)
  BIND(CONCAT(STR(?decade), "s") AS ?decadeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language 
"[AUTO_LANGUAGE],ko,en". } }


4.중국 불교 승려의 생애주기를 타임라인으로!

#defaultView:Timeline
SELECT ?person ?personLabel ?birthDate ?deathDate

WHERE {
  VALUES ?country { wd:wd:Q9683  # 당나라
    wd:Q7462  # 송나라
    wd:Q7313  # 원나라
    wd:Q9903  # 명나라
    wd:Q8733  # 청나라
    wd:Q7209  # 한나라
    wd:Q148 }  # 중화인민공화국
  ?person wdt:P106 wd:Q854997;
          wdt:P27 ?country.
  #출생일과 사망일이 모두 있는 경우만
  ?person wdt:P569 ?birthDate.
  OPTIONAL { ?person wdt:P570 ?deathDate. }
  FILTER(YEAR(?birthDate) >= 400)  #5세기(401년) 이후 데이터만 보기
  SERVICE wikibase:label { bd:serviceParam wikibase:language 
"[AUTO_LANGUAGE],ko,en". } }
LIMIT 50

5.문화대혁명 시기에 건립된 사원 목록

SELECT ?year ?temple ?templeLabel ?locationLabel 

WHERE {
  ?temple wdt:P31/wdt:P279* wd:Q5393308. #사원
  ?temple wdt:P17 wd:Q148. #중국
  ?temple wdt:P571 ?date. #건립일
  BIND(YEAR(?date) AS ?year) #연도만
  FILTER(?year >= 1966 && ?year <= 1976) #문화대혁명 기간 필터링
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}
ORDER BY ?year

3. 인물로 보는 중국 불교

1.스승과 제자로 이어진 중국 승려

 #defaultView:Graph
SELECT ?monk ?monkLabel ?teacher ?teacherLabel

WHERE {
  ?monk wdt:P106 wd:Q854997. #승려
  VALUES ?country { 
    wd:Q9683  # 당나라
    wd:Q7462  # 송나라
    wd:Q7313  # 원나라
    wd:Q9903  # 명나라
    wd:Q8733  # 청나라
    wd:Q7209  # 한나라
    wd:Q148   # 중화인민공화국
    wd:Q29520 } 
  ?monk wdt:P27 ?country. #위에서 정한 국적의 승려
  ?monk wdt:P1066 ?teacher. #스승
  SERVICE wikibase:label { bd:serviceParam wikibase:language
  "[AUTO_LANGUAGE],ko,zh,en". }
}
LIMIT 50


2.많은 제자를 배출한 승려들의 다른 직업은?

 #defaultView:Table
SELECT ?monkLabel ?dynastyLabel (COUNT(DISTINCT ?student) AS ?studentCount) 

(GROUP_CONCAT(DISTINCT ?otherJobLabel; separator=", ") AS ?otherProfessions)

WHERE {
  ?monk wdt:P106 wd:Q854997.   #승려
  VALUES ?dynasty { 
    wd:Q9683  wd:Q8733  
    wd:Q7462  wd:Q7313
    wd:Q7209  wd:Q148 
    wd:Q9903 wd:Q29520}
  ?monk wdt:P27 ?dynasty. #승려의 국적
  ?monk wdt:P802 ?student. #제자
 #다른 직업 찾기(없어도 승려 이름은 나오도록)
  OPTIONAL {
    ?monk wdt:P106 ?job. #승려의 모든 직업 가져옴
    FILTER(?job != wd:Q854997)   #'승려'라는 직업은 제외하고 나머지만 나타나도록  
    ?job rdfs:label ?otherJobLabel.
    FILTER(LANG(?otherJobLabel) = "ko") }

  SERVICE wikibase:label { bd:serviceParam wikibase:language 
"[AUTO_LANGUAGE],ko,zh,en". }} 
GROUP BY ?monkLabel ?dynastyLabel #승려 이름과 왕조별로 묶음
ORDER BY DESC(?studentCount) #제자가 많은 순서대로 내림차순
LIMIT 50


3.과거의 승려들이 가장 많이 가진 직업은?

 #defaultView:BarChart
SELECT ?otherJobLabel (COUNT(DISTINCT ?person) AS ?count)
WHERE {
 VALUES ?country { 
wd:Q9683  wd:Q8733  
wd:Q7462  wd:Q7313
wd:Q7209   wd:Q9903 }
 ?person wdt:P27 ?country. #국적
 ?person wdt:P106 wd:Q854997. #승려
 ?person wdt:P106 ?otherJob. #다른 직업
 FILTER(?otherJob != wd:Q854997) #'승려'는 제외하고 나머지
 SERVICE wikibase:label { bd:serviceParam wikibase:language
 "[AUTO_LANGUAGE],ko,zh,en". }} 
GROUP BY ?otherJobLabel #직업별로 묶음
ORDER BY DESC(?count) #많이 나온 직업 순서대로 LIMIT 20 #상위20개만


4.시인 혹은 작가의 직업을 가진 승려의 대표작은?

SELECT DISTINCT ?person ?personLabel ?work ?workLabel
WHERE { 
  
  VALUES ?country { wd:Q9683  # 당나라
    wd:Q7462  # 송나라
    wd:Q7313  # 원나라
    wd:Q9903  # 명나라
    wd:Q8733  # 청나라
    wd:Q7209  # 한나라
    wd:Q148  } # 중화인민공화국
  ?person wdt:P27 ?country.
  ?person wdt:P106 wd:Q854997.
  { ?person wdt:P106 wd:Q36180. } #작가이거나
  UNION 
  { ?person wdt:P106 wd:Q49757. } #시인
  ?person wdt:P800 ?work. #대표작
  SERVICE wikibase:label { bd:serviceParam wikibase:language
 "[AUTO_LANGUAGE],ko,zh,en". } } LIMIT 200


5.20세기 이후 중국 출생의 불교 신자의 직업!

#defaultView:BubbleChart
SELECT ?occupationLabel (COUNT(?person) AS ?count)
WHERE {
  ?person wdt:P31 wd:Q5.                 #인간
  ?person wdt:P19/wdt:P17 wd:Q148.       # 국가
  ?person wdt:P140 wd:Q748.              # 종교: 불교
  ?person wdt:P569 ?birthDate.           # 생년월일
  FILTER(YEAR(?birthDate) >= 1901)       # 1901년 이후 출생
  ?person wdt:P106 ?occupation.          # 직업
  # 승려, 수도자 직업 제외 필터 
  FILTER (?occupation != wd:Q733786 && ?occupation != wd:Q854997)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en". }
} GROUP BY ?occupationLabel ORDER BY DESC(?count)
limit 30 

결과해석

상단으로 이동

1. 불교 문화의 중심지 결과

1.현재 중국 내 1급 행정구역(성/직할시) 중 불교 사원이 가장 많이 분포한 지역은 어디?

위키데이터를 기반으로 중국 내 1급 행정구역별 불교 사원 분포를 시각화한 결과 티베트 자치구가 압도적으로 가장 큰 비중을 차지하고 있음을 확인할 수 있습니다. 이는 티베트 지역이 불교 중심의 사회 구조를 가지고 있어 타 지역 대비 사원 밀도가 월등히 높기 때문입니다.

그 외 상위권 지역으로는 산시성과 베이징시가 두드러집니다. 산시성은 중국 불교의 핵심 성지인 오대산이 위치해 있어 사원이 집중되어 있으며 베이징은 역사적 수도로서 다수의 황실 사찰이 보존되어 있기 때문인 것으로 해석됩니다. 결과적으로 중국 내 불교 사원 데이터는 전국에 고르게 분포하기보다는, 티베트와 주요 불교 성지를 중심으로 뚜렷한 집중 양상을 보입니다.

2.중국의 전국중점문물보호단위(국보급 문화재)로 지정된 사원이 많은 지역은?

단순 사원 수 분포와는 다르게 산시성이 가장 큰 비중을 차지하고 있음을 확인할 수 있습니다. 이러한 결과의 주된 원인은 산시성에 중국 불교 4대 명산 중 하나인 오대산(五台山)이 위치해 있기 때문입니다. 오대산은 문수보살의 성지로서 역사적으로 황실과 국가의 막대한 후원을 받아 건립된 사찰들이 밀집해 있습니다. 단순한 소규모 사찰이 아닌 역사적 권위와 종교적 중요성을 국가로부터 공인받은 격이 높은 사찰들이 산시성 지역에 집중되어 있어 국보급 문화재 지정 비율이 압도적으로 높게 나타난 것입니다.

3.중국의 전국중점문물보호단위 사원의 위치는?

위키데이터를 활용하여 '전국중점문물보호단위(국보급 문화재)'로 지정된 사원의 위치 정보를 지도에 투영한 결과, 중국 전역에 고르게 퍼져 있기보다는 황하 중류 지역(산시성, 허난성, 허베이성)에 붉은 점(좌표)이 띠를 이루며 고밀도로 집중되어 있음을 확인할 수 있습니다.

특히 지도상에서 가장 빽빽하게 점이 모여 있는 곳은 산시성 지역입니다. 이는 앞선 버블 차트 분석 결과와 일치하며, 중국의 불교 문화유산이 역사적 중심지인 화북 지역에 집중적으로 보존되어 있음을 시각적으로 증명합니다.

반면 전체 사원 수에서 1위를 차지했던 티베트 지역이나 서부 내륙 지역은 지도상에서 상대적으로 빈도가 낮게 나타납니다. 이를 통해 양적인 사원 분포는 티베트가 우세하지만, 국가가 공인한 역사적·건축학적 가치가 높은 사원은 산시성을 위시한 중원 지역에 편중되어 있다는 결론을 도출할 수 있습니다.

4.승려들의 출생지 분포

본 지도는 중국 승려의 출생지를 시대별로 시각화한 결과로, 이는 정치 중심의 이동과 함께 경제·인구 중심의 변화가 불교 인재 생산지에 직접적인 영향을 미쳤음을 시사합니다.

5.현재는 사라진 사원은?

위키데이터를 통해 '소실된 시점'이 기록된 사원을 조사한 결과, 1856년 태평천국 운동 당시 파괴된 대보은사와 1966년 문화대혁명 시기에 소실된 양팔정사 등 역사적 사건과 맞물린 구체적인 사례를 확인할 수 있었습니다. 하지만 실제 역사 속에서 수많은 사원이 사라졌음에도 불구하고 결과값이 극히 소수로 나타난 점은 이번 조사의 한계이자 아쉬운 점입니다. 이는 위키데이터 상에 폐사 정보가 충분히 기록되지 않았기 때문으로 보이며, 앞으로 더 많은 데이터 보완이 필요하다고 생각합니다.

종합 분석

1.사원의 양적 분포와 문화재적(질) 분포의 차이를 확인했습니다. 단순한 사원의 수는 티베트 불교의 영향으로 티베트 자치구가 압도적으로 많았습니다. 하지만 국가가 공인한 국보급 문화재(전국중점문물보호단위)로 범위를 좁히면 오대산이 있는 산시성과 수도였던 베이징 등 화북 지역이 중심지로 나타났습니다. 이는 사원의 절대적인 숫자는 티베트에 집중되어 있지만 역사적·건축학적 가치가 공인된 사원은 전통적인 중원 지역에 밀집해 있다는 사실을 보여줍니다.

2.승려들의 출생지와 사원의 분포가 일치하지 않는 현상을 통해 중국 불교의 구조적 특징을 발견했습니다. 앞서 분석한 사원의 분포(특히 국보급 문화재)는 오대산이 있는 산시성이나 티베트 등 특정 성지와 정치적 거점에 집중되어 있었습니다. 반면, 승려들의 출생지는 당·송 시대의 강남 지역이나 근현대의 전국적 확산 등 시대별 인구와 경제의 흐름을 따라가는 경향을 보였습니다. 이는 사찰의 분포가 국가 권력과 성지 형성의 결과인 반면, 승려의 출생지는 인구와 경제 중심지의 변화를 반영하기 때문으로 해석됩니다. 즉 두 데이터의 지리적 불일치는 중국 불교 역사에서 제도화(사원 건립 및 유지)와 사회화(승려 배출 및 대중적 확산)가 서로 분리되었음을 보여주는 중요한 지표라 할 수 있습니다.

3.소실된 사원 데이터를 통해 역사의 흔적과 데이터의 한계를 동시에 발견했습니다. 태평천국 운동(1856년)과 문화대혁명(1966년) 등 중국 근현대사의 주요 사건 당시에 사원이 파괴된 구체적인 기록을 찾을 수 있었습니다. 하지만 실제 역사적 피해 규모에 비해 위키데이터에 기록된 소실 데이터는 극히 소수에 불과했습니다.

2.시대의 흐름으로 본 중국 볼교의 전성기와 쇠퇴기

1.불교 사원 건립 연도별/세기별 추이 그래프 (연도별)

1.불교 사원 건립 연도별/세기별 추이 그래프 (세기별)

연도별 분석에서는 1056년 북송 시기가 가장 높은 수치를 기록하여 당시가 불교 건축의 역사적 전성기였음을 보여줍니다. 반면 세기별 분석에서는 20세기와 18~19세기(청나라)의 비중이 압도적으로 높게 나타납니다.

이는 송나라 때 사원이 많이 지어졌음에도 불구하고 목조 건축의 특성상 오래된 건물은 소실되고 비교적 최근에 지어지거나 중건된 사원들이 데이터에 많이 남아있다는 것을 보여주는 결과입니다.

2.국보급 사원의 건립 시기는?

11세기(송나라)가 3위를 차지하며 상위권에 올랐습니다. 일반적인 사원 분포에서는 청나라(18~19세기)의 비중이 높았던 것과 달리 국보급 사원은 11세기(송)와 7세기(당) 등 고대 건축물의 비중이 상대적으로 높게 나타나 국가가 공인하는 문화유산의 가치가 오래된 건축물에 집중되어 있음을 통계적으로 보여줍니다.

3.20세기 이후 연대별(10년 단위) 사원 건립 현황

1980년대(개혁개방 이후)와 1920~30년대(민국 시기)가 가장 큰 면적을 차지하여 불교 건축 활동이 활발했던 두 차례의 전성기를 보여줍니다.

4.중국 불교 승려의 생애주기를 타임라인으로!

중국 불교의 흐름을 전성기-침체기-급증기로 보여줍니다. 7~11세기(당·송)의 빽빽한 분포는 불교의 역사적 황금기를 14~16세기(명 중기)의 긴 공백은 유교 중심 사회에서의 위축기를 나타냅니다. 반면 19세기 이후의 폭발적인 증가는 근대 불교의 부흥 운동과 현대의 기록 보존이 맞물린 결과로 보입니다.

5.문화대혁명 시기에 건립된 사원 목록은?

문화대혁명 기간에 건립된 사원은 단 1건으로 이 검색 결과 조차 본토 밖의(홍콩) 사례로 추정되기에 사실상 0건에 수렴합니다.

종합 분석

1.전성기 (당·송): 7세기 인물 군집과 11세기(1056년)의 데이터는 불교가 교리적·건축적으로 가장 융성했던 황금기임을 증명합니다.

2.쇠퇴와 보존 (명·청): 14~16세기(명)의 긴 데이터 공백은 성리학 사회에서의 쇠퇴를 나타내며, 18~19세기(청)의 높은 수치는 근대 불교의 중흥이라기보다는 비교적 가까운 과거의 건축물이 전란을 피하고 현존할 확률이 높다는게 반영된 결과로 보입니다.

3.파괴와 급증 (근현대): 문화대혁명(1966~76) 시기의 '건립 0건'이라는 암흑기를 거친 후, 1980년대 이후 사원 건립 건수가 폭발적으로 급증하는 양상을 보입니다.

3.인물로 보는 중국 불교 결과

1.스승과 제자로 이어진 중국 승려

2.많은 제자를 배출한 승려들의 다른 직업은?

많은 제자를 양성한 승려들은 수행자임과 동시에 작가로서 저술 활동을 병행했다는 점이 가장 두드러지며 제자 수가 많은 상위권 승려들의 경우 정치인으로서의 역할을 겸하거나 시인·화가·서예가 등 예술 및 학술 분야에서 다재다능한 면모를 보인것로 보입니다.

3.과거의 승려들이 가장 많이 가진 직업은?

과거 승려들이 가장 많이 겸했던 직업은 압도적으로 시인과 화가였으며, 서예가와 작가가 그 뒤를 이어 승려들이 당대 예술과 문화를 주도하는 핵심 지식인 계층이었음을 보여줍니다.

4.시인 혹은 작가의 직업을 가진 승려의 대표작은?

5.20세기 이후 중국 출생의 불교 신자의 직업!

종합 분석

1.과거 중국의 승려는 종교인을 넘어 당대 핵심 지식인 계층이었습니다. 스승과 제자로 이어진 촘촘한 네트워크와 다양한 겸직의 데이터는, 승려가 단순 수행 공동체가 아닌 학문과 교육의 중심 역할도 수행했음을 보여줍니다.

2.경전을 넘어 다양한 장르의 문학과 예술로 확장되었다. 현장 스님의 여행기 <대당서역기>나 석두희천 스님의 <참동계>와 같은 불교 명저는 물론 백거이의 <장한가> 같은 서정시까지 포함된 결과는 이들이 단순히 경전만 쓴 것이 아니라 시 논설 등 다양한 분야에서 당대 최고의 문학가이자 지성인으로 활약했음을 보여줍니다.

3.현대에 이르러 승려에서 신자로 계승되었다. 20세기 이후 데이터에서 작가와 예술가가 압도적 다수를 차지한 것은 불교 인물들의 정체성이 시대에 따라 그 주체만 바뀌었을 뿐 본질은 여전히 유지되고 있음을 시사합니다.

참고자원

상단으로 이동

(내용 서술)

연구 후기 및 학우들의 감상

상단으로 이동

김은지 (😭🤪🧐‼️👍🏻💡)

(소실된 사원의 데이터가 별로 없는게 아쉬웠습니다. 여기에 넣진 않았지만 석굴사원을 찾는 쿼리를 짰었는데 석굴사원 대신 단순히 동굴이나 유적지로 등록되어있어 검색결과가 제대로 나오지 않았습니다. (불교와 관련된 석굴이지만 그냥 동굴로만 분류) )

김성산 (😭🤪🧐‼️👍🏻💡)

방대한 중국 불교 문헌 기록을 위키데이터 데이터로 전환하는 시도가 신선했다.특히,중국 대륙의 넓게 퍼져있는 사찰의 지리적 분포와 승려의 계보를 시각적으로 분석하는 것이 인상적인 발표였다.

최다혜 (⛩️⛩️⛩️⛩️⛩️⛩️)

(불교라는 소재가 어려울 수 있는데 듣는사람들이 편하고 쉽게 이해할 수 있도록 쿼리와 시각화를 잘 짜주신것 같습니다.)

김태현 (😭🤪🧐‼️👍🏻💡)

전체적으로 결과를 나열하는 데서 멈추지 않고, 데이터가 왜 이렇게 나왔는지를 계속 고민한 흔적이 잘 보였다. 특히 사원 분포와 승려 출생지의 불일치나 소실 사원 데이터의 부족을 통해 역사와 기록의 관계까지 짚어낸 점이 인상적이었다.

신서령 (😭🤪🧐‼️👍🏻💡)

쿼리를 풍부하게 잘 짜서 흥미롭게 들을 수 있었다.

박승정 (😭🤪🧐‼️👍🏻💡)

중국 불교의 승려들과 사원들을 쿼리를 통해 잘 조사한 것 같고 시각 자료들도 잘 찾은 것 같다.

정윤환 (😭🤪🧐‼️👍🏻💡)

불교라는 익숙하지만 학술적으로는 상당히 번거로운 주제를 시각적으로 잘 풀어내신 것 같습니다

황시아 (😭🤪🧐‼️👍🏻💡)

(이곳에 학우의 연구에 대한 감상을 남겨주세요)

강현지 (😭🤪🧐‼️👍🏻💡)

(방대한 중국의 사원의 위치 등을 한눈에 볼 수 있어서 신기했다.)

YEFENG (😭🤪🧐‼️👍🏻💡)

(이곳에 학우의 연구에 대한 감상을 남겨주세요)

QUAN (😭🤪🧐‼️👍🏻💡)

(이곳에 학우의 연구에 대한 감상을 남겨주세요)

주석

상단으로 이동