RCCTD WikiDataCuration05

데이터로 읽는 중국문화(강의) 페이지로 가기

당송 시가의 메타데이터 분석

:시인의 생애주기, 지리적 분포, 사회적 관계망을 중심으로

박승정

목차

Contents

---

연구배경 연구목적 대상주제 쿼리작성 결과해석 참고자원

---

연구배경

상단으로 이동

중국 역사에서 당나라와 송나라는 시가 문학이 가장 화려하게 꽃피웠던 황금기였다. 이 시기에는 우리가 잘 아는 이백, 두보, 소식 같은 유명한 시인들뿐만 아니라 수많은 지식인이 활동하며 방대한 양의 작품을 남겼다. 하지만 등장하는 시인이 워낙 많고 관련 기록이 여러 역사책과 문집에 흩어져 있다 보니, 기존에 책을 읽고 해석하는 방식만으로는 수천 명에 달하는 시인들이 구체적으로 어디에서 활동했고 서로 어떤 관계를 맺었는지 한눈에 파악하기가 어려웠다. 특히 시대가 당나라에서 송나라로 바뀌면서 시인들의 활동 지역이 어떻게 이동했는지, 학파가 어떻게 형성되었는지 같은 거시적인 흐름을 정확한 근거를 통해 설명하는 데에는 한계가 있었다.

최근 들어 이러한 방대한 인문학 자료를 효과적으로 다루기 위해 컴퓨터와 데이터를 활용하는 연구 방법이 주목받고 있다. 그중에서도 위키데이터는 전 세계의 지식을 누구나 사용할 수 있도록 구조화된 데이터로 제공하는 플랫폼이다. 본 연구는 이러한 디지털 기술을 활용하여, 단순히 문헌을 읽는 것을 넘어 쿼리라는 데이터 검색 명령어를 이용해 당나라와 송나라 시인들의 정보를 위키데이터에서 직접 추출하고 분석하고자 한다. 쿼리를 사용하면 수많은 시인의 출신지, 관직, 인물 관계 등의 데이터를 빠르고 정확하게 모을 수 있고 이를 지도나 그래프로 시각화하여 막연하게만 알고 있던 문학사의 흐름을 눈으로 직접 확인할 수 있게 된다. 이는 방대한 고전 문학의 숲을 데이터를 통해 새롭고 객관적으로 바라보는 중요한 계기가 될 것이다.

연구목적

상단으로 이동

본 연구의 목적은 다음과 같다.

1) 시공간적 데이터 시각화를 통한 문학의 지역성 규명
기존의 문헌 위주 연구에서 벗어나, 위키데이터의 정형화된 데이터를 활용해 당·송 시인들의 출생지와 활동 시기를 지도와 연표 위에 시각화한다. 이를 통해 당나라에서 송나라로 넘어가는 시기에 시인들의 주 활동 무대가 어떻게 이동했는지, 시대별로 특정 지역에서 문인들이 집중적으로 배출되는 경향(지역적 편중)이 있는지 거시적으로 파악하고자 한다.

2) 정량적 분석을 통한 시인 집단의 인구통계학적 재해석
남성 중심의 문학사 서술 속에서 구체적인 데이터를 통해 전체 시인 중 여성 시인의 비율을 산출하고, 그들의 존재 양상을 재조명한다. 또한, 작가별 작품 수 데이터를 통해 다작 시인과 과작 시인의 분포를 파악하고, 성별이나 시대에 따른 창작 활동의 양적 차이를 실증적으로 분석한다.

3) 관료 문인으로서의 정체성과 사회적 지위 상관관계 분석
당·송 시대의 독특한 계층인 사대부적 특성에 주목하여, 시 창작 활동과 관직 생활의 병행 여부를 데이터로 확인한다. 문학적 성취가 높은 시인들이 실제 정치 현장에서 어떤 위상을 가졌는지 분석함으로써, 당시 문학과 정치의 밀접한 상호 연관성을 규명한다.

