사용자:Hiblue

생물정보 LOD

• 생물정보LOD 명세서
• VOWL
• 생물LOD SPARQL Endpoint sample

덕유산에서 서식하고 있는 모든 버섯의 학명을 반환하시오.
prefix wildlife: <http://lod.nature.go.kr/resource/>
prefix wlo: <http://lod.nature.go.kr/ontology/>
select ?species ?sName where { 
 ?species wlo:hasInternalDistribution wildlife:Deokyusan . 
 ?species wlo:kingdom wildlife:Fungi .
 ?species wlo:scientificName ?sName .
} limit 500

4월에 꽃이 피는 식물은?
prefix wildlife: <http://lod.nature.go.kr/resource/>
prefix wlo: <http://lod.nature.go.kr/ontology/>
select ?species ?label where { 
 ?species wlo:floweringSeason wildlife:April . 
 ?species rdfs:label ?label .
} limit 500

독수리 인스턴스가 포함하고 있는 Object Property 항목을 반환하시오
prefix wildlife: <http://lod.nature.go.kr/resource/>
Select ?p ?o where {
wildlife:Aegypius_monachus ?p ?o .
?p rdf:type owl:ObjectProperty .
}

생물종별 인스턴스 개수는?
SELECT DISTINCT ?kingdom ?label ( COUNT(DISTINCT ?species) AS ?count )
WHERE {
   {
       ?species <http://lod.nature.go.kr/ontology/kingdom> <http://lod.nature.go.kr/resource/Plantae> .
       ?species <http://lod.nature.go.kr/ontology/kingdom> ?kingdom .
       ?kingdom rdfs:label ?label .
   } UNION {
       ?species <http://lod.nature.go.kr/ontology/kingdom> <http://lod.nature.go.kr/resource/Fungi> .
       ?species <http://lod.nature.go.kr/ontology/kingdom> ?kingdom .
       ?kingdom rdfs:label ?label .
   } UNION {
       ?species <http://lod.nature.go.kr/ontology/class> <http://lod.nature.go.kr/resource/Aves> .
       ?species <http://lod.nature.go.kr/ontology/class> ?kingdom .
       ?kingdom rdfs:label ?label .
   } UNION {
       ?species <http://lod.nature.go.kr/ontology/class> <http://lod.nature.go.kr/resource/Actinopterygii> .
       ?species <http://lod.nature.go.kr/ontology/class> ?kingdom .
       ?kingdom rdfs:label ?label .
   } UNION {
       {
           {
               ?species <http://lod.nature.go.kr/ontology/class> <http://lod.nature.go.kr/resource/Amphibia> .
           }
           UNION
           {
               ?species <http://lod.nature.go.kr/ontology/class> <http://lod.nature.go.kr/resource/Sauropsida> .
           }
       }
       ?species <http://lod.nature.go.kr/ontology/class> ?kingdom .
       ?kingdom rdfs:label ?label .
   }
}
GROUP BY ?kingdom ?label

부산 영화 영상 관광 LOD

• LOD 소개
• 부산LOD sparqlEndpoint

영화 사도에 출연한 배우들은?
SELECT distinct ?movieUri ?movieTitle ?personName
WHERE {
  BIND(resource:Movie_사도 as ?movieUri).
  ?movieUri rdfs:label ?movieTitle.
  ?movieUri  ns:hasActor ?person.
  ?person rdfs:label ?personName.
}

국제영화제에 출품된 작품 중에서 2015년에 제작된 영화와 제작년도는?
SELECT distinct ?movieUri ?movieTitle ?makeYear
WHERE {
  ?movieUri rdf:type ns:FilmFestivalEntry.
  ?movieUri  rdfs:label ?movieTitle.
  ?movieUri  ns:makeYear ?makeYear.
  FILTER(?makeYear="2015").  
}

영화 사도에 나온 배우가 출연한 다른 작품은?
SELECT DISTINCT  ?personName ?movieUri ?movieTitle
WHERE
  { BIND(res:Movie_사도 AS ?res )
    ?res ns:hasActor ?personUri .
    ?personUri rdfs:label ?personName.
    ?personUri ns:appearedIn ?movieUri .
    ?movieUri rdfs:label ?movieTitle.
   FILTER ( ?movieUri != ?res )  
 }

영화 국제시장을 연출했던 감독의 다른 작품은?
SELECT distinct ?movieTitle ?directorName
WHERE
  { BIND(res:Movie_국제시장 AS ?res)
    ?res ns:hasDirector ?person .
    ?person rdfs:label ?directorName.
    ?person ns:direct ?MovieUri .
    ?MovieUri rdfs:label ?movieTitle.  
   FILTER ( ?res != ?MovieUri ).    
 }

해운대온천센터 근처 1km내의 숙박지에 대한 정보는?
PREFIX  schema: <http://schema.org/>
PREFIX  f:    <http://www.saltlux.com/geo/functions#>
PREFIX  res:  <http://lod.busan.go.kr/resource/>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX  ns:   <http://lod.busan.go.kr/ontology/>
PREFIX  geo:  <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX  foaf: <http://xmlns.com/foaf/0.1/>
PREFIX  xsd:  <http://www.w3.org/2001/XMLSchema#>
PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>

SELECT DISTINCT  ?uri ?label ?image ?address ?tel ?
homepage
WHERE
 { BIND(res:해운대온천센터 AS ?res)
   ?res geo:lat ?lat .
   ?res geo:long ?long .
   ?uri rdf:type ?class
   FILTER ( ?class = ns:LodgingFacility )
   ?uri rdfs:label ?label .
   ?uri geo:lat ?lat2 .
   ?uri geo:long ?long2
   FILTER ( ?res != ?uri )
   FILTER f:within_distance(?lat, ?long, ?lat2, ?long2, 1000)
   BIND(f:distance(?lat, ?long, ?lat2, ?long2) AS ?distance)
   OPTIONAL
     { ?uri ns:image ?image }
   OPTIONAL
     { ?uri ns:address ?address }
   OPTIONAL
     { ?uri ns:tel ?tel }
   OPTIONAL
     { ?uri ns:homepage ?homepage }
   OPTIONAL
     { ?uri ns:content ?content }
 }
ORDER BY ?distance
LIMIT   5