RCCTD WikiDataCuration07

데이터로 읽는 중국문화(강의) 페이지로 가기

사상과 삶으로 읽는 중국 근대사

:량치차오, 쑨원, 캉유웨이, 옌푸, 루쉰, 후스, 리다자오의 생애와 저작을 중심으로

황시아

목차

Contents

---

연구배경 연구목적 대상주제 쿼리작성 결과해석 참고자원

---

연구배경

상단으로 이동

19세기 아편전쟁을 기점으로 중국은 정치,사회사상 면에서 급격한 변화를 겪기 시작했다.
질서가 흔들리고 서구 열강의 침략이 강화되면서, 중국 사회는 위기를 맞았다.
이러한 격변의 시기는 단순한 외부 충격만으로 설명할 수 없으며, 내부의 개혁 논쟁과 새로운 사상의 등장
그리고 실천적 행동이 복합적으로 작용하며 전개되었다.
중국 근대는 전통 질서와 새로운 세계관이 충돌하고 뒤섞이는 과정이었고,
이 전환기의 중심에는 시대를 고민하고 자신의 방식으로 변혁을 시도했던 다양한 지식인과 혁명가들이 있었다.

본 연구에서 다루는 량치차오, 쑨원, 캉유웨이, 옌푸, 루쉰, 후스, 리다자오는
이러한 변화의 중심축을 형성한 대표적인 인물들이다.
이들은 서로 다른 시대와 환경에서 활동했지만,
공통적으로 중국이 근대를 어떻게 이해하고 수용해야 하는지에 대한 문제의식을 공유했다.
7인은 각기 다른 방식으로 중국 근대사의 형성과 전개에 핵심적인 기여를 한 인물들이다.

하지만 이러한 인물들의 생애와 사상 저서들이 어떻게 서로 연결되고 영향을 주고받았는지,
그리고 그들의 활동이 근대 중국사에서 어떤 위치를 차지하는지는 개별적연구가 많다.
이에 본 연구는 Wikidata 와 SPARQL을 활용한 데이터 기반 접근을 통해
인물 간 관계, 활동시기, 주요저서, 사장적흐름을 구조적으로 분석하고자 한다.

따라서 본 연구는 7인의 생애와 저서, 사상 활동을 하나의 데이터 네트워크로 통합하여
중국 근대사의 흐름을 새로운 방식으로 조망하고자 한다.
이는 단순히 인물 연구에 그치지 않고, 중국 근대라는 거대한 전환기의 사상적 사회적 맥락을
보다 입체적으로 이해하는데 큰 기여할 것이다.

연구목적

상단으로 이동

본 연구의 목적은 다음과 같다.

1)근대 사상가,혁명가 7인의 생애와 사상 요소를 데이터로 구조화해 파악한다.
근대 역사는 단순히 인물의 생몰연도와 사건 목록으로 이해될 수 없다.
각 인물은 사상, 저술, 정치활도으 사회적 영향력, 당대 제자,동료 네트워크가 결합된 복합적 사상 체계의 일부다.
따라서 SPARQL을 사용해 인물 -> 저서 -> 사상개념 -> 활동장소 -> 사회적 맥락으로
이어지는 데이터를 체계적으로 추출해, 근대 중국 사상가들의 활동 구조를 파악한다.

2)7인이 활동한 시대와 지역이 어떻게 다른지 데이터를 통해 비교한다.
시기,지역,정치환경에 따라 이들이 수행한 역할과 사상이 어떻게 달라졌는지
Wikidata 기반 데이터로 비교한다.
이를 통해 지역성과 시대성이 사상 형성에 미친 영향을 규명한다.

3)각 인물이 남긴 주요저서의 기원, 내용, 사상적 분포를 분석한다.
SPARQL을 통해 저서가 어떤 시대,사상,사회적 문제와 연결되는지,
그리고 같은 사상 개념이 어떤 인물들 사이에서 반복 등장하는지 분석한다.