4) 사제 관계 네트워크 분석을 통한 문단 형성 과정 추적
시인들 간의 스승과 제자 관계 데이터를 연결망으로 구조화하여, 당·송 문단을 이끌었던 주요 학파와 인적 네트워크를 시각화한다. 이를 통해 특정 스승을 중심으로 문학적 경향이 어떻게 계승되고 확산되었는지 지적 계보를 파악한다.

대상주제

상단으로 이동

본 연구는 특정 대표 시인에 국한하지 않고, 위키데이터에 등재된 당·송 시기 시인 집단 전체와 그들의 메타데이터를 분석 대상으로 삼는다. 여기에는 시인들의 출생·사망 정보, 지리적 기원, 성별, 관직 이력, 창작한 작품 수, 그리고 인적 교류 관계 등의 속성 데이터가 포함된다.

기존 연구가 주요 작가의 작품 세계를 미시적으로 분석하는 데 치중했다면, 본 연구는 SPARQL 쿼리를 활용한 정량적 분석을 통해 당·송 문단의 사회적 구조와 시공간적 변동 양상을 시각화하는 데 목적이 있다. 문학적 황금기였던 당·송 시대에 시인들이 어떠한 지리적 분포를 보이고, 관료 사회와 어떻게 결합했으며, 학통이 어떻게 계승되었는지를 데이터 관점에서 규명한다.

본 연구는 단순한 인물 정보의 나열이 아닌, 데이터 간의 상관관계를 통해 다음과 같은 문학사적 맥락을 도출한다.

지리 정보 시스템(GIS)적 접근을 통한 문학의 지역성 분석: 시인들의 출생지와 생몰년 데이터를 결합하여, 당에서 송으로 넘어가는 역사의 흐름 속에서 문인들의 주요 활동 지역이 어떻게 이동하고 확산되었는지 그 추이를 시각적으로 구현한다.

시인 집단의 사회·계층적 정체성 재해석: 시인이면서 관직을 수행한 자의 데이터를 추출하여 문학과 정치 권력의 결합 양상을 분석한다. 아울러 성별 비율과 여성 시인의 분포, 작가별 작품 수 편차를 분석하여 남성·엘리트 중심의 서술에서 드러나지 않았던 인구통계학적 특성을 파악한다.

지식 네트워크와 학통의 구조화: 시인들 간의 스승-제자 관계를 네트워크망으로 구축하여, 당·송 시단을 지탱했던 학문적 계보와 인적 상호작용의 구조를 실증적으로 드러낸다.

쿼리작성

상단으로 이동

① 당나라와 송나라의 시인들

SELECT DISTINCT ?person ?personLabel ?dynastyLabel 
WHERE {

# 1. 인물은 '인간'
?person wdt:P31 wd:Q5.

# 2. 국적은 '당나라(Q9683)' 또는 '송나라(Q7462)'
VALUES ?dynasty { wd:Q9683 wd:Q7462 }
?person wdt:P27 ?dynasty.

# 3. 직업이 '시인(Q49757)'
?person wdt:P106 wd:Q49757.

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
} 
ORDER BY ?dynastyLabel ?personLabel

② 당나라와 송나라 시인들의 출생지를 지도로 보기

#defaultView:Map
SELECT ?poet ?poetLabel ?birthPlace ?birthPlaceLabel ?coord
WHERE {
VALUES ?dynasty { wd:Q9683 wd:Q7462 } # 당나라 또는 송나라
?poet wdt:P106 wd:Q49757;   # 직업이 '시인'
      wdt:P27 ?dynasty;     # 국적이 당나라 또는 송나라
      wdt:P19 ?birthPlace.  # 출생지 정보가 있는 경우
 

?birthPlace wdt:P625 ?coord.
 
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,zh,en". }
}

③ 중국 송나라와 당나라 시인들의 출생일과 사망일