4)인물<->저서<->사상개념<->활동장소로 이어지는 근대 사상 연결망을 시각적으로 재구성한다.
관계를 SPARQL분석으로 시각화하여,근대 중국이 단절된 인물들의 이야기가 아니라
상호작용,전파,대립으로 이루어진 사상 네트워크였음을 드러낸다.

대상주제

상단으로 이동

본 연구의 대상은 중국 근대화를 대표하는 사상가·혁명가
7인(량치차오, 쑨원, 캉유웨이, 옌푸, 루쉰, 후스, 리다자오)이다.

이들은 정치 개혁, 혁명 운동, 신문화운동, 문학혁명, 마르크스주의 수용 등
중국 근대 사회의 전환점을 형성한 핵심 인물들로,
각각의 활동과 사상이 중국 근대의 지적·사회적 구조를 변화시키는 데 중요한 역할을 수행하였다.
본 연구는 이 7인을 중심으로 근대 중국이 어떤 사상적 변화, 정치적 실험, 문화적 전환을
거쳐 형성되었는지를 분석하는 것을 주제로 한다.

특히 다음과 같은 측면을 중심으로 연구 주제를 설정한다.
7인의 생애, 활동 시기, 주요 사건을 데이터로 구조화하여 근대 중국의 시간적 흐름을 재구성한다.
주요 저서와 사상의 핵심 개념을 비교하여 사상적 차이와 공통점을 밝힌다.
사제 관계, 사상 영향, 정치·혁명 네트워크 등 인물 간 연결망을 파악해 근대 지성사의 상호작용 구조를 드러낸다.
데이터 기반 분석(SPARQL)을 통해 근대 중국을 인물–사상–시대–공간이 결합된 네트워크로 시각화한다.

쿼리작성

상단으로 이동

1. 중국 근대 사상가,혁명가 7의 인물 기본정보

1-1. 중국 근대 사상가 7인의 출생,사망일을 확인
#defaultView:Timeline
SELECT ?person ?personLabel ?birth ?death ?image
WHERE {
VALUES ?person {
wd:Q379836
wd:Q8573
wd:Q360135
wd:Q559957
wd:Q23114
wd:Q47667
wd:Q378036}
?person wdt:P569 ?birth.
OPTIONAL { ?person wdt:P570 ?death. }
OPTIONAL { ?person wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". }}
ORDER BY ?birth

1-2.각 인물의 출생지와 주요활동 장소 확인
#defaultView:Map
SELECT ?person ?personLabel ?birthPlaceLabel ?birthCoord ?deathPlaceLabel ?deathCoord
WHERE {
VALUES ?person {
wd:Q379836 # 강유위
wd:Q8573 # 쑨원
wd:Q360135 # 양계초
wd:Q559957 # 후스
wd:Q23114 # 루쉰
wd:Q47667 # 리다자오
wd:Q378036 # 천두슈 }
OPTIONAL {
?person wdt:P19 ?birthPlace.
?birthPlace wdt:P625 ?birthCoord. # 출생지 좌표 추가
}
OPTIONAL {
?person wdt:P20 ?deathPlace.
?deathPlace wdt:P625 ?deathCoord. # 사망지 좌표 추가
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }

1-3.각 인물의 직업과 사회적 역할(사상가,혁명가 등)을 확인
#defaultView:Dimensions
SELECT ?person ?personLabel ?occupationLabel
WHERE {
VALUES ?person {
wd:Q379836
wd:Q8573
wd:Q360135
wd:Q559957
wd:Q23114
wd:Q47667
wd:Q378036}
OPTIONAL { ?person wdt:P106 ?occupation. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }

1-4.중국 근대 지식인 7인은 어떤 정당과 조직에 소속되어 활동했는가?
#defaultView:Dimensions
SELECT DISTINCT ?personLabel ?organization ?organizationLabel ?relationLabel
WHERE {
VALUES ?person {wd:Q379836 wd:Q8573 wd:Q360135 wd:Q559957wd:Q23114 wd:Q47667 wd:Q378036}
{?person wdt:P102 ?organization.
BIND("정당 소속"@ko AS ?relationLabel)}
UNION
{?person wdt:P463 ?organization.
BIND("조직·단체 소속"@ko AS ?relationLabel)}
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". } }
ORDER BY ?personLabel ?relationLabel

1-5.인물 기본 정보 총정리
SELECT ?person ?personLabel ?birth ?death ?birthPlaceLabel ?deathPlaceLabel ?occupationLabel
WHERE {
VALUES ?person {
wd:Q379836 # 량치차오
wd:Q8573 # 쑨원
wd:Q360135 # 캉유웨이
wd:Q559957 # 옌푸
wd:Q23114 # 루쉰
wd:Q47667 # 후스
wd:Q378036 # 리다자오
}
OPTIONAL { ?person wdt:P569 ?birth. } # 출생일
OPTIONAL { ?person wdt:P570 ?death. } # 사망일
OPTIONAL { ?person wdt:P19 ?birthPlace. } # 출생지
OPTIONAL { ?person wdt:P20 ?deathPlace. } # 사망지
OPTIONAL { ?person wdt:P106 ?occupation. } # 직업/역할
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }

1-6. 7인이 어디에서 공부했고, 어디에 거주(유학지/망명지)를 찾아보자
->서구 및 일본의 근대 사상을 습득하는데 영향
SELECT ?person ?personLabel ?educationLabel ?countryLabel ?residenceLabel
WHERE {
VALUES ?person {
wd:Q379836 # 량치차오
wd:Q8573 # 쑨원
wd:Q360135 # 캉유웨이
wd:Q559957 # 옌푸
wd:Q23114 # 후스
wd:Q47667 # 리다자오
wd:Q378036 # 루쉰
}
OPTIONAL { ?person wdt:P69 ?education. # 1. 교육 기관 (P69): 어디서 교육을 받았는가?
OPTIONAL { ?education wdt:P17 ?country. } }# 1-1. 교육 기관의 국가 (P17): 어느 나라의 영향을 받았는가?
OPTIONAL { ?person wdt:P551 ?residence. }# 2. 주요 거주지 (P551): 유학/망명 시 주로 어디에 머물렀는가?
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }
ORDER BY ?personLabel

1-7. 1-6에 있는 교육장소, 유학지, 망명지 등에 대한 위치를 지도에 표시해보자
#defaultView:Map
SELECT ?person ?personLabel ?educationLabel ?educationCoord ?countryLabel ?residenceLabel ?residenceCoord
WHERE {
VALUES ?person {
wd:Q379836 # 량치차오
wd:Q8573 # 쑨원
wd:Q360135 # 캉유웨이
wd:Q559957 # 옌푸
wd:Q23114 # 후스
wd:Q47667 # 리다자오
wd:Q378036 # 루쉰
}
OPTIONAL { ?person wdt:P69 ?education. # 1. 교육 기관 (P69) 정보 및 좌표 (P625)
OPTIONAL { ?education wdt:P17 ?country. }
OPTIONAL { ?education wdt:P625 ?educationCoord. } # <--- 교육 기관 좌표 (P625)
}
OPTIONAL { ?person wdt:P551 ?residence. # 2. 주요 거주지 (P551) 정보 및 좌표 (P625)
OPTIONAL { ?residence wdt:P625 ?residenceCoord. } # <--- 거주지 좌표 (P625)
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }
ORDER BY ?personLabel

2.근대역사가 7인의 사상,저작 데이터

2-1. 중국 근대사 주요인물7명의 주요저작 목록 찾기
SELECT DISTINCT ?personLabel ?work ?workLabel ?typeLabel
WHERE {
VALUES ?person {
wd:Q379836 wd:Q8573 wd:Q360135 wd:Q559957 wd:Q23114 wd:Q47667 wd:Q378036 }
{?work wdt:P50 ?person.}
UNION
{?person wdt:P800 ?work.}
UNION
{?work wdt:P170 ?person.}
?work wdt:P31/wdt:P279* wd:Q47461344.
OPTIONAL { ?work wdt:P31 ?type. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }
ORDER BY ?personLabel ?publicationDate
LImit 200

2-2. 중국 근대사 7인의 저작목록과 각 저작의 원본 출판 연도를 찾아보자.
#defaultView:Timeline
SELECT DISTINCT ?personLabel ?work ?workLabel ?publicationDate
WHERE {
VALUES ?person {
wd:Q379836 wd:Q8573 wd:Q360135 wd:Q559957 wd:Q23114 wd:Q47667 wd:Q378036 }
{?work wdt:P50 ?person.}
UNION
{?person wdt:P800 ?work.}
UNION
{?work wdt:P170 ?person.}
?work wdt:P31/wdt:P279* wd:Q47461344.
?work wdt:P577 ?publicationDate.
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }
ORDER BY ?personLabel ?publicationDate

2-3. 7인 중 누가 저작활동이 가장 활발했는지 barchart로 확인해보자
#defaultView:BarChart
SELECT ?personLabel (COUNT(DISTINCT ?work) AS ?workCount)
WHERE {
VALUES ?person {
wd:Q379836 # 량치차오
wd:Q8573 # 쑨원
wd:Q360135 # 캉유웨이
wd:Q559957 # 옌푸
wd:Q23114 # 후스
wd:Q47667 # 리다자오
wd:Q378036 # 루쉰
}
{ ?work wdt:P50 ?person. }
UNION
{ ?person wdt:P800 ?work. }
UNION
{ ?work wdt:P170 ?person. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }
GROUP BY ?personLabel
ORDER BY DESC(?workCount)

2-4.중국 근대사 주요인물 7인이 창작하거나 집필한 저작물을 인물별, 유형별(장르)로 분류하여 count로 묶어서 어떤 장르를 많이 썼는지 알아보자
#defaultView:Linechart
SELECT ?personLabel ?typeLabel (COUNT(DISTINCT ?work) AS ?workCount)
WHERE {
VALUES ?person {
wd:Q379836 # 량치차오
wd:Q8573 # 쑨원
wd:Q360135 # 캉유웨이
wd:Q559957 # 옌푸
wd:Q23114 # 후스
wd:Q47667 # 리다자오
wd:Q378036 # 루쉰 }
{ ?work wdt:P50 ?person. } # 저자 (Author)
UNION
{ ?person wdt:P800 ?work. } # 주요 저작 (Notable work)
UNION
{ ?work wdt:P170 ?person. } # 창작자 (Creator)
OPTIONAL { ?work wdt:P31 ?type. }
# 2. 작품의 '유형/종류' (P31: instance of)를 선택. (장르 P136보다 더 넓은 범주)
service wikibase:label { bd:serviceParam wikibase:language "ko,en,zh". } }
GROUP BY ?personLabel ?typeLabel
ORDER BY ?personLabel DESC(?workCount)

3.중국의 역사적 사건과 인물들과의 관계성, 인물과 인물들의 관계성, 저작들과 인물들의 관계 찾기

3-1. 중국 근대 지식인 7명(량치차오, 쑨원, 캉유웨이, 옌푸, 루쉰, 후스, 리다자오)을 중심으로,
이들 인물과 직간접적으로 연결된 다른 모든 인적 관계(사람)를 추출하고, 인물과 관계의 이름을 보여줘
SELECT DISTINCT ?corePerson ?corePersonLabel ?relation ?relationLabel ?relatedPerson ?relatedPersonLabel
WHERE {
VALUES ?corePerson { # 1. 핵심 인물 7인 정의)
wd:Q379836 # 량치차오
wd:Q8573 # 쑨원
wd:Q360135 # 캉유웨이
wd:Q559957 # 옌푸
wd:Q23114 # 후스
wd:Q47667 # 리다자오
wd:Q378036 # 루쉰
}
{?corePerson ?relation ?relatedPerson.}# 2. 핵심 인물과 관련된 모든 인물을 찾는 패턴 (쌍방향 검색)
UNION
{?relatedPerson ?relation ?corePerson.}
?relatedPerson wdt:P31 wd:Q5. # 3. 관련된 대상이 사람(Q5: human)인지 확인
SERVICE wikibase:label{ bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ko,en". } }

3-2. 중국 역사에서 주요 사건에 속하는 세부 전투들은 무엇이며, 각각 어떤 큰 역사적 사건 안에서 발생했는가?”
(*1860년대 이후: 청말기 위기와 서구의 개입으로 중국이 근대적 전환 겪기 시작한시기)
#defaultView:TreeMap
SELECT ?eventLabel ?battleLabel ?year
WHERE {
?battle wdt:P31 wd:Q178561 ; # 전투 (battle)
wdt:P276/wdt:P17 wd:Q148 ; # 장소: 중국 (China)
wdt:P361 ?event . # 상위 사건/전쟁 (part of)
?event wdt:P580 ?startTime . # 사건의 시작 시간
BIND(YEAR(?startTime) AS ?year)
FILTER(?year >= 1860)
SERVICE wikibase:label {
bd:serviceParam wikibase:language "ko,zh,en".
?event rdfs:label ?eventLabel.
?battle rdfs:label ?battleLabel.
}
FILTER(BOUND(?eventLabel) && BOUND(?battleLabel))
}
ORDER BY ?year ?eventLabel ?battleLabel
LIMIT 500

3-3. 1860년 이후 중국에서 발생한 주요 사건과 그에 속한 전투는 무엇이며, 각 사건에 어떤 인물들이 참여했는가?
SELECT DISTINCT ?event ?eventLabel ?battle ?battleLabel ?person ?personLabel
WHERE {
?battle wdt:P31 wd:Q178561;
wdt:P276/wdt:P17 wd:Q148;
wdt:P361 ?event.
?event wdt:P580 ?startTime.
FILTER(YEAR(?startTime) >= 1860)
OPTIONAL { ?event wdt:P710 ?person. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ko,zh,en". } }
LIMIT 500

3-4.1860년 이후 중국의 주요 사건 시기에, 해당 사건과 연결된 인물들은 어떤 저작을 통해 사상을 표현했는가?
-> X

결과해석

상단으로 이동

1. 중국 근대 사상가,혁명가 7의 인물 기본정보

1-1. 출생,사망시기 분석

결과,중국 근대 사상가·혁명가 7인은 모두 19세기 중·후반에 출생하여 20세기 전반에 활동한 인물들로 확인된다. 이들은 청말 체제의 붕괴, 공화혁명, 신문화운동, 사회주의 사상의 유입이라는 중국 근대사의 핵심 전환기를 직접 경험한 세대에 해당한다.
출생 시기의 중첩은 이들이 동일한 시대적 문제의식—서구 문명의 충격, 전통 질서의 위기, 국가 재건—을 공유했음을 보여주며, 이후 사상적 연대와 논쟁이 가능했던 역사적 조건을 형성하였다.

1-2. 출생지·사망지 및 주요 활동 공간

출생지와 사망지를 지도에 시각화한 결과, 이들 인물은 중국 남부와 연해 지역 출신이 다수를 차지하며,
활동 무대는 베이징·상하이 등 정치·출판 중심지로 확장된다.
이는 근대 중국의 사상 생산이 지리적으로 개방된 항구 도시와 정치 중심 공간을 중심으로 이루어졌음을 보여주며,
사상의 형성과 확산이 특정 지역에 집중되었음을 시사한다.

1-3. 직업과 사회적 역할

직업 정보를 분석하면, 이들 7인은 단일한 정체성을 지닌 집단이 아니라
사상가, 혁명가, 정치가, 학자, 언론인 등 복합적인 사회적 역할을 수행한 인물들임을 확인할 수 있다.
이는 중국 근대 지식인이 학문 활동에 머무르지 않고,
정치 참여·사회 비판·대중 계몽을 동시에 수행한 실천적 지식인이었음을 보여준다.

참고자원

상단으로 이동

(내용 서술)

주석

상단으로 이동