SELECT ?poet ?poetLabel ?dynastyLabel ?birthDate ?deathDate
WHERE {
VALUES ?dynasty { wd:Q9683 wd:Q7462 }
?poet wdt:P31 wd:Q5;                # 인간
      wdt:P106 wd:Q49757;           # 직업: 시인
      wdt:P27 ?dynasty;             # 국적: 당나라 또는 송나라
      wdt:P569 ?birthDate.          # 출생일 

OPTIONAL { ?poet wdt:P570 ?deathDate. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,zh,en". }
}
ORDER BY ?birthDate 
LIMIT 500

④ 당나라와 송나라 시인들의 수 비교하기

#defaultView:BubbleChart
SELECT ?dynastyLabel (COUNT(?poet) AS ?count) 
WHERE {
VALUES ?dynasty { wd:Q9683 wd:Q7462 } . # Q9683: 당나라, Q7462: 송나라
 
?poet wdt:P106 wd:Q49757 ;     # 직업: 시인
      wdt:P27 ?dynasty .       # 국적: 해당 왕조
 
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en". }
}
GROUP BY ?dynastyLabel
ORDER BY DESC(?count)

⑤ 당나라와 송나라 시인들의 성별 비율

#defaultView:BarChart
SELECT ?genderLabel (COUNT(?poet) AS ?count) 
WHERE {
VALUES ?dynasty { wd:Q9683 wd:Q7462 } . 
 
?poet wdt:P106 wd:Q49757 ;
      wdt:P27 ?dynasty ;
      wdt:P21 ?gender .
 
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en". }
}
GROUP BY ?genderLabel
ORDER BY DESC(?count)

⑥ 당나라와 송나라의 여성 시인

SELECT ?poet ?poetLabel ?dynastyLabel 
WHERE {
VALUES ?dynasty { wd:Q9683 wd:Q7462 } .
 
?poet wdt:P106 wd:Q49757 ;    # 직업: 시인
      wdt:P27 ?dynasty ;      # 국적: 당/송
      wdt:P21 wd:Q6581072 .   # 성별: 여성
 
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en". }
}

⑦ 당나라와 송나라 시인들의 작품

#defaultView:TreeMap
SELECT ?dynastyLabel ?poetLabel ?workLabel 
WHERE {
 # 1. 대상 왕조 설정 (당나라, 송나라)
VALUES ?dynasty { wd:Q9683 wd:Q7462 } .
 
 # 2. 시인 찾기 (직업: 시인, 국적: 해당 왕조)
?poet wdt:P106 wd:Q49757 ;
      wdt:P27 ?dynasty .
 
 # 3. 작품 찾기 (양방향 검색: 시인의 대표작 OR 작품의 작가)
{ ?poet wdt:P800 ?work } UNION { ?work wdt:P50 ?poet }
 
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,zh,en". }
}
LIMIT 500 리미트 안걸면 38109개

⑧ 당송 시인들의 개인별 작품 개수

#defaultView:TreeMap
SELECT ?dynastyLabel ?poetLabel (COUNT(DISTINCT ?work) AS ?workCount)
WHERE {
 # 1. 대상 왕조 (당, 송)
 VALUES ?dynasty { wd:Q9683 wd:Q7462 } .

# 2. 시인 찾기
 ?poet wdt:P106 wd:Q49757 ;
       wdt:P27 ?dynasty .

 # 3. 작품 찾기 (양방향 검색)
 { ?poet wdt:P800 ?work } UNION { ?work wdt:P50 ?poet }

SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,zh,en". }
}
GROUP BY ?dynastyLabel ?poetLabel
ORDER BY DESC(?workCount)
LIMIT 500

⑨ 시인이면서 관직에도 자리한 사람

SELECT DISTINCT ?person ?personLabel ?dynastyLabel ?positionLabel
WHERE {
 # 1. 인물은 '인간'
?person wdt:P31 wd:Q5.
 
 # 2. 국적은 '당나라(Q9683)' 또는 '송나라(Q7462)'
VALUES ?dynasty { wd:Q9683 wd:Q7462 }
?person wdt:P27 ?dynasty.
 
 # 3. 직업이 '시인(Q49757)'
?person wdt:P106 wd:Q49757.
 
 # 4. '관직(P39)'
?person wdt:P39 ?position.
 
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}
ORDER BY ?dynastyLabel ?personLabel

⑩ 당나라 송나라 시인들의 사제 관계

#defaultView:Graph
SELECT DISTINCT ?student ?studentLabel ?teacher ?teacherLabel ?dynastyLabel
WHERE {
 # 1. 국적: 당나라(Q9683) 또는 송나라(Q7462)
VALUES ?dynasty { wd:Q9683 wd:Q7462 }
?student wdt:P27 ?dynasty;
         wdt:P31 wd:Q5. # 사람  

# 2. 직업: 시인
?student wdt:P106 wd:Q49757.

 # 3. 스승(P1066) 관계 추출
?student wdt:P1066 ?teacher.

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}

⑪ 당나라 송나라 시인들이 영향을 받은 인물

SELECT DISTINCT ?person ?personLabel ?influencer ?influencerLabel ?dynastyLabel
WHERE {
 # 1. 국적: 당나라 또는 송나라
VALUES ?dynasty { wd:Q9683 wd:Q7462 }
       ?person wdt:P27 ?dynasty;
               wdt:P106 wd:Q49757. # 직업: 시인

# 2. 영향을 준 인물(P737) 추출
?person wdt:P737 ?influencer.

SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }
}

결과해석

상단으로 이동

① 당송 시인들의 기본 정보

1-1 위키데이터에 존재하는 당송 시인들

첫 번째 쿼리를 통해 위키데이터에 등재된 인물 중 국적이 당나라 또는 송나라이면서 직업이 시인인 인물은 총 3,599명으로 집계되었다.
이는 위키데이터 내에서 해당 시기의 문학가들에 대한 인물 정보가 상당히 방대하게 구축되어 있음을 시사하며,
본 연구의 모집단이 된다.

1-2 당송 시인들의 출생지

3,599명의 시인 중 출생지 좌표 정보가 존재하는 인물은 189명이다. 
이를 지도 시각화로 분석한 결과는 다음과 같다.

중원 집중 현상:

대부분의 시인은 중국의 정치·경제·문화의 중심지였던 황허강 및 양쯔강 유역(중앙 및 동부 지역)에 밀집해 있다.
 이는 당시의 문학 활동이 수도(장안, 낙양, 개봉 등)와 주요 도시를 중심으로 활발히 이루어졌음을 시각적으로 증명한다.

실크로드와 이백의 특이점: 

대다수가 중국 내륙에 위치한 반면, 이백의 출생지가 서역의 수야브(현 키르기스스탄)로 나타난 점은 매우 주목할 만한 결과이다.
 수야브는 당나라 안서도호부 산하의 군사·교역 거점으로, 실크로드의 요충지였다.
 이는 당나라의 개방적이고 국제적인 성격과 이백이라는 시인이 가진 문화적 배경의 특수성을 데이터가 정확히 반영하고 있음을 보여준다.

1-3 당송 시인들의 생일과 사망일 그리고 데이터 공백

3,599명의 시인 중 생일이나 사망일 정보가 존재하는 인물은 866명이다. 

세 가지 쿼리의 결과값을 비교할 때,
 정보의 유형에 따라 데이터의 양이 급격히 줄어드는 현상이 뚜렷하게 관찰된다.

1단계 (존재 확인): 전체 시인 3,599명

2단계 (시간 정보): 생년 또는 몰년 정보가 있는 시인 866명 (약 24%)

3단계 (공간 정보): 출생지 좌표 정보가 있는 시인 189명 (약 5.2%)

② 당송 시인집단의 구성과 분포

③ 당송 시인들의 저작물 데이터와 통계

④ 당송 시인들의 사회적 위상 및 학통 네트워크

참고자원

상단으로 이동

(내용 서술)

주석

상단으로 이동